1 of 10 labels not displaying

Just starting out? Need help? Post your questions and find answers here.
User avatar
Columbo
Enthusiast
Enthusiast
Posts: 303
Joined: Wed Sep 10, 2014 7:17 am
Location: Ontario Canada
Contact:

1 of 10 labels not displaying

Post by Columbo »

I made a few minor changes to a program that I had written about a year ago and for some reason 1 of my labels is not displaying on the screen. The only changes made to the labels was a slight change in vertical positioning.

Here is my Enumeration:

Code: Select all


Enumeration
  ; Windows
  #MainWindow
  
  ;Databases
  #dbaseID
  
  ; Buttons
  #searchBtn
  #getRecBtn
  #prevBtn
  #nextBtn
  #exitBtn
  
  ; Labels
  #header
  #footer
  #labelName
  #labelMeaning
  #labelPronounce
  #labelPeriod
  #labelGroup
  #labelSize
  #labelLived
  #labelDiet
  #labelFossils
  #labelFactfile
  #labelPicture
  #labelCompare
  
  ;Text Boxes
  #name
  #meaning
  #pronounce
  #period
  #group
  #size
  #lived
  #diet
  #fossils
  #factFile
  
  ;Edit Boxes
  #search
   
  ; Images
  #img0
  #img1
  #img2
  #img3
  #headerImg
  #searchIcon
  
  ; Miscellaneous
  #headerFont
  #footerFont
  #kbdSearch
  #RecNo
  
EndEnumeration

And here is the procedure where the label is being used:

Code: Select all


