[RESOLU] ListIcongadget : l'item manquant

[falsam]

Je coches l'ensemble des items que je souhaites voir dans un résultat (Bouton Result)

Si je sélectionne un des items ou que je modifie un des items, bien que l'item concerné soit toujours cocher, celui-çi n’apparaît pas dans le résultat.

Un peu de code pour étayer mon soucis.

Code : Tout sélectionner

Enumeration
	#Mainform
	#Liste
	#Col1
	#Col2
	#Update
	#Result
EndEnumeration

Define.l Event, EventWindow, EventGadget, EventType, EventMenu

Procedure Open_Mainform()
	If OpenWindow(#Mainform,370,100,423,400,"Test")
		ListIconGadget(#Liste,16,80,374,180,"Col1",100,#PB_ListIcon_CheckBoxes|#PB_ListIcon_FullRowSelect|#PB_ListIcon_MultiSelect)
		AddGadgetColumn(#Liste,1, "Col2",100)
		StringGadget(#Col1,18,265,80,20,"")
		StringGadget(#Col2,106,265,80,20,"")
		ButtonGadget(#Update,195,264,80,20,"Update")
		ButtonGadget(#Result,287,263,80,20,"Result")
		
		AddGadgetItem(#Liste, -1, "Pommes"+Chr(10)+"10")
		AddGadgetItem(#Liste, -1, "Peches"+Chr(10)+"20")
		AddGadgetItem(#Liste, -1, "Bananes"+Chr(10)+"30")
		AddGadgetItem(#Liste, -1, "Prunes"+Chr(10)+"40")
		
	EndIf
EndProcedure

Open_Mainform()

Repeat
	Event = WaitWindowEvent()
	Select Event
		Case #PB_Event_Menu

		Case #PB_Event_Gadget

		  Select EventGadget()
		    Case #Liste
		      SetGadgetText(#Col1, GetGadgetItemText(#Liste, GetGadgetState(#Liste), 0))
		      SetGadgetText(#Col2, GetGadgetItemText(#Liste, GetGadgetState(#Liste), 1))

		    Case #Update
		      SetGadgetItemText(#Liste, GetGadgetState(#Liste), GetGadgetText(#Col1), 0)
		      SetGadgetItemText(#Liste, GetGadgetState(#Liste), GetGadgetText(#Col2), 1)

				Case #Result
				  For i=0 To 3
				    If GetGadgetItemState(#Liste, i)=#PB_ListIcon_Checked
				      Debug GetGadgetItemText(#Liste, i, 0)+" -"+GetGadgetItemText(#Liste, i, 1)
				    EndIf
				    
				  Next

			EndSelect

		Case #PB_Event_CloseWindow
			End
	EndSelect
ForEver

Merci d'avance pour votre aide.

[falsam]

J'ai trouver l'origine de mon problème.

il fallait remplacer

Code : Tout sélectionner

If GetGadgetItemState(#Liste, i)=#PB_ListIcon_Checked

par

Code : Tout sélectionner

If GetGadgetItemState(#Liste, i) & #PB_ListIcon_Checked

[dayvid]

Don marque rés..., non rien, j'ai rien dit