Tabulation et WebGadget()

[GallyHC]

Bonjour tous,

J'ai un petit problème avec WebGadget(), je l'utilise dans pb sur windows pour un formulaire et la tabulation ne fonctionne pas. Y a t'il une chose a modifier ou a ajouter pour que cela fonctionne?

Merci d'avance à tous,
GallyHC

[nico]

Code : Tout sélectionner

 Webbrowser.IWebBrowser2=GetWindowLong_(GadgetID(#Web1), #GWL_USERDATA)

 event=WaitWindowEvent()
  Select event
    Case #WM_KEYDOWN
        If EventwParam()=9 
          hr=Webbrowser2\QueryInterface(?IID_IOleInPlaceActiveObject, @OleObject.IOleInPlaceActiveObject)
          If hr=0 And OleObject>0
            web.MSG\message=event : web\wParam=EventwParam() : web\lParam=EventlParam()
            OleObject\TranslateAccelerator(@web)
            OleObject\Release()
          EndIf
        EndIf


DATASECTION
  IID_IOleInPlaceActiveObject : 
  Data.l $00000117
  Data.w $0000, $0000
  Data.b $C0, $00, $00, $00, $00, $00, $00, $46
ENDDATASECTION

[GallyHC]

Bonjour nico,

Je vais faire ce test au plus vite merci pour le bou de code

Cordialement,
GallyHC

[Mesa]

Pour illustrer voici un exemple fonctionnel, ça peut aider.

Code : Tout sélectionner

;code exemple

#Web1 = 0
 OpenWindow(0,0,0,800,600,"WebGadget",#PB_Window_SystemMenu|#PB_Window_ScreenCentered) 
    WebGadget(#Web1 ,10,10,780,580,"http://www.purebasic.com")

Webbrowser.IWebBrowser2=GetWindowLong_(GadgetID(#Web1), #GWL_USERDATA)

Repeat
event=WaitWindowEvent()
  Select event
    Case #WM_KEYDOWN
        If EventwParam()=9
          hr=Webbrowser\QueryInterface(?IID_IOleInPlaceActiveObject, @OleObject.IOleInPlaceActiveObject)
          If hr=0 And OleObject>0
            web.MSG\message=event : web\wParam=EventwParam() : web\lParam=EventlParam()
            OleObject\TranslateAccelerator(@web)
            OleObject\Release()
          EndIf
        EndIf
EndSelect
Until event= #PB_Event_CloseWindow

DataSection
  IID_IOleInPlaceActiveObject :
  Data.l $00000117
  Data.w $0000, $0000
  Data.b $C0, $00, $00, $00, $00, $00, $00, $46
EndDataSection

[Ar-S]

ça marche au poil, je prends aussi merci !

[GallyHC]

Bonjour tout le monde,

deja encore merci a nico le code été nickel (j'ai du faire quelque modif de presentation on va dire) .

Merci Mesa, mais j'avais deja fait les modifs que j'avais besoin vu que je code avec les directives "EnableExplicit".

Ar-S> c'est bien pratique tu as raisons de mettre cela de cote

Cordialement a tous,
GallyHC