Simplissimo, le navigateur le plus discret et le plus rapide

[Jagang]

Bonjour
Voila je suis en train de faire un navigateur.
Il aura pour atout d'être très rapide à ce lancer et de n'avoir presque pas de barre d'outils (vraiment très petite).
Dans l'aide j'ai trouver plein de choses intéressantes et une en particulier :
On peut utiliser le moteur de rendu de Mozilla au lien de celui d'IE en rajoutant quelque chose mais le probleme c'est que je n'ai pas réussi a trouver ce quelque chose ...
Si quelqu'un sait ...

Merci d'avance
Cordialement
Jagang

PS: Je poste le code dès que j'ai le temps

[Stefou]

#PB_Web_Mozilla: Utilise l'ActiveX Mozilla à la place de IE (Seulement pour Windows)

Voir l'aide de pure, dans gadget \ webgadget
a+

[Jagang]

Merci
Mais que ce que ça fait sous Linux ? Ça plante ou ça utilise un autre ?

Cordialement
Jagang

[jbernard13]

sous linux tu as Firefox

[Progi1984]

sous linux tu as Firefox

et sous windows, aussi !

[Jagang]

Il y a un probleme quand j'utilise FireFox il n'y a pas de scrollBar (pour faire descendre la page) et c'est assez pas pratique
Je met le code :

