probleme avec le TrackBarGadget()

[samy97]

bonjour
je suis debutant avec le pure basic et j'ai un petit probleme:
je n'arive pas a utiliser le TrackBarGadget() dans mon prograe ,c'est pur pouvoir regler le son dans un lecteur style "VLC" avec la fonction MovieAudio().
si quelqu'un povais m'expliquer comment fair ?
merci d'avance.
samy97

mon code est::

Code : Tout sélectionner

#fenetre=0
#absis_fenetre=10
#ordone_fenetre=10
#hauteure_fenetre=90
#largeur_fenetre=290
OpenWindow(#fenetre,#absis_fenetre,#ordone_fenetre,#largeur_fenetre,#hauteure_fenetre,"SamyMediaPlayer",#PB_Window_SystemMenu|#PB_Window_SizeGadget|#PB_Window_BorderLess)

FenetreID = WindowID(#fenetre)
CreateGadgetList(FenetreID)
InitMovie()
#editor = 1
#buttonPlay = 2
#buttonStop = 3
#buttonPose = 4
#buttonResume =5
EditorGadget(#editor,10,10,270,40,#PB_Editor_ReadOnly)
ButtonGadget(#buttonPlay,10,60,30,20,"play")
ButtonGadget(#buttonStop,50,60,30,20,"stop")
ButtonGadget(#buttonPose,90,60,40,20,"pause")
ButtonGadget(#buttonResume,140,60,50,20,"continue")
Resultat = TrackBarGadget(6,200,60,80,20,0,100,#PB_TrackBar_Ticks)

Repeat
event=WaitWindowEvent()
If event =#PB_Event_Gadget
clicgadget = EventGadget()
Else
clicgadget=0
EndIf

If clicgadget= #buttonPlay

MovieName$ = OpenFileRequester("Choisis ton son", "", "Audio files|*.mp3;*.wma|All Files|*.*", 0)
If MovieName$
  If LoadMovie(#fenetre, MovieName$)
    PlayMovie(#fenetre, WindowID(#fenetre))
     SetGadgetText(#editor,MovieName$)
     ;-ici mon probleme
     ;****************************************************************************************
       If clicgadget = 6
       Resultat = GetGadgetState(6)
       MovieAudio(#fenetre,Resultat ,0)
       EndIf
     ;****************************************************************************************  
  Else
    MessageRequester("Error", "impossible de lire ce son...", 0)
  EndIf
EndIf 
EndIf


If clicgadget= #buttonStop
StopMovie(#fenetre)
EndIf

If clicgadget= #buttonPose
PauseMovie(#fenetre)
EndIf

If clicgadget= #buttonResume
ResumeMovie(#fenetre)
EndIf

Until event=#PB_Event_CloseWindow

ce n'est qu'un debut et je compte bien l'ameliorer!!!

[Ollivier]

Salut et bienvenu,

J'ai déplacé la gestion du volume HORS de la gestion de mise en lecture (sinon le son n'était modifiable qu'au chargement d'un son et non tout le temps).
Et j'ai rajouté une condition avec la variable Qqch (quelquechose) parce que s'il n'y a pas de fichier chargé, ça génère une erreur.

Code : Tout sélectionner

#fenetre=0 
#absis_fenetre=10 
#ordone_fenetre=10 
#hauteure_fenetre=90 
#largeur_fenetre=290 
OpenWindow(#fenetre,#absis_fenetre,#ordone_fenetre,#largeur_fenetre,#hauteure_fenetre,"SamyMediaPlayer",#PB_Window_SystemMenu|#PB_Window_SizeGadget|#PB_Window_BorderLess) 

FenetreID = WindowID(#fenetre) 
CreateGadgetList(FenetreID) 
InitMovie() 
#editor = 1 
#buttonPlay = 2 
#buttonStop = 3 
#buttonPose = 4 
#buttonResume =5 
EditorGadget(#editor,10,10,270,40,#PB_Editor_ReadOnly) 
ButtonGadget(#buttonPlay,10,60,30,20,"play") 
ButtonGadget(#buttonStop,50,60,30,20,"stop") 
ButtonGadget(#buttonPose,90,60,40,20,"pause") 
ButtonGadget(#buttonResume,140,60,50,20,"continue") 
Resultat = TrackBarGadget(6,200,60,80,20,0,100,#PB_TrackBar_Ticks) 

Repeat 
  event=WaitWindowEvent() 
  If event =#PB_Event_Gadget 
    clicgadget = EventGadget() 
  Else 
    clicgadget=0 
  EndIf 

  If clicgadget= #buttonPlay 

    MovieName$ = OpenFileRequester("Choisis ton son", "", "Audio files|*.mp3;*.wma|All Files|*.*", 0) 
    If MovieName$ 
      If LoadMovie(#fenetre, MovieName$) 
        PlayMovie(#fenetre, WindowID(#fenetre)) 
        SetGadgetText(#editor,MovieName$)
        Qqch = 1 
      Else 
        MessageRequester("Error", "impossible de lire ce son...", 0) 
      EndIf 
    EndIf 
  EndIf 

  If Qqch

    If clicgadget = 6        
      Resultat = GetGadgetState(6) 
      MovieAudio(#fenetre,Resultat ,0) 
    EndIf 

    If clicgadget= #buttonStop 
      StopMovie(#fenetre) 
    EndIf 

    If clicgadget= #buttonPose 
      PauseMovie(#fenetre) 
    EndIf 

    If clicgadget= #buttonResume 
      ResumeMovie(#fenetre) 
    EndIf 

  EndIf

Until event=#PB_Event_CloseWindow