[Résolu] texte défilant alterné

Micoute · Message par **Micoute** » sam. 18/oct./2014 17:35

Bonsoir à tous

j'ai un petit problème, je souhaiterais faire un texte défilant un peu particulier, c'est à dire qu'au départ, le texte est complètement à droite, la première lettre va se placer complètement à gauche et quand elle arrivée, la deuxième vient se placer à sa droite, ainsi de suite jusqu'à la dernière, puis la dernière retourne à droite et quand elle est arrivée, c'est au tour de l'avant dernière jusqu'à la première et on recommence le cycle.

Je n'arrive pas à trouver la solution, si vous acceptez de m'aider, je vous serait redevable !

Code : Tout sélectionner

Enumeration Police
  #Police
EndEnumeration

Enumeration Fenetre
  #Fenetre_principale
EndEnumeration

Enumeration Sprite
  #Txt_1
  #Txt_2
  #Txt_3
  #Txt_4
  #Txt_5
  #Txt_6
  #Txt_7
EndEnumeration

Global largeur = GetSystemMetrics_(#SM_CXSCREEN), hauteur = GetSystemMetrics_(#SM_CYSCREEN), y = hauteur - 70

If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0 And InitSound() = 0
  MessageRequester("Erreur", "Le système Sprite ne peut pas être initialisé !", #MB_ICONERROR)
  End
EndIf

OpenScreen(largeur, hauteur, 32, "Sprite police")
  LoadFont(#Police, "Arial", 25)
  
  CreateSprite(#Txt_1, 25, 38)
  CreateSprite(#Txt_2, 8, 38)
  CreateSprite(#Txt_3, 24, 38)
  CreateSprite(#Txt_4, 26, 38)
  CreateSprite(#Txt_5, 23, 38)
  CreateSprite(#Txt_6, 21, 38)
  CreateSprite(#Txt_7, 22, 38)
  
  StartDrawing(SpriteOutput(#Txt_1))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "M", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_2))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "I", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_3))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "C", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_4))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "O", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_5))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "U", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_6))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "T", $87E34C, $FFFFFF)
  StopDrawing()
  
  StartDrawing(SpriteOutput(#Txt_7))
  DrawingFont(FontID(#Police))
  DrawText(0, 0, "E", $87E34C, $FFFFFF)
  StopDrawing()
  


  Repeat
    FlipBuffers()
    Delay(100)
  ClearScreen($FFFFFF)
  
  
  XD1 = 0 : XF1 = 1779 : x1 = xf1
  XD2 = 25 : XF2 = 1804 : x2 = xf2
  XD3 = 32 : XF3 = 1812 : x3 = xf3
  XD4 = 54 : XF4 = 1836 : x4 = xf4
  XD5 = 78 : XF5 = 1860 : x5 = xf5
  XD6 = 101 : XF6 = 1882 : x6 = xf6
  XD7 =121 : XF7 = 1900 : x7 = xf7
  
  DisplaySprite(#Txt_1, xf1, y) ; M
  While x1 > xd1
    DisplaySprite(#Txt_1, x1, y)
    x1 - 1
  Wend
  
  DisplaySprite(#Txt_2, xf2, y) ; I
  While x2 > xd2
    DisplaySprite(#Txt_2, x2, y)
    x2 - 1
  Wend
  
  DisplaySprite(#Txt_3, xf3, y) ; C
  While x3 > xd3
    DisplaySprite(#Txt_3, x3, y)
    x3 - 1
  Wend
  
  DisplaySprite(#Txt_4, xf4, y) ; O
  While x4 > xd4
    DisplaySprite(#Txt_4, x4, y)
    x4 - 1
  Wend
  
  DisplaySprite(#Txt_5, xf5, y) ; U
  While x5 > xd5
    DisplaySprite(#Txt_5, x5, y)
    x5 - 1
  Wend
  
  DisplaySprite(#Txt_6, xf6, y) ; T
  While x6 > xd6
    DisplaySprite(#Txt_6, x6, y)
    x6 - 1
  Wend
  
  DisplaySprite(#Txt_7, xf7, y) ; E
  While x7 > xd7
    DisplaySprite(#Txt_7, x7, y)
    x7 - 1
  Wend
  
  DisplaySprite(#Txt_7, xd7, y) ; E
  While x7 < xf7
    DisplaySprite(#Txt_7, x7, y)
    x7 + 1
  Wend
  
  DisplaySprite(#Txt_6, xd6, y) ; T
  While x6 < xf6
    DisplaySprite(#Txt_6, x6, y)
    x6 + 1
  Wend
  
  DisplaySprite(#Txt_5, xd5, y) ; U
  While x5 < xf5
    DisplaySprite(#Txt_5, x5, y)
    x5 + 1
  Wend
  
  DisplaySprite(#Txt_4, xd4, y) ; O
  While x4 < xf4
    DisplaySprite(#Txt_4, x4, y)
    x4 + 1
  Wend
  
  DisplaySprite(#Txt_3, xd3, y) ; C
  While x3 < xf3
    DisplaySprite(#Txt_3, x3, y)
    x3 + 1
  Wend
  
  DisplaySprite(#Txt_2, xd2, y) ; I
  While x2 < xf2
    DisplaySprite(#Txt_2, x2, y)
    x2 + 1
  Wend
  
  DisplaySprite(#Txt_1, xd1, y) ; M
  While x1 < xf1
    DisplaySprite(#Txt_1, x1, y)
    x1 + 1
  Wend
  
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape)

comtois · Message par **comtois** » sam. 18/oct./2014 18:36

un début de solution

Code : Tout sélectionner

If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0 And InitSound() = 0
  MessageRequester("Erreur", "Le système Sprite ne peut pas être initialisé !")
  End
EndIf

Structure S_Sprite
  No.i
  x.i
  y.i
  Width.i
  Height.i
EndStructure

Dim Alphabet.S_sprite(26)
NewList Sprite.S_Sprite()

#Police = 0

ExamineDesktops()
Global largeur = DesktopWidth(0), hauteur = DesktopHeight(0), y = hauteur - 70


OpenScreen(largeur, hauteur, 32, "Sprite police")
LoadFont(#Police, "Arial", 25)

StartDrawing(ScreenOutput())
DrawingFont(FontID(#Police))
For i='A' To 'Z' 
  T$ = Chr(i)
  Alphabet(i-'A')\Width = TextWidth(T$)
  Alphabet(i-'A')\Height = TextHeight(T$)
Next
StopDrawing()

For i='A' To 'Z'
  CreateSprite(i-'A', Alphabet(i-'A')\Width, Alphabet(i-'A')\Height)
  StartDrawing(SpriteOutput(i-'A'))
  DrawingFont(FontID(#Police))
  
  DrawingMode(#PB_2DDrawing_Transparent)  
  DrawText(0,0,Chr(i), RGB(255,0,0))
  
  StopDrawing()
Next



Texte$="MICOUTE"

StartX=Largeur
EndX=Largeur-400
Compteur = 1
Lettre$= Mid(Texte$, Compteur, 1)
Repeat
  FlipBuffers()
  ClearScreen($FFFFFF)
  
  ForEach Sprite()
    DisplayTransparentSprite(Sprite()\No, Sprite()\x,40)
  Next  
  
  
  DisplayTransparentSprite(Asc(Lettre$)-'A', StartX,40)
  
  If StartX > EndX
    StartX - 1
  ElseIf Compteur < Len(Texte$)
    AddElement(Sprite())
    Sprite()\x = StartX
    Sprite()\No = Asc(Lettre$)-'A'
    Compteur + 1
    EndX=Alphabet(Asc(Lettre$)-'A')\Width+StartX
    Lettre$= Mid(Texte$, Compteur, 1)
    StartX=Largeur
  EndIf
  
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape)

Micoute · Message par **Micoute** » sam. 18/oct./2014 19:41

Bonsoir comtois et merci énormément, je suis tellement surpris du résultat que j'en reste bouche bée ! C'est tellement magnifique !

comtois · Message par **comtois** » sam. 18/oct./2014 19:53

faut pas, le code ci-dessus ne répond pas au cahier des charges

en voici un autre

Code : Tout sélectionner

If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0 And InitSound() = 0
  MessageRequester("Erreur", "Le système Sprite ne peut pas être initialisé !")
  End
EndIf

Structure S_Sprite
  No.i
  x.i
  y.i
  Width.i
  Height.i
EndStructure
Structure S_SpriteAnim
  No.i
  x.i
  y.i
  LeftX.i
  RightX.i
EndStructure

Dim Alphabet.S_sprite(26)

#Police = 0

ExamineDesktops()
Global largeur = DesktopWidth(0), hauteur = DesktopHeight(0), y = hauteur - 70


OpenScreen(largeur, hauteur, 32, "Sprite police")
LoadFont(#Police, "Arial", 25)

StartDrawing(ScreenOutput())
DrawingFont(FontID(#Police))
For i='A' To 'Z' 
  T$ = Chr(i)
  Alphabet(i-'A')\Width = TextWidth(T$)
  Alphabet(i-'A')\Height = TextHeight(T$)
Next
StopDrawing()

For i='A' To 'Z'
  CreateSprite(i-'A', Alphabet(i-'A')\Width, Alphabet(i-'A')\Height)
  StartDrawing(SpriteOutput(i-'A'))
  DrawingFont(FontID(#Police))
  
  DrawingMode(#PB_2DDrawing_Transparent)  
  DrawText(0,0,Chr(i), RGB(255,0,0))
  
  StopDrawing()
Next



Texte$="MICOUTE"

Dim Sprite.S_SpriteAnim(Len(Texte$))

For i=1 To Len(Texte$) 
  Lettre$= Mid(Texte$, i, 1)
  Sprite(i)\No = Asc(Lettre$)-'A'
  If i = 1
    Sprite(i)\LeftX = largeur/1.5
  Else
    Sprite(i)\LeftX = Sprite(i-1)\LeftX+ SpriteWidth(Sprite(i-1)\No)
  EndIf
Next

For i=Len(Texte$) To 1 Step-1
  If i = Len(Texte$)
    Sprite(i)\RightX = Largeur-SpriteWidth(Sprite(i)\No)
  Else
    Sprite(i)\RightX = Sprite(i+1)\RightX - SpriteWidth(Sprite(i)\No)
  EndIf
  Sprite(i)\x = Sprite(i)\RightX 
  Sprite(i)\y = 40
Next

Sens = -1
Compteur = 1

Repeat
  FlipBuffers()
  ClearScreen($FFFFFF)
  
  If sens = -1
    If Sprite(Compteur)\x>Sprite(Compteur)\LeftX
      Sprite(Compteur)\x - 1
    Else
      Compteur + 1
      If Compteur > Len(Texte$)
        Compteur = Len(Texte$)
        sens = -sens
      EndIf
    EndIf  
  Else
    If Sprite(Compteur)\x<Sprite(Compteur)\RightX
      Sprite(Compteur)\x + 1
    Else
      Compteur - 1
      If Compteur < 1
        Compteur = 1
        sens = -sens
      EndIf
    EndIf 
  EndIf
   
  For i = 1 To Len(Texte$)
    DisplayTransparentSprite(Sprite(i)\No, Sprite(i)\x,Sprite(i)\y)
  Next  
    
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape)

comtois · Message par **comtois** » sam. 18/oct./2014 21:47

Avec une interpolation linéaire pour accélérer les déplacements.

J'arrête là, je te laisse le soin de simplifier le code.

Code : Tout sélectionner

If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0 And InitSound() = 0
  MessageRequester("Erreur", "Le système Sprite ne peut pas être initialisé !")
  End
EndIf

Structure S_Sprite
  No.i
  x.i
  y.i
  Width.i
  Height.i
EndStructure
Structure S_SpriteAnim
  No.i
  x.f
  y.f
  LeftX.i
  RightX.i
EndStructure

Macro NextCompteur
  Compteur - sens
  If Compteur > Len(Texte$)
    Compteur = Len(Texte$)
    sens = -sens
  ElseIf Compteur < 1
    Compteur = 1
    sens = -sens
  EndIf  
EndMacro

Dim Alphabet.S_sprite('z'-' '+1)

#Police = 0

ExamineDesktops()
Global largeur = DesktopWidth(0), hauteur = DesktopHeight(0), y = hauteur - 70

Declare.f Interpolation(x1.f, x2.f, percent.f)

OpenScreen(largeur, hauteur, 32, "Sprite police")
LoadFont(#Police, "Arial", 48, #PB_Font_Bold)

StartDrawing(ScreenOutput())
DrawingFont(FontID(#Police))
For i=' ' To 'z' 
  T$ = Chr(i)
  Alphabet(i-' ')\Width = TextWidth(T$)
  Alphabet(i-' ')\Height = TextHeight(T$)
Next
StopDrawing()

For i=' ' To 'z'
  CreateSprite(i-' ', Alphabet(i-' ')\Width, Alphabet(i-' ')\Height)
  StartDrawing(SpriteOutput(i-' '))
  DrawingFont(FontID(#Police))
  
  DrawingMode(#PB_2DDrawing_Transparent)  
  DrawText(2,2,Chr(i), RGB(245,245,45))
  DrawText(0,0,Chr(i), RGB(250, 50, 50))
  
  StopDrawing()
Next

Texte$="Salut le monde 123 !"

Dim Sprite.S_SpriteAnim(Len(Texte$))

For i=1 To Len(Texte$) 
  Lettre$= Mid(Texte$, i, 1)
  Sprite(i)\No = Asc(Lettre$)-' '
  If i = 1
    Sprite(i)\LeftX = 0
  Else
    Sprite(i)\LeftX = Sprite(i-1)\LeftX+ SpriteWidth(Sprite(i-1)\No)
  EndIf
Next

For i=Len(Texte$) To 1 Step-1
  If i = Len(Texte$)
    Sprite(i)\RightX = Largeur-SpriteWidth(Sprite(i)\No)
  Else
    Sprite(i)\RightX = Sprite(i+1)\RightX - SpriteWidth(Sprite(i)\No)
  EndIf
  Sprite(i)\x = Sprite(i)\RightX 
  Sprite(i)\y = 40
Next

Sens = -1
Compteur = 1
Vitesse.f = 0.08

Repeat
  FlipBuffers()
  ClearScreen(0)
  
  If sens = -1
    If Sprite(Compteur)\x>Sprite(Compteur)\LeftX
      Sprite(Compteur)\x = Interpolation(Sprite(Compteur)\x, Sprite(Compteur)\LeftX, Vitesse)
      If Sprite(Compteur)\x-1< Sprite(Compteur)\LeftX
        Sprite(Compteur)\x=Sprite(Compteur)\LeftX
      EndIf
      
    Else
      Repeat
        NextCompteur
      Until Mid(Texte$, Compteur, 1) <> " "
    EndIf  
  Else
    If Sprite(Compteur)\x<Sprite(Compteur)\RightX
      Sprite(Compteur)\x = Interpolation(Sprite(Compteur)\x, Sprite(Compteur)\RightX, Vitesse)
      If Sprite(Compteur)\x+1> Sprite(Compteur)\RightX
        Sprite(Compteur)\x=Sprite(Compteur)\RightX
      EndIf
    Else
      Repeat
        NextCompteur
      Until Mid(Texte$, Compteur, 1) <> " " 
    EndIf 
  EndIf
  
  For i = 1 To Len(Texte$)
    DisplayTransparentSprite(Sprite(i)\No, Sprite(i)\x,Sprite(i)\y)
  Next  
  
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape)  

Procedure.f Interpolation(x1.f, x2.f, percent.f)
  If percent<0
    percent=0
  EndIf
  If percent>1
    percent=1
  EndIf
  ProcedureReturn x1 + percent * (x2 - x1)
  
EndProcedure

Lord Nelson · Message par **Lord Nelson** » sam. 18/oct./2014 22:06

Jolie

Micoute · Message par **Micoute** » dim. 19/oct./2014 9:54

Bonjour comtois, que de surprises ce matin à mon réveil, en plus c'est beaucoup mieux que ce que j'avais oser rêver, en un mot "SUBLISSIME" !

Je te remercie énormément pour ce sublime travail !

comtois · Message par **comtois** » dim. 19/oct./2014 16:14

J"ai édité le dernier code ci-dessus pour prendre en compte plus de caractères (minuscules, chiffre, etc)

et un dernier code pour le fun, bougez la souris.

Code : Tout sélectionner

If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0 And InitSound() = 0
  MessageRequester("Erreur", "Le système Sprite ne peut pas être initialisé !")
  End
EndIf

Structure S_Sprite
  No.i
  x.f
  y.f
  Width.i
  Height.i
EndStructure

Dim Alphabet.S_sprite('z'-' '+1)

#Police = 0

ExamineDesktops()
Global largeur = DesktopWidth(0), hauteur = DesktopHeight(0), y = hauteur - 70

Declare.f Interpolation(x1.f, x2.f, percent.f)

OpenScreen(largeur, hauteur, 32, "Sprite police")
LoadFont(#Police, "Arial", 48, #PB_Font_Bold)

StartDrawing(ScreenOutput())
DrawingFont(FontID(#Police))
For i=' ' To 'z'
  T$ = Chr(i)
  Alphabet(i-' ')\Width = TextWidth(T$)
  Alphabet(i-' ')\Height = TextHeight(T$)
Next
StopDrawing()

For i=' ' To 'z'
  CreateSprite(i-' ', Alphabet(i-' ')\Width, Alphabet(i-' ')\Height)
  StartDrawing(SpriteOutput(i-' '))
  DrawingFont(FontID(#Police))
  
  DrawingMode(#PB_2DDrawing_Transparent) 
  DrawText(2,2,Chr(i), RGB(245,245,45))
  DrawText(0,0,Chr(i), RGB(250, 50, 50))
  
  StopDrawing()
Next

Mouse = CreateSprite(#PB_Any, 32, 32)
StartDrawing(SpriteOutput(Mouse))
Circle(16, 16, 4, RGB(255, 255, 255)) 
StopDrawing()

Texte$="Salut le monde 123 !"

Dim Sprite.S_Sprite(Len(Texte$))

For i=1 To Len(Texte$)
  Lettre$= Mid(Texte$, i, 1)
  Sprite(i)\No = Asc(Lettre$)-' '
Next

Sens = -1
Compteur = 1
Vitesse.f = 0.08
Dernier = Len(Texte$)

Repeat
  FlipBuffers()
  ClearScreen(0)
  ExamineMouse() 
  
  Sprite(Dernier)\x = Interpolation(Sprite(Dernier)\x, MouseX(), Vitesse)
  Sprite(Dernier)\y = Interpolation(Sprite(Dernier)\y, MouseY(), Vitesse)
  DisplayTransparentSprite(Sprite(Dernier)\No, Sprite(Dernier)\x,Sprite(Dernier)\y)
  DisplayTransparentSprite(Mouse, MouseX(), MouseY())
  
  For i = Len(Texte$)-1 To 1 Step -1
    Sprite(i)\x = Interpolation(Sprite(i)\x, Sprite(i+1)\x-SpriteWidth(Sprite(i)\No), Vitesse)
    Sprite(i)\y = Interpolation(Sprite(i)\y, Sprite(i+1)\y, Vitesse)
    DisplayTransparentSprite(Sprite(i)\No, Sprite(i)\x,Sprite(i)\y)
  Next 
   
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape) 

Procedure.f Interpolation(x1.f, x2.f, percent.f)
  If percent<0
    percent=0
  EndIf
  If percent>1
    percent=1
  EndIf
  ProcedureReturn x1 + percent * (x2 - x1)
  
EndProcedure

Mindphazer · Message par **Mindphazer** » dim. 19/oct./2014 19:23

Très cool

Faut juste virer le ", #MB_ICONERROR" du MessageRequester, et le code est crossplatform

kernadec · Message par **kernadec** » dim. 19/oct./2014 19:41

bonsoir
Merci comtois pour le partage
C'est cool

je vais l'utiliser ce code pour balader mes signes du zodiaque sur mon écran

Cordialement

Micoute · Message par **Micoute** » lun. 20/oct./2014 9:11

Bonjour comtois, quand je disais que c'était magnifique, je n'envisageais pas à ce qu'on puisse faire encore mieux !
Grand merci à Fred sans qui tout ça n'existerait pas !

PureBasic

[Résolu] texte défilant alterné

[Résolu] texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné

Re: texte défilant alterné