PureBasic

Code : Tout sélectionner

; Compilez le programme et crééz en Exe.
; Crééz un nouvel outil dans PureBasic, mettez le nom que vous voulez puis mettez un raccourcis et c'est partie !

; Code créé par RSBasic du forum anglais de PureBasic.
; Process IDentifier, Identifiant de processus.

; Renvoie l'Identifiant du processus actuellement en court d’exécution.
Procedure GetParentPID()
  Protected hSnapshot
  Protected PROCESSENTRY32.PROCESSENTRY32
  Protected bProcess
  
  hSnapshot = CreateToolhelp32Snapshot_(#TH32CS_SNAPPROCESS, #Null)
  If hSnapshot
    PROCESSENTRY32\dwsize = SizeOf(PROCESSENTRY32)
    bProcess = Process32First_(hSnapshot, @PROCESSENTRY32)
    If bProcess
      Repeat
        If PROCESSENTRY32\th32ProcessID = GetCurrentProcessId_()
          CloseHandle_(hSnapshot)
          ProcedureReturn PROCESSENTRY32\th32ParentProcessID
        EndIf
        bProcess = Process32Next_(hSnapshot, @PROCESSENTRY32)
      Until Not bProcess
    EndIf
    CloseHandle_(hSnapshot)
  EndIf
  
EndProcedure

; Code créé par RSBasic du forum anglais de PureBasic.
; Renvoie le code taper dans l'éditeur actif de PB.
Procedure.s GetCurrentScintillaCode(PBScintillaHandle)
  Protected Code$
  Protected result
  Protected length
  Protected memory
  Protected hProcess
  
  SendMessageTimeout_(PBScintillaHandle, #SCI_GETCHARACTERPOINTER, 0, 0, #SMTO_ABORTIFHUNG, 1000, @result)
  If result
    SendMessageTimeout_(PBScintillaHandle, #SCI_GETTEXTLENGTH, 0, 0, #SMTO_ABORTIFHUNG, 1000, @length)
    memory = AllocateMemory(length+2)
    If memory
      hProcess = OpenProcess_(#PROCESS_ALL_ACCESS, #False, GetParentPID())
      ReadProcessMemory_(hProcess, result, memory, length,0)
      Code$ = PeekS(memory, -1, #PB_UTF8)
      
      CloseHandle_(hProcess)
      FreeMemory(memory)
    EndIf
    
  EndIf
  
  ProcedureReturn Code$
EndProcedure

;Handle de l'IDE / Handle of IDE
HandleIDESci=Val(GetEnvironmentVariable("PB_TOOL_Scintilla")) 

If HandleIDESci 
  MessageRequester("", GetCurrentScintillaCode(HandleIDESci))
EndIf