question about dynamic array and data

[Lonely_Star77]

hello...

i'm trying to create a 1 dimensional array with 0 as number of cells in it and then dynamically load it with string data from data section using a procedure in a for loop however when i print the data inside the array i only get the last string and not the whole data... i don't understand what i'm doing wrong

here is the code:

Code: Select all

Dim arr.s(0)
Define.s r

Procedure sappend(Array arr.s(1), temp.s)
  Define i = 0
  ReDim arr(0 + i)
  arr(i) = temp
  i+1
EndProcedure

For i = 0 To 2
  Read.s r
  sappend(arr(),r)
Next


For i = 0 To 2
  Debug arr(i)
Next


DataSection
  Data.s "hello", "hi", "goodbye"
EndDataSection

[TI-994A]

...dynamically load it with string data from data section using a procedure in a for loop...

Try it like this:

Code: Select all

Dim arr.s(0)
Define.s r

Procedure sappend(Array arr.s(1), temp.s, notFirstValue)      
  If notFirstValue
    i = ArraySize(arr()) + 1  
    ReDim arr(i)
  EndIf     
  arr(i) = temp 
EndProcedure

For i = 0 To 2
  Read.s r
  sappend(arr(), r, i)
Next

For i = 0 To 2
  Debug arr(i)
Next

DataSection
  Data.s "hello", "hi", "goodbye"
EndDataSection

[infratec]

Code: Select all

Procedure sappend(Array arr.s(1), temp.s)
  Define i = 0
  ReDim arr(0 + i)
  arr(i) = temp
  i+1
EndProcedure

You always do ReDim arr(0 + 0), since i is always 0.
You can ignore the i+1, because after EndProcedure the variable i does no longer exist.
You can do it like this if you use Static instead of Define.
But the solution of TI-99A is a better solution.

[Lonely_Star77]

Thank you very much!

[infratec]

You can add simply

Code: Select all

Debug i

to see this

[mk-soft]

Even though this is possible with arrays, it is better to use a list when adding a lot of individual data in unknown numbers. (Global NewList row.s())

For example when reading a text file.

[Olli]

Is this code below right ? This allows the coder to waste time ressources to reallocate on every new string.

Code: Select all

Structure Table
 powSize.I
 maxLimit.I
 realLimit.I
 Array A$(0)
EndStructure

Procedure TableCreate()
 Define *This.Table = AllocateMemory(SizeOf(Table) )
 InitializeStructure(*This, Table)
 ProcedureReturn *This
EndProcedure

Procedure TableGrow(*This.Table)
 With *This
  \realLimit + 1
  If \realLimit > \maxLimit
   \powSize + 1
   \maxLimit = 1 << \powSize - 1
   Redim \A$(\maxLimit) ; <<< --- right ?
  EndIf
 EndWith
EndProcedure

;- Main

Define *x = TableCreate()
For i = 0 to 5
 TableGrow(*x)
 *x\A$(i) = Str(i * i)
 Debug *x\A$(i)
Next

[Axolotl]

Hi,
I wouldn't say it's right or wrong. The idea I recognize here is not to always call the REDIM. This saves time and conserves resources.

Whether this approach is sufficiently "correct" depends INMO on the expected result in terms of speed.

An alternative for Arrays are known to be the List and Map functions.

But also in this case probably applies: 10 programmers equal 11 opinions. (10 is not binary. )

My little suggestion on your example code, not starting with zero at the member variables:

Code: Select all

Procedure TableCreate(SizeChunks.i = 3) 
  ; ... 
  *This\powSize = SizeChunks 
  *This\maxLimit = 1 << SizeChunks 
EndProcedure 

Happy coding and Stay healthy.

[TI-994A]

...This allows the coder to waste time ressources to reallocate on every new string...

If the intended array size is known beforehand, it would be easier and more productive to simply dimension and assign it all at once. However, if the array size grows gradually with the execution of the program, then it has to be re-dimensioned and assigned as required.

[Olli]

Replacing 5 with 500, then 5000, then 50000, then 500000 strings in the code line << For i = 0 To 5 >>.
If Redim is okay for dynamic arrays (apparently nobody wanted to check...), you have just 19 array changes. What it is not a lot for 500 000 strings updates... (considering you have only 4 megabytes of wasted strings memory if you cause the grow to a limit at 1 000 000 for 500 001 strings - exactly 2^19+1 strings)