PureBasic

Forums PureBasic - Français
http://forums.purebasic.com/french/

Executable ne marche pas(je viens de mettre le source)

http://forums.purebasic.com/french/viewtopic.php?t=6252

Page 2 sur 2

Publié : lun. 05/févr./2007 11:17
par Flype
si je commente la ligne SkinWin (ligne 51) tout fonctionne (en mode debug ou pas / en executable ou pas).

je n'ai pas testé avec la lib SkinWin puisque je ne l'ai pas.

Le lien de la lib

Publié : lun. 05/févr./2007 18:23
par SpaceMan
Merci Flype
Je me demandais si le probleme ne vient pas de la lib ? J'utilise la lib PBOSL
voici le http://pbosl.purearea.net/index.php?site=Libs

Publié : lun. 05/févr./2007 18:28
par flaith
Et bien j'ai déjà cette lib, et chez moi ça marche nikel, juste pour info je suis sous Win2K SP4

Publié : lun. 05/févr./2007 19:06
par SpaceMan
salut flaith
essaie de creer un exe puis de le lancer et tu verras le problème.

Publié : lun. 05/févr./2007 19:23
par Flype
Bon je viens de tester et c'est une horreur absolue ton code mais peu importe.

l'exécutable généré fonctionne très bien pour moi s'il est dans le meme dossier que tes images.

par contre il fonctionne pas s'il est placé tout seul sur le bureau par exemple.

dans ce dernier cas c'est normal qu'il ne marche pas ton programme.
en plus la réponse a été évoquée dans les posts précédents donc c'est un peu rageant.

1/

tu utilises IncludeBinary/CatchImage ET LoadImage
il faut faire un choix. l'un ou l'autre mais les deux me semblent pas trop adapté.

2/

tu écris :

If LoadImage()
...
HideWindow()
...
Endif

Repeat
...
Until Quit = 1

Le problème c'est que ton programme démarre bien mais la fenêtre est invisible puisque LoadImage() ne fonctionne pas ( HideWindow() n'est pas appelé en fait ). Il n'y a qu'à regarder dans le gestionnaire des taches (ton prog est dans la liste)

Publié : lun. 05/févr./2007 19:26
par Flype
Ensuite si tu écris WindowEvent() au lieu de WaitWindowEvent() il faut mettre un Delay(1) dans la boucle d'évènements sans quoi ton programme consomme 100% du CPU (ce qui est totalement proscrit).

Publié : lun. 05/févr./2007 19:30
par Flype
bref, le problème ne viens absolument pas de la lib SkinWin qui fonctionne à merveille mais de ton code qui est construit à l'arrache.

je propose une légère correction - rien de plus qu'un petit nettoyage de code :

Code : Tout sélectionner

; le programme utilise les libs suivantes:PureCOLOR et PBOSL

;--- CONSTANTES

Enumeration ; Fenêtres
  #fen1
  #fen2
EndEnumeration

Enumeration ; Gadgets
  #load
  #list
  #btclose
  #play
  #Stop
  #Pause
  #Fw
  #Next
  #S1
  #S2
  #bar_de_lecture
  #Gadget_Volume
  #Gadget_Volumetxt
  #Gadget_PositionTxt
  #Gadget_Position
EndEnumeration

Enumeration ; Images
  #img0
  #img1
  #img2
  #img3
  #img4
  #img5
  #img6
EndEnumeration

Enumeration ; Polices
  #Font1
EndEnumeration

;--- RESSOURCES

