PureBasic

Bonjour à tous,

J'ai un petit soucis avec les WebGadget.

Lorsque je mets en place un WebGadget je n'arrive pas à désactiver le Scrolling vertical.

J'ai trouvé ce post dans le moteur de recherche du forum : http://www.purebasic.fr/french/viewtopi ... ing#p18908. Le soucis c'est que j'ai du mal à comprendre ce code. Pour cette raison je m'adresse à vous.

La question paraît simple comme ça mais je vous avoue je planche là dessus.

Je suis actuellement sur PB4.40 (merci au passage aux dév pour la gestion du PNG ça fait trop plaisir depuis le temps).

Si quelqu'un peu me renseigner sur la désactivation du scroll grisé du webgadget.

Je vous remercie par avance.

Cordialement.

Tinangel

Code converti en 4.40

Code : Tout sélectionner

Enumeration
  #WebGadget
  #Window=0
EndEnumeration

If OpenWindow(#Window, 0, 0, 640, 480, "Catch webbrowser events...", #PB_Window_ScreenCentered|#PB_Window_SystemMenu)
  If CreateGadgetList(WindowID(#Window))   
    WebGadget(#WebGadget, 5, 5, 630, 470, "about:blank")
    Browser.IWebBrowser2 = GetWindowLong_(GadgetID(#WebGadget), #GWL_USERDATA)   

    Repeat
      While WindowEvent(): Wend
      Delay(1)
      Browser\get_busy(@isBusy.l)
    Until isBusy = 0
   
    If Browser\get_Document(@DocumentDispatch.IDispatch) = #S_OK
      If DocumentDispatch\QueryInterface(?IID_IHTMLDocument2, @Document.IHTMLDocument2) = #S_OK
        If Document\get_body(@Element.IHTMLElement) = #S_OK
          If Element\get_style(@Style.IHTMLStyle)  = #S_OK
            Style\put_overflow("hidden")
          EndIf 
        EndIf
        Document\Release()
      EndIf 
      DocumentDispatch\Release()   
    EndIf
   
    Repeat
    Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf
EndIf

DataSection
IID_IHTMLDocument2:  ;  {332C4425-26CB-11D0-B483-00C04FD90119}
Data.l $332C4425
Data.w $26CB, $11D0
Data.b $B4, $83, $00, $C0, $4F, $D9, $01, $19

IID_IHTMLElement:  ; {3050F1FF-98B5-11CF-BB82-00AA00BDCE0B}
Data.l $3050F1FF
Data.w $98B5, $11CF
Data.b $BB, $82, $00, $AA, $00, $BD, $CE, $0B 
EndDataSection

Sinon...

Code : Tout sélectionner

If OpenWindow(0,0,0,375,500,"Web no scroll",#PB_Window_SystemMenu|#PB_Window_ScreenCentered |#PB_Window_TitleBar)=0
   End 
Else  
 Url$  ="about:<html><body scroll='no' leftmargin='0' topmargin='0'><img src='"+"http://www.purearea.net/pb/pics/PB4-Developer.jpg"+"'></img></body></html>"  
 WebGadget(0,0,0,375,500,Url$)    
EndIf 
 Repeat 
  EventID = WaitWindowEvent()     
      If EventID
        Select EventID
          Case #PB_Event_CloseWindow
            Quit = 1
        EndSelect
      EndIf      
 Until Quit     
End

Merci pour la réponse aussi rapide.

Je suis qu'un idiot dans la page Web j'utilisais margin='0' et j'oubliais le scroll='0'.

Je suis blazé de ne plus avoir Dreamweaver ... il me simplifiais la vie !!!

Je suis vraiment désolé du dérangement.

Merci infiniement.

Tinangel.

PureBasic

Désactiver le scrolling d'un webgadget ! (RESOLU)

Désactiver le scrolling d'un webgadget ! (RESOLU)

Re: Désactiver le scrolling d'un webgadget !

Re: Désactiver le scrolling d'un webgadget !

Re: Désactiver le scrolling d'un webgadget !