explorer Temporary Internet Files

venom · Message par **venom** » ven. 03/août/2007 11:02

bonjour, et bien voila j'ai crée une fenetre avec un ExplorerListGadget

et quand je vais dans le dossier Temporary Internet Files et bien je ne voie aucun fichier

.

seriez vous me dire pourquoi on ne voie rien dans ce dossier ?

d'avance merci.

@++

Anonyme · Message par **Anonyme** » ven. 03/août/2007 12:07

fichier caché ? non?

flaith · Message par **flaith** » ven. 03/août/2007 12:23

quel répertoire ? (ex : C:\Documents and Settings\<user>\Local Settings\Temporary Internet Files) ?

SpaceMan · Message par **SpaceMan** » ven. 03/août/2007 13:22

@ Venom

bonjour, et bien voila j'ai crée une fenetre avec un ExplorerListGadget

et quand je vais dans le dossier Temporary Internet Files et bien je ne voie aucun fichier .

je confirme qu'on ne voit rien dans ce dosssier lorsqu'on l'ouvre dans ExplorerListGadget. Pourtant pleins de fichiers cookies s'y trouvent et ce ne sont meme pas des fichiers cachés.

flaith · Message par **flaith** » ven. 03/août/2007 19:55

sous Win2K + PB 4.10B2 => marche nickel

Flype · Message par **Flype** » ven. 03/août/2007 20:45

avec l'exemple de la doc çà fonctionne chez moi, je vois les fichiers et les dossiers. windows xp sp2 - pb4.10b2.

