Drawing image with transparent background on canvas

[jacdelad]

I am, again, failing to create an image with transparent background on runtime and putting it on a canvas.

Code: Select all

OpenWindow(0,0,0,300,300,"Test",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
CanvasGadget(1,0,0,300,300)
CreateImage(2,300,300,32,#PB_Image_Transparent)
StartDrawing(ImageOutput(2))
Box(100,100,100,100,RGB(255,0,0))
StopDrawing()
StartDrawing(CanvasOutput(1))
Box(0,0,300,300,GetSysColor_(15))
DrawingMode(#PB_2DDrawing_AlphaBlend)
DrawImage(ImageID(2),0,0)
StopDrawing()
Repeat
Until WaitWindowEvent()=#PB_Event_CloseWindow

Why is the background always black? According to the help and a thread I found #PB_2DDrawing_AlphaBlend should be the right mode, so I assume I'm doing something wrong with the image itself.

[StarBootics]

Hello,

I think I got it :

Code: Select all

OpenWindow(0,0,0,300,300,"Test",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)

CanvasGadget(1,0,0,300,300)

CreateImage(2,300,300,32, #PB_Image_Transparent)
StartDrawing(ImageOutput(2))
DrawingMode(#PB_2DDrawing_AlphaChannel)
Box(0,0,300,300,RGBA(0,0,0,255))
DrawingMode(#PB_2DDrawing_AllChannels)
Box(100,100,100,100,RGBA(255,0,0, 255))
StopDrawing()

StartDrawing(CanvasOutput(1))
Box(0,0,300,300, 0)

DrawingMode(#PB_2DDrawing_AlphaBlend)
DrawAlphaImage(ImageID(2), 0, 0)
StopDrawing()

Repeat
Until WaitWindowEvent()=#PB_Event_CloseWindow

Best regards
StarBootics

[Paul]

I would do this...

Code: Select all

OpenWindow(0,0,0,300,300,"Test",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
CanvasGadget(1,0,0,300,300)
CreateImage(2,300,300,32,#PB_Image_Transparent)

StartDrawing(ImageOutput(2))
  DrawingMode(#PB_2DDrawing_AlphaBlend)
  Box(100,100,100,100,RGBA(255,0,0,255))
StopDrawing()

StartDrawing(CanvasOutput(1))
  Box(0,0,300,300,GetSysColor_(15))
  DrawingMode(#PB_2DDrawing_AlphaBlend)
  DrawImage(ImageID(2),0,0)
StopDrawing()
Repeat
Until WaitWindowEvent()=#PB_Event_CloseWindow

[jacdelad]

Ayeyeye...thanks. Very stupid mistake(s)...