[Résolu] Webgadget et version activeX

[Stefou]

Bonjour à tous !

Merci de me lire et de votre futur aide

Je dois me connecter et surfer sur un site pour mon boulot.
Je voudrais le faire avec mon propre programme.
J'utilise donc un webgadget.
Mais voilà, la version du webgadget n'a pas l'air au niveau, lorsque je surf j'ai une erreur qui apparait sur chaque page :
Erreur de script dans internet Explorer - erreur : liferayest indéfini.

Bref le comprtement du site n'est pas le même que sous un navigateur classique !
Dès la première page, on ne peut pas passer du champ nom au champ mot de pass avec la touche TAB !

Qu'en pensez vous ?

Code : Tout sélectionner

OpenWindow(0,10,10,800,800,"ess")
WebGadget(1,10,10,700,700,"https://ent77.seine-et-marne.fr/connexion/login?service=https%3A%2F%2Fent77.seine-et-marne.fr%2Flilie%2Fc%2Fportal%2Flogin")
Repeat
  event=WaitWindowEvent()
Until event=#PB_Event_CloseWindow

Bonne journée !

[brossden]

Bonjour
Juste une précision tu utilise Mozilla Iexplore ou un autre navigateur ?

[falsam]

Juste aprés ton webgadget ajoutes ce code (Compatible Window Uniquement)

Code : Tout sélectionner

  myBrowser.IWebBrowser2 = GetWindowLong_(GadgetID(#TonWebgadget), #GWL_USERDATA)
  myBrowser\put_Silent(#True) 
  myBrowser\put_Left(50)

J’espère que ça fonctionnera correctement.

[Stefou]

Merci Falsam !

T'es un boss !

Lorsque je surf, je n'ai plus de message d'erreur.

Reste le mini problème sur la page de connexion : je n'arrive pas a changer de champ, juste avec le clavier !
Normalement une pression sur tab et on passe de l'identifiant au mot de passe.

Une idée...sinon tant pis c'est déjà super !

[falsam]

Une idée...sinon tant pis c'est déjà super !

j'ai cherché un peu sur le forum anglais (je n'ai pas tout compris mais ça fonctionne)

Code : Tout sélectionner

Enumeration
  #Mainform
  #Web
EndEnumeration

If OpenWindow(#Mainform, 0, 0, 700, 500, "Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_TitleBar)  
  
  WebGadget(#Web, 10, 10, 680, 480, "http://www.purebasic.fr/french/ucp.php?mode=login") 
  
  ;IWebBrowser2 permet d'accéder aux composants MSIE
  myBrowser.IWebBrowser2 = GetWindowLong_(GadgetID(#Web), #GWL_USERDATA)  
  
  ;Pour répondre à ton message sur les erreurs de script
  myBrowser\put_Silent(#True) 
  myBrowser\put_Left(50)
  
  ;J'ai betement recopié et adapté
  ;http://forum.purebasic.com/english/viewtopic.php?f=13&t=36796&sid=653100f5cab735dd5a69200411294c8b
  CoCreateInstance_(?CLSID_IOleInPlaceActiveObject, 0, 1, ?IID_IOleInPlaceActiveObject,@OleObject.IOleInPlaceActiveObject) 
  MyBrowser\QueryInterface(?IID_IOleInPlaceActiveObject, @OleObject) 
  
  Repeat 
    Event = WaitWindowEvent() 
    Select Event         
        
      Case #WM_KEYDOWN ;Ta touche tabulation
        If EventwParam() = #VK_TAB
          web.MSG\message = event 
          web\wParam = EventwParam() ;Fonction en principe devenu obsolete
          web\lParam = EventlParam() ;Fonction en principe devenu obsolete
          OleObject\TranslateAccelerator(@web) 
          OleObject\Release() 
        EndIf      
        
      Case #PB_Event_CloseWindow 
        End
        
    EndSelect
  ForEver
EndIf 

DataSection 
;{00000117-0000-0000-C000-000000000046} 
IID_IOleInPlaceActiveObject: 
Data.l $00000117 
Data.w $0000, $0000 
Data.b $C0, $00, $00, $00, $00, $00, $00, $46 

;{00000320-0000-0000-C000-000000000046} 
CLSID_IOleInPlaceActiveObject: 
Data.l $00000320 
Data.w $0000, $0000 
Data.b $C0, $00, $00, $00, $00, $00, $00, $46 
EndDataSection

[Stefou]

Alors là !!!! Tu as vraiment assuré !!!!

Je n'aurais jamais trouvé ça.

Bravo et vraiment merci.

[Ar-S]

Je suis aussi bien content de lire ces réponses, surtout le coup de "myBrowser"
Merci bien Falsam