Code : Tout sélectionner

   ;- datasection
  DataSection 
    precedent: IncludeBinary "precedent.bmp"
    suivant: IncludeBinary "suivant.bmp"
    actualiser: IncludeBinary "actualiser.bmp"
    stop: IncludeBinary "stop.bmp"
  EndDataSection

  ;- ouveture de la fenetre
  If OpenWindow(0,0,0,800,577,"Simplissimo",#PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MinimizeGadget | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget) 
    WindowBounds(0, 250, 100, #PB_Ignore, #PB_Ignore) ;les dimmentions minimal de la fenetre
    
    ;- creation des gadjets
    
    WebGadget(0,1,22,798,535,"http://pagesperso-orange.fr/jagang/") ; <---------------------------------
    TextGadget(1,1,557,250,20,"") ; info
    StringGadget(2,81,1,679,20,GetGadgetText(0)) ; barre d'adresse
    ButtonGadget(3,700,557,100,20,"Google",#PB_Button_Toggle)
    ButtonGadget(4,760,1,40,20,"OK",#PB_Button_Toggle)
    
    ;- mis en place des bouttons
    
    If CatchImage(1, ?precedent)    
      ButtonImageGadget(5, 1, 1, 20, 20, ImageID(1),#PB_Button_Toggle)
    Else
      ButtonGadget(5, 1, 1, 20, 20, "<",#PB_Button_Toggle)
    EndIf
    If CatchImage(2, ?suivant)    
      ButtonImageGadget(6, 21, 1, 20, 20, ImageID(2),#PB_Button_Toggle)
    Else
      ButtonGadget(6, 21, 1, 20, 20, ">",#PB_Button_Toggle)
    EndIf
    If CatchImage(3, ?actualiser)    
      ButtonImageGadget(7, 41, 1, 20, 20, ImageID(3),#PB_Button_Toggle)
    Else
      ButtonGadget(7, 41, 1, 20, 20, "O",#PB_Button_Toggle)
    EndIf    
    If CatchImage(4, ?stop)    
      ButtonImageGadget(8, 61, 1, 20, 20, ImageID(4),#PB_Button_Toggle)
    Else
      ButtonGadget(8, 61, 1, 20, 20, "X",#PB_Button_Toggle)
    EndIf
    
    ;- mis en place du systeme tray icon
    ErrorSysTray=0
    SysTrayIcon = AddSysTrayIcon(#PB_Any, WindowID(0) , LoadImage(5, "croix.ico"))
    If IsSysTrayIcon(SysTrayIcon)=0
      MessageRequester("Error","impossible d'ouvrir le Systeme Tray.",#PB_MessageRequester_Ok)
      ErrorSysTray=1
    EndIf
    SysTrayIconToolTip(SysTrayIcon, "Simplissimo")
    
    
    SmartWindowRefresh(0, 1) 

    ;- fenetre ouverte, debut de la boucle principale
    etat=1
    Repeat 
      ev=WaitWindowEvent()
      URL$=GetGadgetText(0)
      
      If URL$ <> URL_avant$
        URL_avant$=URL$
        SetGadgetText(2,URL$)
      EndIf
      
      If  EventType()= #PB_EventType_DownloadStart 
        SetGadgetText(1,"Téléchargement en cour")
        ;SetGadgetState( progresse_bar , GetGadgetAttribute(0,#PB_Web_Progress))
      ElseIf EventType()= #PB_EventType_DownloadEnd 
        SetGadgetText(1,"Téléchargement terminer")
      EndIf
      
      If ev = #PB_Event_SysTray
        If EventType() = #PB_EventType_LeftClick
          HideWindow(0, etat)
          If etat = 1
            etat = 0
          Else
            etat = 1
            SetWindowState(0, #PB_Window_Normal)
          EndIf
        EndIf
      EndIf
      
      If ev = #PB_Event_SizeWindow
        Gosub redimwin
      EndIf
      
      If ev = #PB_Event_MinimizeWindow And ErrorSysTray=0
        HideWindow(0, 1)
      EndIf
      
      If ev=#PB_Event_Gadget 
        If GetGadgetState(3)=1
          SetGadgetState(3, 0)
          SetGadgetText(0, "http://www.google.fr/ig?hl=fr")
        EndIf
        If GetGadgetState(4)=1
          SetGadgetState(4, 0)
          SetGadgetText(0, GetGadgetText(2))
        EndIf
        If GetGadgetState(5)=1
          SetGadgetState(5, 0)
          SetGadgetState(0, #PB_Web_Back)
        EndIf
        If GetGadgetState(6)=1
          SetGadgetState(6, 0)
          SetGadgetState(0, #PB_Web_Forward)
        EndIf
        If GetGadgetState(7)=1
          SetGadgetState(7, 0)
          SetGadgetState(0, #PB_Web_Refresh)
        EndIf
        If GetGadgetState(8)=1
          SetGadgetState(8, 0)
          SetGadgetState(0, #PB_Web_Stop)
        EndIf
      EndIf
      
      
    Until ev = #PB_Event_CloseWindow
  EndIf

  End

;*****************************************************************************************************
;-LES SOUS-PROGRAMME
;*****************************************************************************************************
;- Redimention de la fenetre
redimwin:
  HauteurWin = WindowHeight(0)
  LargeurWin = WindowWidth(0) 
  ResizeGadget(0, #PB_Ignore, #PB_Ignore, LargeurWin-2, HauteurWin-42) ; redimention du Web Gadjet
  ResizeGadget(2, #PB_Ignore, #PB_Ignore, LargeurWin-121, #PB_Ignore) ; redimention de la barre d'adresse
  ResizeGadget(4, LargeurWin-40, #PB_Ignore, #PB_Ignore, #PB_Ignore) ; reposition du boutton de la barre d'adresse
  ResizeGadget(1, #PB_Ignore, HauteurWin-20, #PB_Ignore, #PB_Ignore) ; reposition de l'info d'etat de la page
  ResizeGadget(3, LargeurWin-100, HauteurWin-20, #PB_Ignore, #PB_Ignore) ; reposition du boutton Google
  SetWindowTitle(0, Str(HauteurWin)+"*"+Str(LargeurWin)) 
Return

La ça fonctionne et dès que l'on met #PB_Web_Mozilla ça ne fonctionne plus

Help me !
Cordialement
Jagang

PS: si j'ai bien compris, sous Linux c'est automatiquement FireFox ?

[jbernard13]

j'ai pas le temps de tester ton programme mais juste un conseil à te donner

evite ceci : Gosub redimwin


crée une procedure :

Code : Tout sélectionner

Procedure redimwin() 
HauteurWin = WindowHeight(0) 
  LargeurWin = WindowWidth(0) 
  ResizeGadget(0, #PB_Ignore, #PB_Ignore, LargeurWin-2, HauteurWin-42) ; redimention du Web Gadjet 
  ResizeGadget(2, #PB_Ignore, #PB_Ignore, LargeurWin-121, #PB_Ignore) ; redimention de la barre d'adresse 
  ResizeGadget(4, LargeurWin-40, #PB_Ignore, #PB_Ignore, #PB_Ignore) ; reposition du boutton de la barre d'adresse 
  ResizeGadget(1, #PB_Ignore, HauteurWin-20, #PB_Ignore, #PB_Ignore) ; reposition de l'info d'etat de la page 
  ResizeGadget(3, LargeurWin-100, HauteurWin-20, #PB_Ignore, #PB_Ignore) ; reposition du boutton Google 
  SetWindowTitle(0, Str(HauteurWin)+"*"+Str(LargeurWin)) 
endprocedure 

et ensuite pour l'appeler :


If ev = #PB_Event_SizeWindow
redimwin()
EndIf

[case]

oui mais la il faut que ses variables soient globales pour y accéder dans une procédure

tout au moins celles qu'il partage avec l'extérieur de la procédure
quand a ton poll c'est un peu tôt vu que ton navigateur n'est pas fini

[Jagang]

jbernard13 :
Désolé j'ai pas trop l'habitude de faire des fonction c'est pour ça. Mais c'est plus rapide ou quelque chose comme ça qu'il faut faire des fonctions ?

case:

quand a ton poll c'est un peu tôt vu que ton navigateur n'est pas fini

J'ai pas compris désolé