AddKeyboardShortcut indomptable... [Résolu]

[SPH]

Salut a tous,

Je n'arrive pas a créer un "AddKeyboardShortcut" (je ne l'ai jamais fait; faut bien une premiere fois).
Ici, je voudrais que quand j'appuie sur ESC, ca fasse un END (regardez la ligne 44 et 45)

Code : Tout sélectionner

InitSprite()
InitKeyboard()
InitMouse()



If OpenWindow(0, 0, 0, 0,0, " Polygons_Maker",#PB_Window_Maximize|#PB_Window_BorderLess)=0
  Beep_(500,250) : Delay(150) : Beep_(500,250)
  Debug ("OpenWindow() impossible")
  End
EndIf

If OpenGLGadget(1,0,0,1920,1080)=0
  Beep_(500,250) : Delay(150) : Beep_(500,250)
  Debug ("OpenGLGadget() impossible")
  End
EndIf


AddKeyboardShortcut(0,  #PB_Shortcut_Escape, 666)


Repeat
  
  key = GetGadgetAttribute(1, #PB_OpenGL_Key)
  

  SetGadgetAttribute(1,#PB_OpenGL_FlipBuffers,#True)
  
  StopDrawing()
  
  ;  Repeat
  Event = WaitWindowEvent()
  
  Select Event
      
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 1
          Select EventType()
            Case #PB_EventType_LeftClick        : Debug "Clic avec le bouton gauche de la souris"
            Case #PB_EventType_RightClick       : Debug "Clic avec le bouton droit de la souris"
          EndSelect
        Case 666 ; ?????????
          End
          
      EndSelect
      
  EndSelect
  
ForEver

Grand merci a l'avance...

[Mindphazer]

Les raccourcis clavier sont assimilés à des événements de type menu
Il faut donc que tu fasses un truc du style :

Code : Tout sélectionner

Case #PB_Event_Menu
  Select EventMenu()
    Case 666...
  EndSelect

[Mindphazer]

Ton code complet :

Code : Tout sélectionner

InitSprite()
InitKeyboard()
InitMouse()



If OpenWindow(0, 0, 0, 0,0, " Polygons_Maker",#PB_Window_Maximize|#PB_Window_BorderLess)=0
  Beep_(500,250) : Delay(150) : Beep_(500,250)
  Debug ("OpenWindow() impossible")
  End
EndIf

If OpenGLGadget(1,0,0,1920,1080)=0
  Beep_(500,250) : Delay(150) : Beep_(500,250)
  Debug ("OpenGLGadget() impossible")
  End
EndIf



AddKeyboardShortcut(0,  #PB_Shortcut_Escape, 666)


Repeat
  
  key = GetGadgetAttribute(1, #PB_OpenGL_Key)
  

  SetGadgetAttribute(1,#PB_OpenGL_FlipBuffers,#True)
  
  StopDrawing()
  
  ;  Repeat
  Event = WaitWindowEvent()
  
  Select Event
      
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 1
          Select EventType()
            Case #PB_EventType_LeftClick        : Debug "Clic avec le bouton gauche de la souris"
            Case #PB_EventType_RightClick       : Debug "Clic avec le bouton droit de la souris"
          EndSelect
        ;Case #KeyESC ; ?????????
        ;  End
          
      EndSelect
    Case #PB_Event_Menu
      Select EventMenu()
        Case 666
          End
      EndSelect
  EndSelect
  
ForEver

[SPH]

Merci beaucoup, je n'y serais pas arrivé sans ton aide

[venom]

En même temps c'est bien connu, on ne met pas 666 comme label. C'est le diable assuré






@++

[SPH]

En même temps c'est bien connu, on ne met pas 666 comme label. C'est le diable assuré

Pour faire un End, il fallait bien ça

[falsam]

Résolu ok mais ce n'est pas la bonne solution

Une lecture de la documentation sur OpenGLGadget() t'aurais donnée une solution sans passer par l'ajout d'une touche de raccourci.

https://www.purebasic.com/french/docume ... adget.html

Voici un code pour tester les événements clavier/souris de ton OpenGLGadget().

Code : Tout sélectionner

EnableExplicit

Global window, ww = 800, wh = 600, viewport, Key

OpenWindow(#PB_Any, 0, 0, ww, wh, "Test Opengl", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)

viewport = OpenGLGadget(#PB_Any, 0, 0, ww, wh, #PB_OpenGL_NoDepthBuffer | #PB_OpenGL_Keyboard)
SetActiveGadget(viewport)

While #True
  Repeat     
    Select EventType()
        
      Case #PB_EventType_KeyDown  ;Une touche a été pressée (Exemple les fléches du clavier)
         Key = GetGadgetAttribute(viewport, #PB_OpenGL_Key)
        Select Key
          Case #PB_Shortcut_Left
            Debug "Left : Fleche gauche"
            
          Case #PB_Shortcut_Right
            Debug "Right : Fleche droite"            
        EndSelect
                
      Case #PB_EventType_KeyUp  ;Une touche a été relâchée (Exemple Escape)
        Key = GetGadgetAttribute(viewport, #PB_OpenGL_Key)
        Select Key
          Case #PB_Shortcut_Escape
            Debug "Esc : Je sors"
            End   
        EndSelect
        
      Case #PB_EventType_LeftButtonDown ;Le bouton gauche de la souris a été pressé    
        Debug "Bouton gauche de la souris"
    EndSelect
  Until WindowEvent() = 0
Wend

Tu peux tester la touche Escape, Fleche gauche et droite et Clic Gauche sur l'OpenGLGadget.