si on presse ESC, ca arrete le programme !

[SPH]

Bonjour,
Je n'arrive pas a dire que si on presse ESC, ca arrete le programme !
J'ai fais la methode du screen dans un windows. Il faut mettre quoi ?

Code : Tout sélectionner

UseJPEGImageDecoder()
If InitSprite() And InitMouse() And InitKeyboard()
Else
MessageRequester("Erreur", "InitSprite() And InitMouse() And InitKeyboard() And InitSound() : impossible")
End 
EndIf


file$ = OpenFileRequester("Sélectionnez un fichier","","JPG (.jpg)|*.jpg|All files (*.*)|*.*",0)
  If file$
    If ReadFile(0, file$) 
      length = Lof(0)                            ; Lit la taille en octets du fichier 
      *MemoryID = AllocateMemory(length)         ; alloue un bloc mémoire de la taille du fichier
      If *MemoryID
        bytes = ReadData(0, *MemoryID, length)   ; Lit les données du fichier et les place dans le bloc mémoire
      EndIf
      CloseFile(0)
    EndIf
  EndIf
  
  Resultat = CatchImage(0, *MemoryID, length)
  
  ;Debug resultat
  
  OpenWindow(0, 0, 0, ImageWidth(0), ImageHeight(0), "Resultat de ma selection", #PB_Window_BorderLess)
  ImageGadget(#PB_Any, 0,0,300,200,ImageID(0))
  ;ImageGadget(#PB_Any, 0,0,0,0,ResizeImage(0, 300, 200))
  
  Repeat
  
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow
      End                
      
  EndSelect
  
  ; si on appuie sur ESC, ca ferme l'image)
  ExamineKeyboard() 
If KeyboardPushed(#PB_Key_Escape)
  End
EndIf

ForEver

[graph100]

Utilise les raccourcis clavier. Tu ne peux utiliser ExamineKeyboard() qu'avec un écran ouvert.

Code : Tout sélectionner

UseJPEGImageDecoder()
If InitSprite() And InitMouse() And InitKeyboard()
Else
	MessageRequester("Erreur", "InitSprite() And InitMouse() And InitKeyboard() And InitSound() : impossible")
	End
EndIf


file$ = OpenFileRequester("Sélectionnez un fichier","","JPG (.jpg)|*.jpg|All files (*.*)|*.*",0)
If file$
	If ReadFile(0, file$)
		length = Lof(0)                            ; Lit la taille en octets du fichier
		*MemoryID = AllocateMemory(length)         ; alloue un bloc mémoire de la taille du fichier
		If *MemoryID
			bytes = ReadData(0, *MemoryID, length)   ; Lit les données du fichier et les place dans le bloc mémoire
		EndIf
		CloseFile(0)
	EndIf
EndIf

Resultat = CatchImage(0, *MemoryID, length)

;Debug resultat

OpenWindow(0, 0, 0, ImageWidth(0), ImageHeight(0), "Resultat de ma selection", #PB_Window_BorderLess)
ImageGadget(#PB_Any, 0,0,300,200,ImageID(0))
;ImageGadget(#PB_Any, 0,0,0,0,ResizeImage(0, 300, 200))



AddKeyboardShortcut(0, #PB_Shortcut_Escape, 0)

Repeat
	event = WaitWindowEvent()
	
	If event = #PB_Event_Menu
		Select EventMenu()
			Case 0
				event = #PB_Event_CloseWindow              
				
		EndSelect
	EndIf
	
	; si on appuie sur ESC, ca ferme l'image)
	
Until event = #PB_Event_CloseWindow

End

[SPH]

Ca alors, je ne connaissais pas cette instruction. Merci