Problème Affichage Sprite en mode fenêtre

[jmg49]

Bonjour,

Je rencontre un problème quand je veux simplement afficher une image en png sur un OpenWindowedScreen, l'image s'affiche bien là où elle devrait mais le programme plante tout seul au bout de quelques secondes, "ne répond pas " s'affiche dans la caption de la fenêtre, je n'ai pas le problème en OpenScreen classique, en fait peut etre mais je ne peux pas voir de message dans la caption cause plein écran ,

j'ai la même chose sur le code que j'avais soumis à votre analyse l'autre jour (sinusscroll, starfield etc...) , en fullscreen ok , en fenêtre, quand ma caméra recule pour inverser le starfield , plantage.

Code : Tout sélectionner

InitSprite()
InitKeyboard()
OpenWindow(0, 0,0,800, 600, "Yep !" , #PB_Window_SystemMenu|#PB_Window_BorderLess |#PB_Window_ScreenCentered )
OpenWindowedScreen(WindowID(0),0,0,800,600)


;OpenScreen(800,600,32,"yep")

UsePNGImageDecoder()

LoadSprite(0, "biolorisk.png")
   

; ************************ Main ***************

Repeat
  
  ExamineKeyboard()
  FlipBuffers () 
  ClearScreen(0)
  
  
 ;DisplayTransparentSprite(0,260,150)
 DisplaySprite(0,260,150)
  
Until KeyboardPushed(#PB_Key_Escape)

End

pourtant y'a rien dans le code !!! aurais je oublié quelque chose ??

Merci

[graph100]

Tu utilises une fenêtre, il te faut donc traiter les évènements liés aux fenêtres.
La commande waitwindowevent() ou windowevent() doit être placée dans ta boucle principale, et traitée.

Code : Tout sélectionner

InitSprite()
InitKeyboard()
OpenWindow(0, 0,0,800, 600, "Yep !" , #PB_Window_SystemMenu|#PB_Window_BorderLess |#PB_Window_ScreenCentered )
OpenWindowedScreen(WindowID(0),0,0,800,600)


;OpenScreen(800,600,32,"yep")

; UsePNGImageDecoder()

CreateSprite(0, 40, 40)


; ************************ Main ***************

Repeat
	
	event = WindowEvent()
	
	ExamineKeyboard()
	FlipBuffers () 
	ClearScreen(RGB(255, 255, 255))
	
	
	;DisplayTransparentSprite(0,260,150)
	DisplaySprite(0,260,150)
	
Until KeyboardPushed(#PB_Key_Escape) Or event = #PB_Event_CloseWindow

End

[Backup]

Arf ! grillé par Graph100

Code : Tout sélectionner

Enumeration
	#win
Endenumeration

Enumeration
	#sprite
EndEnumeration





InitSprite()
InitKeyboard()
OpenWindow(#win, 0,0,800, 600, "Yep !" , #PB_Window_SystemMenu|#PB_Window_BorderLess |#PB_Window_ScreenCentered )
OpenWindowedScreen(WindowID(#win),0,0,800,600)


;OpenScreen(800,600,32,"yep")

UsePNGImageDecoder()

LoadSprite(#sprite, "biolorisk.png")


; ************************ Main ***************

Repeat
	; Ajout Dobro ...... et les Events ??? tu t'en fou des Events ???
	Event= WaitWindowEvent(2)
	; **********************************************
	ExamineKeyboard()
	;DisplayTransparentSprite(#sprite,260,150)
	DisplaySprite(#sprite,260,150)
	FlipBuffers ()
	ClearScreen($0)
Until KeyboardPushed(#PB_Key_Escape)

End
; Epb

[graph100]