Can I create a FOLD on a selected bit of code?

[AMpos]

Hi!

Can I create a fold on a selected piece of code. I mean, I select a few lines with the mouse, click on a button/menu and insert ;{ at start and ;} at the end:

Code: Select all

line 1
line 2
line 3
line 4

After selecting LINE 2 & LINE 3, choose "create fold":

Code: Select all

line 1
;{
line 2
line 3
;}
line 4

[infratec]

Sorry, but I cant not read where you need this.

IDE, EditorGadget(), StringGadget(), ScintillaGadget() ...

From what you are talking?

If you mean the IDE, you can create a tool which do this.

[BarryG]

He means the IDE, like we can select a group of lines to comment with Ctrl+B. He wants something like that but to insert fold marks at the start and end of the selected code block. It can't be done natively and would need a tool, as you said. Or he could post it in "Feature Requests" maybe.

[infratec]

Code: Select all

EnableExplicit

#SetCursor = #True

Define IDEGadgetID.i, SavedClipboardText$, IDEText$

CompilerIf #SetCursor
  Define StartPos.l
CompilerEndIf


IDEGadgetID = Val(GetEnvironmentVariable("PB_TOOL_Scintilla"))
If IDEGadgetID
  CompilerIf #SetCursor
    StartPos = SendMessage_(IDEGadgetID, #SCI_GETSELECTIONSTART, #Null, #Null)
  CompilerEndIf
  SavedClipboardText$ = GetClipboardText()
  SetClipboardText("")
  SendMessage_(IDEGadgetID, #SCI_COPY, #Null, #Null)
  IDEText$ = GetClipboardText()
  If IDEText$ <> ""
    SetClipboardText(";{ " + #LF$ + IDEText$ + #LF$ + ";}")
    SendMessage_(IDEGadgetID, #SCI_PASTE, #Null, #Null)
    CompilerIf #SetCursor
      StartPos + 3
      SendMessage_(IDEGadgetID, #SCI_GOTOPOS, StartPos, #Null)
    CompilerEndIf
  EndIf
  SetClipboardText(SavedClipboardText$)
EndIf

Compile it to an Exe and add it to the Tools.

I'm not 100% sure about the #LF$ maybe it should be a #CRLF$, but it looks that it works.

[NicTheQuick]

You can create a Feature Request on Github: https://github.com/fantaisie-software/purebasic/issues

[AMpos]

Code: Select all

EnableExplicit


Define IDEGadgetID.i, SavedClipboardText$, IDEText$

IDEGadgetID = Val(GetEnvironmentVariable("PB_TOOL_Scintilla"))
If IDEGadgetID
  SavedClipboardText$ = GetClipboardText()
  SetClipboardText("")
  SendMessage_(IDEGadgetID, #SCI_COPY, #Null, #Null)
  IDEText$ = GetClipboardText()
  If IDEText$ <> ""
    SetClipboardText(";{" + #LF$ + IDEText$ + #LF$ + ";}")
    SendMessage_(IDEGadgetID, #SCI_PASTE, #Null, #Null)
  EndIf
  SetClipboardText(SavedClipboardText$)
EndIf

Compile it to an Exe and add it to the Tools.

I'm not 100% sure about the #LF$ maybe it should be a #CRLF$, but it looks that it works.

It works at first try! Love you!

[AMpos]

Just asking... can it be modified to place the cursor just after the ";{"

[infratec]

Extended the listing above.

[AMpos]

Extended the listing above.

Thanks dude!

[infratec]

Ahhh, you want to extend the first line with an additional comment after 'insert folding'.
I corrected the listing above (added a space and + 4 is changed to + 3)