Code : Tout sélectionner

  If OpenWindow(0, 0, 0, 400, 200, "ExplorerListGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) And CreateGadgetList(WindowID(0))
    ExplorerListGadget(0, 10, 10, 380, 180, "*.*", #PB_Explorer_MultiSelect)
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

venom · Message par **venom** » ven. 03/août/2007 23:24

bonsoir tout le monde,

@flype

avec l'exemple de la doc çà fonctionne chez moi, je vois les fichiers et les dossiers. windows xp sp2 - pb4.10b2.

ecoute j'ai la meme configuration que toi et moi j'ai rien du tout

.
la preuve

c'est bizarre quand meme.

@++

Flype · Message par **Flype** » ven. 03/août/2007 23:40

oui moi pareil.

mais si tu rentres dans Content.IE5 il y a pleins de dossiers dedans dans lesquels on trouve les fichiers temp et les cookies

c'est vrai que l'affichage est different entre le résultat produit par l'ExplorerListGadget et l'Explorateur Windows pour des raisons de sécurités peut être.

venom · Message par **venom** » ven. 03/août/2007 23:48

oui c'est surement pour des raisons de securite tant pi

.

@++

Flype · Message par **Flype** » sam. 04/août/2007 0:51

sinon il y a moyen de lister les fichiers temp internet via les api win32.

http://msdn2.microsoft.com/en-us/library/aa384026.aspx

j'ai pas cherché plus que çà mais en gros voilà :

Code : Tout sélectionner

#NORMAL_CACHE_ENTRY        = $00000001
#STABLE_CACHE_ENTRY        = $00000002
#STICKY_CACHE_ENTRY        = $00000004
#COOKIE_CACHE_ENTRY        = $00100000
#URLHISTORY_CACHE_ENTRY    = $00200000
#TRACK_OFFLINE_CACHE_ENTRY = $00000010
#TRACK_ONLINE_CACHE_ENTRY  = $00000020
#SPARSE_CACHE_ENTRY        = $00010000
#OCX_CACHE_ENTRY           = $00020000

Structure INTERNET_CACHE_ENTRY_INFO
  dwStructSize.l
  lpszSourceUrlName.s
  lpszLocalFileName.s
  CacheEntryType.l
  dwUseCount.l
  dwHitRate.l
  dwSizeLow.l
  dwSizeHigh.l
  LastModifiedTime.FILETIME
  ExpireTime.FILETIME
  LastAccessTime.FILETIME
  LastSyncTime.FILETIME
  lpHeaderInfo.l
  dwHeaderInfoSize.l
  lpszFileExtension.s
  StructureUnion 
    dwReserved.l
    dwExemptDelta.l
  EndStructureUnion
  buffer.b[4096]
EndStructure

info.INTERNET_CACHE_ENTRY_INFO

size.l = SizeOf(INTERNET_CACHE_ENTRY_INFO)

info\dwStructSize = SizeOf(INTERNET_CACHE_ENTRY_INFO)

hFile = FindFirstUrlCacheEntry_("", @info, @size)

If hFile 
  
  While FindNextUrlCacheEntry_(hFile, @info, @size) <> -1 And GetLastError_() <> #ERROR_NO_MORE_ITEMS
    Debug info\CacheEntryType
    Debug info\lpszLocalFileName
    Debug info\lpszSourceUrlName
  Wend
  
  FindCloseUrlCache_(hFile)
  
EndIf

venom · Message par **venom** » sam. 04/août/2007 9:02

bonjour,

je t'en remercie flype pour ce bout de code je vais le garder de cote voir ce que je peut en faire .

@++

venom · Message par **venom** » sam. 04/août/2007 14:00

dit Flype ,

j'ai regarder ton code mais je ne voie pas quel fonction tu a utilisé pour arrivé directement dans le dossier Temporary Internet Files.

merci

@++

Droopy · Message par **Droopy** » lun. 06/août/2007 21:33

Il a utilisé l'APi Win32 pour visualiser les fichier inclus dans le cache de IE.
Voici une version graphique :

Code : Tout sélectionner

;/ james / hi - toro / Flype

;{ Cache Functions & Structure

Structure INTERNET_CACHE_ENTRY_INFO 
  dwStructSize.l 
  lpszSourceUrlName.s 
  lpszLocalFileName.s 
  CacheEntryType.l 
  dwUseCount.l 
  dwHitRate.l 
  dwSizeLow.l 
  dwSizeHigh.l 
  LastModifiedTime.FILETIME 
  ExpireTime.FILETIME 
  LastAccessTime.FILETIME 
  LastSyncTime.FILETIME 
  lpHeaderInfo.l 
  dwHeaderInfoSize.l 
  lpszFileExtension.s 
  StructureUnion 
    dwReserved.l 
    dwExemptDelta.l 
  EndStructureUnion 
  Buffer.b[4096] 
EndStructure 

Structure CacheEntry
  Type.s
  Name.s
  Url.s
EndStructure

Procedure IE6CacheEntry()
  Static Init
  If Init=0
    Global NewList IE6CacheEntry_LList.CacheEntry()
    Init=1
  Else
    ClearList(IE6CacheEntry_LList())
  EndIf
  
  info.INTERNET_CACHE_ENTRY_INFO 
  Size.l = SizeOf(INTERNET_CACHE_ENTRY_INFO) 
  info\dwStructSize = SizeOf(INTERNET_CACHE_ENTRY_INFO) 
  hFile = FindFirstUrlCacheEntry_(EntryType, @info, @Size) 
  
  If hFile
    
    Repeat
      AddElement(IE6CacheEntry_LList())
      If info\CacheEntryType & $00100000        ; #COOKIE_CACHE_ENTRY
        IE6CacheEntry_LList()\Type="Cookie"
      ElseIf info\CacheEntryType & $00200000    ; #URLHISTORY_CACHE_ENTRY
        IE6CacheEntry_LList()\Type="History"
      Else
        IE6CacheEntry_LList()\Type="Other"
      EndIf
      
      IE6CacheEntry_LList()\Name=info\lpszLocalFileName 
      IE6CacheEntry_LList()\Url=info\lpszSourceUrlName 
      
    Until FindNextUrlCacheEntry_(hFile, @info, @Size) = -1 Or GetLastError_() = #ERROR_NO_MORE_ITEMS 
    FindCloseUrlCache_(hFile) 
  EndIf 
  
  ProcedureReturn CountList(IE6CacheEntry_LList())
EndProcedure

Procedure DeleteIE6CacheEntryType(Type.s) ; Cookie / History / Other / All
  ForEach IE6CacheEntry_LList()
    If UCase(IE6CacheEntry_LList()\Type)=UCase(Type) Or UCase(Type)="ALL"
      DeleteUrlCacheEntry_(IE6CacheEntry_LList()\Url)
      DeleteElement(IE6CacheEntry_LList())
    EndIf
  Next
EndProcedure

;}

Enumeration
  #Liste
  #Status
  
  #Menu
  #Cookie
  #History
  #Other
  #All
  
  #Refresh
  
EndEnumeration

Procedure ShowCacheEntry()
  ClearGadgetItemList(#Liste)
  
  Entrees=IE6CacheEntry()
  StatusBarText(#Status,0,"  "+Str(Entrees)+" entrées")
  
  If Entrees
    ForEach IE6CacheEntry_LList()
    AddGadgetItem(#Liste,-1, IE6CacheEntry_LList()\Name+Chr(10)+ IE6CacheEntry_LList()\Url +Chr(10)+ IE6CacheEntry_LList()\Type)
    Next
  EndIf

EndProcedure

;{/ Visual
OpenWindow(0,0,0,640,480,"IE6CacheEntry", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
CreateGadgetList(WindowID(0))
ListIconGadget(#Liste,10,10,620,420,"Name",250, #PB_ListIcon_FullRowSelect|#PB_ListIcon_AlwaysShowSelection)
AddGadgetColumn(#Liste,1, "URL", 250)
AddGadgetColumn(#Liste,2, "Type", 100)
CreateStatusBar(#Status,WindowID(0))
CreateMenu(#Menu,WindowID(0))
MenuTitle("Entry")
OpenSubMenu("Delete")
MenuItem(#Cookie,"Cookie")
MenuItem(#History,"History")
MenuItem(#Other,"Other")
MenuItem(#All,"All")
CloseSubMenu()
MenuItem(#Refresh,"Refresh")
;}

ShowCacheEntry()

;{/ Event Management
Repeat
  Evt = WaitWindowEvent()
  If Evt=#PB_Event_Menu
  Select EventMenu()
  Case #Cookie
    DeleteIE6CacheEntryType("Cookie")
    ShowCacheEntry()
  Case #History
    DeleteIE6CacheEntryType("History")
    ShowCacheEntry()
  Case #Other
    DeleteIE6CacheEntryType("Other")
    ShowCacheEntry()
  Case #All
    DeleteIE6CacheEntryType("All")
    ShowCacheEntry()
  Case #Refresh
    ShowCacheEntry()
  EndSelect
EndIf
Until Evt = #PB_Event_CloseWindow
;}