Procedure setupScreen()
   path$ = GetPathPart(ProgramFilename())
   imagePath3 =  path$ + "images\header.jpg"
   LoadImage(#img3,imagePath3)
      
  ;---------------{ Setup Header ]---------------
   ImageGadget(#headerimg,0,0,1280,678,ImageID(#Img3))     ;Used as background
   DisableGadget(#headerimg,1)
  
  ;----------------{ Setup Labels ]----------------
  TextGadget(#labelName, 90, 205, 45, 20, "Name : ")
  TextGadget(#labelMeaning, 80, 256, 50, 20, "Meaning : ")
  TextGadget(#labelPronounce, 50, 305, 85, 20, "Pronounciation : ")
  TextGadget(#labelPeriod, 92, 353, 50, 20, "Period : ")
  TextGadget(#labelGroup, 68, 403, 70, 20, "Main Group : ")
  TextGadget(#labelSize, 103, 454, 30, 20, "Size : ")
  TextGadget(#labelLived, 98, 503, 40, 20, "Lived : ")
  TextGadget(#labelDiet, 105, 552, 30, 20, "Diet : ")
  TextGadget(#labelFossils, 95, 598, 50, 20, "Fossils : ")
  TextGadget(#labelFactfile, 585, 627, 50, 20, "Fact File : ")
    
   For colorGadgets = #labelName To #labelFactFile
     SetGadgetColor(colorGadgets, #PB_Gadget_BackColor, RGB(226,222,213))
     SetGadgetColor(colorGadgets, #PB_Gadget_FrontColor, RGB(62, 34, 7))
   Next 
  
  ;---------------{ Setup Data Fields ]-----------------
  TextGadget(#name, 145, 202, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#meaning, 145, 250, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#pronounce, 145, 302, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#period, 145, 351, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#group, 145, 400, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#size, 145, 450, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#lived, 145, 500, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#diet, 145, 548, 202, 20, "", #SS_CENTERIMAGE)
  TextGadget(#fossils, 145, 598, 200, 20, "", #SS_CENTERIMAGE)
  EditorGadget(#FactFile, 375, 200, 480, 420, #PB_Editor_WordWrap)
  
  ;---[ Setup Search Box & Record Number Box ]---
  StringGadget(#search, 985, 160, 150, 20, "", #SS_CENTERIMAGE)     ;Search Box  (At top right of screen)
  StringGadget(#RecNo, 1036, 510, 70, 20, "", #SS_CENTERIMAGE)    ; Get Record Box (above the Prev and Next buttons)
  
  For colorGadgets = #name To #FactFile
    SetGadgetColor(colorGadgets, #PB_Gadget_BackColor, RGB(255,255,255))
    SetGadgetColor(colorGadgets, #PB_Gadget_FrontColor, RGB(0, 0, 0))
  Next
  
  margin = 10
   SendMessage_(GadgetID(#Factfile), #EM_SETMARGINS, #EC_LEFTMARGIN, margin|0 << 16)
   SendMessage_(GadgetID(#Factfile), #EM_SETMARGINS, #EC_RIGHTMARGIN, 0|margin << 16)
   SetGadgetText(#Factfile, GetDatabaseString(#dbaseID, dbColumn))
   SetActiveGadget(#Search)
  
  ;---{ Setup Buttons ]---
  ButtonGadget(#getRecBtn, 1042, 540, 60, 20, "Get Record")
  ButtonGadget(#prevBtn, 1000, 575, 60, 20, "Prev")
  ButtonGadget(#nextBtn, 1090, 575, 60, 20, "Next")
  ButtonGadget(#exitBtn, 1048, 610, 60, 20, "Exit")  


All of the labels and TextGadgets display ok. Only the "Meaning" label is not displaying. I can't see anything different with the label code from the others. At first I thought maybe it was being hidden under the background image but, if that were the case, how come the other labels are not also hidden under the background image?
Anyone see a problem that I am missing?
http://www.oldtimeradiotoday.com - Listen to or download classic old time radio broadcasts.
User avatar
hujambo
User
User
Posts: 48
Joined: Wed May 15, 2013 8:26 pm
Location: South Pacific

Re: 1 of 10 labels not displaying

Post by hujambo »

Nothing obvious that I can see from the code. Obviously, don't know what is in the rest of your coding; one thing that might be worth a try is setting a start for Enumeration ie. Enumeration Labels 1000

Code as you supplied works with all TextGadgets displaying

Code: Select all

Enumeration
  ; Windows
  #MainWindow
  
  ;Databases
  #dbaseID
  
  ; Buttons
  #searchBtn
  #getRecBtn
  #prevBtn
  #nextBtn
  #exitBtn
  
  ; Labels
  #header
  #footer
  #labelName
  #labelMeaning
  #labelPronounce
  #labelPeriod
  #labelGroup
  #labelSize
  #labelLived
  #labelDiet
  #labelFossils
  #labelFactfile
  #labelPicture
  #labelCompare
  
  ;Text Boxes
  #name
  #meaning
  #pronounce
  #period
  #group
  #size
  #lived
  #diet
  #fossils
  #factFile
  
  ;Edit Boxes
  #search
  
  ; Images
  #img0
  #img1
  #img2
  #img3
  #headerImg
  #searchIcon
  
  ; Miscellaneous
  #headerFont
  #footerFont
  #kbdSearch
  #RecNo
  
EndEnumeration

Global imagePath3.s
UseJPEGImageDecoder()


Procedure setupScreen()
  path$ = GetPathPart(ProgramFilename())
  imagePath3 = path$ + "images\back.png"

  LoadImage(#img3,imagePath3)
  
  ;---------------{ Setup Header ]---------------
  ImageGadget(#headerimg,0,0,1280,678,ImageID(#Img3))     ;Used as background
  DisableGadget(#headerimg,1)
  
  ;----------------{ Setup Labels ]----------------
  TextGadget(#labelName, 90, 205, 45, 20, "Name : ")
  TextGadget(#labelMeaning, 80, 256, 50, 20, "Meaning : ")
  TextGadget(#labelPronounce, 50, 305, 85, 20, "Pronounciation : ")
  TextGadget(#labelPeriod, 92, 353, 50, 20, "Period : ")
  TextGadget(#labelGroup, 68, 403, 70, 20, "Main Group : ")
  TextGadget(#labelSize, 103, 454, 30, 20, "Size : ")
  TextGadget(#labelLived, 98, 503, 40, 20, "Lived : ")
  TextGadget(#labelDiet, 105, 552, 30, 20, "Diet : ")
  TextGadget(#labelFossils, 95, 598, 50, 20, "Fossils : ")
  TextGadget(#labelFactfile, 585, 627, 50, 20, "Fact File : ")
  
  For colorGadgets = #labelName To #labelFactFile
    SetGadgetColor(colorGadgets, #PB_Gadget_BackColor, RGB(226,222,213))
    SetGadgetColor(colorGadgets, #PB_Gadget_FrontColor, RGB(62, 34, 7))
  Next
  
  ;---------------{ Setup Data Fields ]-----------------
  TextGadget(#name, 145, 202, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#meaning, 145, 250, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#pronounce, 145, 302, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#period, 145, 351, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#group, 145, 400, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#size, 145, 450, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#lived, 145, 500, 200, 20, "", #SS_CENTERIMAGE)
  TextGadget(#diet, 145, 548, 202, 20, "", #SS_CENTERIMAGE)
  TextGadget(#fossils, 145, 598, 200, 20, "", #SS_CENTERIMAGE)
  EditorGadget(#FactFile, 375, 200, 480, 420, #PB_Editor_WordWrap)
  
  ;---[ Setup Search Box & Record Number Box ]---
  StringGadget(#search, 985, 160, 150, 20, "", #SS_CENTERIMAGE)     ;Search Box  (At top right of screen)
  StringGadget(#RecNo, 1036, 510, 70, 20, "", #SS_CENTERIMAGE)      ; Get Record Box (above the Prev and Next buttons)
  
  For colorGadgets = #name To #FactFile
    SetGadgetColor(colorGadgets, #PB_Gadget_BackColor, RGB(255,255,255))
    SetGadgetColor(colorGadgets, #PB_Gadget_FrontColor, RGB(0, 0, 0))
  Next
  
  margin = 10
  SendMessage_(GadgetID(#Factfile), #EM_SETMARGINS, #EC_LEFTMARGIN, margin|0 << 16)
  SendMessage_(GadgetID(#Factfile), #EM_SETMARGINS, #EC_RIGHTMARGIN, 0|margin << 16)
  ;SetGadgetText(#Factfile, GetDatabaseString(#dbaseID, dbColumn))
  ;SetActiveGadget(#Search)
  
  ;---{ Setup Buttons ]---
  ButtonGadget(#getRecBtn, 1042, 540, 60, 20, "Get Record")
  ButtonGadget(#prevBtn, 1000, 575, 60, 20, "Prev")
  ButtonGadget(#nextBtn, 1090, 575, 60, 20, "Next")
  ButtonGadget(#exitBtn, 1048, 610, 60, 20, "Exit")  
  
EndProcedure

OpenWindow(0, 0, 0, 1280, 700, "WindowTest", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)

setupScreen()
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow


User avatar
mk-soft
Always Here
Always Here
Posts: 5337
Joined: Fri May 12, 2006 6:51 pm
Location: Germany

Re: 1 of 10 labels not displaying

Post by mk-soft »

Use different Enumeration for Window, Gadget, Menu, MenuItems, Images, Database.

Show Purebasic help - Objects overview
My Projects ThreadToGUI / OOP-BaseClass / EventDesigner V3
PB v3.30 / v5.75 - OS Mac Mini OSX 10.xx - VM Window Pro / Linux Ubuntu
Downloads on my Webspace / OneDrive
User avatar
Columbo
Enthusiast
Enthusiast
Posts: 303
Joined: Wed Sep 10, 2014 7:17 am
Location: Ontario Canada
Contact:

Re: 1 of 10 labels not displaying

Post by Columbo »

Thanks hujambo. I've been playing around with it for about an hour now and can't seem to find the problem. This is the first time that I have run across this. Maybe I'll try mk-soft's suggestion and see if that makes a difference.

Thanks mk-soft for the suggestion on the Enumeration.
http://www.oldtimeradiotoday.com - Listen to or download classic old time radio broadcasts.
User avatar
hujambo
User
User
Posts: 48
Joined: Wed May 15, 2013 8:26 pm
Location: South Pacific

Re: 1 of 10 labels not displaying

Post by hujambo »

I think you'll find Mk-Soft is correct.

Try the enumeraton like this:

Code: Select all


Enumeration MainWindow
  ; Windows
  #MainWindow
EndEnumeration

Enumeration Databases 100
  ;Databases
  #dbaseID
EndEnumeration  

Enumeration FormGadgets 200
  ; Buttons
  #searchBtn
  #getRecBtn
  #prevBtn
  #nextBtn
  #exitBtn
  
  ; Labels
  #header
  #footer
  #labelName
  #labelMeaning
  #labelPronounce
  #labelPeriod
  #labelGroup
  #labelSize
  #labelLived
  #labelDiet
  #labelFossils
  #labelFactfile
  #labelPicture
  #labelCompare
  
  ;Text Boxes
  #name
  #meaning
  #pronounce
  #period
  #group
  #size
  #lived
  #diet
  #fossils
  #factFile
  
  ;Edit Boxes
  #search
EndEnumeration

Enumeration Images 500
  ; Images
  #img0
  #img1
  #img2
  #img3
  #headerImg
  #searchIcon
EndEnumeration

Enumeration Other 700
  ; Miscellaneous
  #headerFont
  #footerFont
  #kbdSearch
  #RecNo
  
EndEnumeration
IdeasVacuum
Always Here
Always Here
Posts: 6425
Joined: Fri Oct 23, 2009 2:33 am
Location: Wales, UK
Contact:

Re: 1 of 10 labels not displaying

Post by IdeasVacuum »

Hi
You should not have empty lines or comments inside an Enumeration - that can upset the compiler!
Just this tiny clean-up should fix the issue:

Code: Select all

Enumeration
#MainWindow      ;Windows
#dbaseID         ;Databases
#searchBtn       ;Buttons
#getRecBtn
#prevBtn
#nextBtn
#exitBtn
#header          ;Labels
#footer
#labelName
#labelMeaning
#labelPronounce
#labelPeriod
#labelGroup
#labelSize
#labelLived
#labelDiet
#labelFossils
#labelFactfile
#labelPicture
#labelCompare
#name            ;Text Boxes
#meaning
#pronounce
#period
#group
#size
#lived
#diet
#fossils
#factFile
#search          ;Edit Boxes
#img0            ;Images
#img1
#img2
#img3
#headerImg
#searchIcon      ;Miscellaneous
#headerFont
#footerFont
#kbdSearch
#RecNo
EndEnumeration
IdeasVacuum
If it sounds simple, you have not grasped the complexity.
User avatar
HeX0R
Addict
Addict
Posts: 979
Joined: Mon Sep 20, 2004 7:12 am
Location: Hell

Re: 1 of 10 labels not displaying

Post by HeX0R »

IdeasVacuum wrote:Hi
You should not have empty lines or comments inside an Enumeration - that can upset the compiler
:shock:
This can't be true, any example where this happens?
User avatar
Columbo
Enthusiast
Enthusiast
Posts: 303
Joined: Wed Sep 10, 2014 7:17 am
Location: Ontario Canada
Contact:

Re: 1 of 10 labels not displaying

Post by Columbo »

I have used comments in enumerations in a number of programs and never had any issues. This program is the first time that I have ever seen where 1 label out of a group of 10 would not display. I've been plating around with it for a couple of days now and I'm still baffled by it.
http://www.oldtimeradiotoday.com - Listen to or download classic old time radio broadcasts.
User avatar
Columbo
Enthusiast
Enthusiast
Posts: 303
Joined: Wed Sep 10, 2014 7:17 am
Location: Ontario Canada
Contact:

Re: 1 of 10 labels not displaying

Post by Columbo »

Thank you very much hujambo. That seems to have worked! Can you explain why? I am not understanding why setting up the enumeration like your example works different that mine and I would really like to get a grip on this.

Thanks again, VERY much.
http://www.oldtimeradiotoday.com - Listen to or download classic old time radio broadcasts.
User avatar
HeX0R
Addict
Addict
Posts: 979
Joined: Mon Sep 20, 2004 7:12 am
Location: Hell

Re: 1 of 10 labels not displaying

Post by HeX0R »

The problem is somewhere else in your code, the changed enumeration (which is bad btw, PB will reserve space for 500 unused images) has only one effect:
#meaning has no longer ID 22.
I would say somewhere in your code you change Gadget number 22.
Just test it yourself:
Use your initial code and swap #meaning with #name, most likely #name will then be the one which is no longer shown.

But all depends on the code you didn't show, I'm more or less just guessing.
User avatar
Columbo
Enthusiast
Enthusiast
Posts: 303
Joined: Wed Sep 10, 2014 7:17 am
Location: Ontario Canada
Contact:

Re: 1 of 10 labels not displaying

Post by Columbo »

You are correct HeX0R. I did the switch with the #labelName and #labelMeaning and the name label was missing instead. I'm not sure where the value of the constant could have been changed but I'll have to go through the code again to see if I can find it.

Thanks.
http://www.oldtimeradiotoday.com - Listen to or download classic old time radio broadcasts.
User avatar
Derren
Enthusiast
Enthusiast
Posts: 313
Joined: Sat Jul 23, 2011 1:13 am
Location: Germany

Re: 1 of 10 labels not displaying

Post by Derren »

The value of the constant is not changed. Constants can't be changed later in the programm.
You just used the same number again for another gadget.


Really interesting what kind suggestions are posted here.
I, too, have no yet a problem with comments or white spaces in an enumeration and it would be a MAJOR bug if that is really the case.
Also, everybody always talks about how you should not use higher numbers for gadgets and such and then the suggestion is to bank windows, gadgets and other objects. Again, I haven't had any problems with a gadget, a window and an image having the exact same ID, and again I think it would be HUGE bug, if that would cause any problems.

Then again, just use #PB_Any. The only real reason to use constants is if you don't trust yourself and fear that you would accidentally overwrite a variable that stores an object ID, but as you can see, constants don't protect you from multiple definitions on the same ID.
User avatar
hujambo
User
User
Posts: 48
Joined: Wed May 15, 2013 8:26 pm
Location: South Pacific

Re: 1 of 10 labels not displaying

Post by hujambo »

So am I confused about how Enumeration work HeX0Rs?

My understating, right or wrong, is that the following:

Code: Select all

Enumeration Images 500
  ; Images
  #img0
  #img1
  #img2
  #img3
  #headerImg
  #searchIcon
EndEnumeration
Just starts the enumeration count at 500.. not that it reserves 500 images?

EDITED: NO This is wrong !!! - you can probably stop reading at this point ! Thanks to HeX0Rs, Josh and Shardik :P

So I thought that you are forcing the enumeration to number #img0 as 500, #img1 as 501 etc

If it reserves 500 images then why does debug #img1 return 500 and why does Debug #PB_Compiler_EnumerationValue return 506... the next available after #505 used for #searchIcon?

and if I followed that code with the following #img4 would be 506

Code: Select all

Enumeration Images
  ; Images
  #img4
EndEnumeration

Would be grateful if people can enlighten me and confirm this? :)

In the example below #EVENTCONNECTStart and #MenuLogout are both assigned 1 - so if you use these for the same thing (not in this case Events and Menu) then you can run into trouble. Which is why there are section titles Events and Menu for Enumeration

Code: Select all

Enumeration Events
  #EVENTExitNOW
  #EVENTCONNECTStart
  #EVENTCONNECTFinished
  #EVENTCONNECTFailed
  #EVENTLOGGEDIN
  #EVENTFORCELogout
  #EVENTFORCEExitCancel
  #EVENTNotesDone
  #EVENTPopulateReady
EndEnumeration

Enumeration Menu
  #MenuQuit
  #MenuLogout
  #MenuNewUser
  #MenuEditUsers
  #MenuEditMyInfo
EndEnumeration

So you can either choose a start point yourself or use #PB_Event_FirstCustomValue for your events eg

Code: Select all

Enumeration #PB_Event_FirstCustomValue
  #EVENTExitNOW
  #EVENTCONNECTStart
  #EVENTCONNECTFinished
  #EVENTCONNECTFailed
  #EVENTLOGGEDIN
  #EVENTFORCELogout
  #EVENTFORCEExitCancel
  #EVENTNotesDone
  #EVENTPopulateReady
EndEnumeration
or

Code: Select all

Enumeration Events 5000
  #EVENTExitNOW
  #EVENTCONNECTStart
  #EVENTCONNECTFinished
  #EVENTCONNECTFailed
  #EVENTLOGGEDIN
  #EVENTFORCELogout
  #EVENTFORCEExitCancel
  #EVENTNotesDone
  #EVENTPopulateReady
EndEnumeration
Last edited by hujambo on Fri Jul 19, 2019 8:18 pm, edited 4 times in total.
User avatar
hujambo
User
User
Posts: 48
Joined: Wed May 15, 2013 8:26 pm
Location: South Pacific

Re: 1 of 10 labels not displaying

Post by hujambo »

And if you don't name Enumeration sections identically for the same purpose (eg. Gadgets) the Enumeration starts at 0 each time which can cause major problems.

Code: Select all

Enumeration Gadgets
  #Button1
  #Button2
EndEnumeration

Enumeration SomethingElse
  #Test1
  #Test2
EndEnumeration

Debug "#Button1 = " + #Button1
Debug "#Button2 = " + #Button2
Debug "#Test1 = " + #Test1
Debug "#Test2 = " + #Test2


If OpenWindow(0, 0, 0, 230, 120, "Example...", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ButtonGadget(#Button1, 10, 10, 150, 30, "Test") 
  ButtonGadget(#Button2, 10, 40, 150, 30, "Test 2") 
  
  Repeat
    Event = WaitWindowEvent()
    
    Select Event
        
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #Test2
            Select EventType()
              Case #PB_EventType_LeftClick : Debug "Wrong! This is #Test2 because #Test2 just the same as #Button2"
            EndSelect
          Case #Button1 
            Select EventType()
              Case #PB_EventType_LeftClick : Debug "Button 1 Click with left mouse button"
            EndSelect
          Case #Button2
            Select EventType()
              Case #PB_EventType_LeftClick : Debug "Button 2 Click with left mouse button"
            EndSelect
            
        EndSelect
        
    EndSelect
  Until Event = #PB_Event_CloseWindow
EndIf
So the code is corrected using

Code: Select all

Enumeration Gadgets
  #Button1
  #Button2
EndEnumeration

Enumeration Gadgets
  #Test1
  #Test2
EndEnumeration
User avatar
Josh
Addict
Addict
Posts: 1183
Joined: Sat Feb 13, 2010 3:45 pm

Re: 1 of 10 labels not displaying

Post by Josh »

hujambo wrote:And if you don't name Enumeration sections identically for the same purpose (eg. Gadgets) the Enumeration starts at 0 each time which can cause major problems.

Code: Select all

Enumeration Gadgets
  #Button1
  #Button2
EndEnumeration

Enumeration SomethingElse
  #Test1
  #Test2
EndEnumeration
So the code is corrected using

Code: Select all

Enumeration Gadgets
  #Button1
  #Button2
EndEnumeration

Enumeration Gadgets
  #Test1
  #Test2
EndEnumeration
Of course that's bullshit. Why do you call one enumeration 'Gadgets' and the other 'SomethingElse'? Because one is for Gadgets and the other is for something else, where 'SomethingElse' can mean 'Windows', 'Menu' or anything else. How did you get the idea that you can use the enumeration 'SomethingElse' for gadgets as well? Of course you will get problems.

PureBasic uses an internal handle. If you use #PB_Any, you get this internal handle back. If you use a number instead of #PB_Any, PB must first translate this number into the PB handle by using an array. This array must then be as large as your highest used number. So if you use a gadget number of 500, PB will create an array of 500 entries even though 499 are unused. This is also the reason why you will automatically get a warning if you have a gadget number of 5000 or more.

An internal array is created for Windows, Gadgets, Menus, etc., so the used numbers can be repeated. However, this does not mean that you can use the numbers from the enumeration for Windows for gadgets.

Named enumerations have two advantages. First, it's easier to read and second, you can continue the enumeration at any point in your code without overlapping.

So Use:

Code: Select all

Enumeration Windows
  #MyWin1
  #MyWin2
EndEnumeration

Enumeration Gadgets
  #MyGad1
  #MyGad2
EndEnumeration

;In an other IncludeFile you can use

Enumeration Windows
  #MyWin3
  #MyWin4
EndEnumeration
IdeasVacuum wrote:Hi
You should not have empty lines or comments inside an Enumeration - that can upset the compiler!
Just this tiny clean-up should fix the issue:
That's bullshit.

Columbo wrote:Here is my Enumeration:
Your problem is certainly sitting in front of your screen. If you post an executable code in which your error is reproducible, then it can also be helped to you. However, I am sure that if you had reduced your code for the forum further and further, so that the error still remains comprehensible, then you would have found the error yourself and your posting would not have taken place at all :)
sorry for my bad english
Post Reply