LoadFont(#Font1, "Arial", 9, #PB_Font_Bold)

LoadImage(#img1, "load.bmp")
LoadImage(#img2, "play.bmp")
LoadImage(#img3, "stop.bmp")
LoadImage(#img4, "pause.bmp")
LoadImage(#img5, "fw.bmp")
LoadImage(#img6, "ff.bmp")

If Not ImageID(#img1) Or Not ImageID(#img2) Or Not ImageID(#img3) Or Not ImageID(#img4) Or Not ImageID(#img5) Or Not ImageID(#img6)
  MessageRequester("Erreur", "Fichier images manquants !", #MB_ICONERROR)
  End
EndIf

;--- INTERFACE GRAPHIQUE

If OpenWindow(#fen1, 0, 0, 700, 400, "PB - SkinWin Example 3", #PB_Window_BorderLess|#PB_Window_ScreenCentered|#PB_Window_Invisible)
  
  If CreateGadgetList(WindowID(#fen1))
    
    ListIconGadget(#list,13,45,210,295, "Liste de Lecture", 150, #PB_ListIcon_FullRowSelect)
    AddGadgetColumn(#list,1,"Durée",55)
    
    TextGadget       (#Gadget_Volumetxt,   610, 323,  60, 15, "Volume")
    TextGadget       (#Gadget_PositionTxt, 310, 280,  50, 15, "");Durée :
    TrackBarGadget   (#Gadget_Volume,      645, 240,  20, 80,  0,  100, #PB_TrackBar_Vertical)
    ProgressBarGadget(#Gadget_Position,    362, 280, 230, 15, 20, 1000)
    
    ButtonImageGadget(#load,  315, 300, 42, 38, ImageID(#img1))
    ButtonImageGadget(#play,  362, 300, 42, 38, ImageID(#img2))
    ButtonImageGadget(#Stop,  409, 300, 42, 38, ImageID(#img3))
    ButtonImageGadget(#Pause, 456, 300, 42, 38, ImageID(#img4))
    ButtonImageGadget(#Fw,    503, 300, 42, 38, ImageID(#img5))
    ButtonImageGadget(#Next,  550, 300, 42, 38, ImageID(#img6))   
    
    SetGadgetColor(#list, #PB_Gadget_FrontColor, $E9EEB7)
    SetGadgetColor(#list, #PB_Gadget_BackColor,  $1E2B10)
    
    PureCOLOR_SetGadgetColor(#load,  $EEEFFF, $391002)
    PureCOLOR_SetGadgetColor(#play,  $000FFF, $391002);$3E1102
    PureCOLOR_SetGadgetColor(#Stop,  $EEEFFF, $391002)
    PureCOLOR_SetGadgetColor(#Pause, $EEEFFF, $391002)
    PureCOLOR_SetGadgetColor(#Fw,    $EEEFFF, $391002)
    PureCOLOR_SetGadgetColor(#Next,  $EEEFFF, $391002)  
    
    PureCOLOR_SetGadgetColor(#Gadget_Volume,      $EEEFFF, $2B1404)
    PureCOLOR_SetGadgetColor(#Gadget_Volumetxt,   $EEEFFF, $2B1404)
    PureCOLOR_SetGadgetColor(#Gadget_PositionTxt, $EEEFFF, $112112)
    
    PureCOLOR_SetColumnHeaderColor(#list, 0, RGB(117, 247, 226), RGB(37, 62, 218), FontID(#Font1))
    PureCOLOR_SetColumnHeaderColor(#list, 1, RGB(117, 247, 226), RGB(18, 98, 85),  FontID(#Font1))
    
    SkinWin(WindowID(#fen1), CatchImage(#img0, ?SkinPicture))
    
  EndIf
  
EndIf

;--- BOUCLE DES EVENEMENTS

If IsWindow(#fen1)
  
  HideWindow(#fen1, #False)
  
  Repeat
    
    EventID = WaitWindowEvent()  
    
    Select EventID   
      
      Case #PB_Event_CloseWindow
        Quit = #True
        
    EndSelect
    
  Until Quit 
  
EndIf 

;--- ZONE DES DATAS

DataSection
SkinPicture: IncludeBinary "lecteur5.bmp"
EndDataSection

;--- FIN DU PROGRAMME

encore Merci

Publié : lun. 05/févr./2007 19:48
par SpaceMan
Flype c'est toi le boss

je pense que mon vrai probleme c'est ne pas revoir attentionnément un code sur lequel je taf :(

je tacherai desormais de faire attention à tout cela car j'apprends beaucoup de mes erreurs. :D

je vais revoir le code car on apprend beaucoup des plus expérimentés
Encore merci pour tout... :D

Publié : lun. 05/févr./2007 20:12
par flaith
SpaceMan a écrit :salut flaith
essaie de creer un exe puis de le lancer et tu verras le problème.
oui, c'est fait, et ça fonctionne toujours :)

Re: encore Merci

Publié : lun. 05/févr./2007 22:08
par Flype
SpaceMan a écrit :je vais revoir le code car on apprend beaucoup des plus expérimentés
Encore merci pour tout... :D
apprend surtout à écrire du code lisible - crois moi c'est un bon conseil :wink:

il aurait été aussi plus simple que tu donnes le code dès le départ parce que pour un code 50 lignes çà vaut pas le coup de le cacher. le forum est 100x plus efficace avec code que sans.

à peluche comme dirait LNA :mrgreen:

Publié : mar. 06/févr./2007 1:03
par Frenchy Pilou
En 2 mots, il fait quoi ce programme? :)
Pourquoi n'est-ce point indiqué dans l'en-tête? :roll:

Publié : mar. 06/févr./2007 1:15
par Flype
En gros c'est le début d'une interface (skinné) d'un player mp3.

Publié : mar. 06/févr./2007 1:20
par Frenchy Pilou
Merci, comme cela on sait ce à quoi cela sert et si on va le charger pour voir de quoi il retourne selon ses propres désidératas 8)

Merci pour les conseils

Publié : mar. 06/févr./2007 17:31
par SpaceMan
@Flype
Merci pour les conseils en fait je ne cachais pas le code mais je voulais vraiment m'en sortir tout seul. Oui je suis un peu egoïste :( c'est d'ailleurs ce qu'on me reproche souvent.
dès que je fais un player 'utilisable je le mets ici

@ frenchy Pilou
Comme l'a dit Flype
En gros c'est le début d'une interface (skinné) d'un player mp3
tout à fait
Fuseau horaire sur UTC+01:00
Page 2 sur 2

Développé par phpBB® Forum Software © phpBB Limited

Traduction française officielle © Qiaeru