PureBasic

Bonjour,

Est-il possible de faire précéder un titre de menu par une icone en Pure basic? Si oui, comment faire?

Merci de votre aide

http://www.purebasic.fr/french/viewtopi ... 930#p58930

Salut.

Si le code de TO7 est ce que tu souhaites faire, alors tu peux le faire en natif en PB.

Regarde "CreateImageMenu"

Des bouts de code pris dans 1 de mes programmes pour te donner une idée de ce qu'il faut faire.
Si tu mets tes propres images, cela doit fonctionner.

Code : Tout sélectionner

; -------------------------------------------------------------------------------------------
;- Enumeration
; -------------------------------------------------------------------------------------------
Enumeration #PB_Compiler_EnumerationValue
      ;- Windows    
      #WINDOW_Menu
      
      ;- Menu bars
      #MENU_Window_Menu
      
      ;- Menu/Toolbar items
      #MENU_SiteWeb
      #MENU_Forum
      #MENU_APropos
      #MENU_Quitter
      #MENU_VerifierLesMisesAJour
      
      ;- Images Menu
      ;#IMAGE_iconeSmiley
      #IMAGE_iconeQuit
      #IMAGE_iconeForum
      #IMAGE_iconeAPropos
EndEnumeration


; -------------------------------------------------------------------------------------------
;- Image Plugins
; -------------------------------------------------------------------------------------------
UsePNGImageDecoder()


; -------------------------------------------------------------------------------------------
;- Catch Images 
; -------------------------------------------------------------------------------------------
;/ Images du menu.
;CatchImage(#IMAGE_iconeSmiley, ?iconeSmiley)
CatchImage(#IMAGE_iconeQuit, ?iconeQuit)
CatchImage(#IMAGE_iconeForum, ?iconeForum)
CatchImage(#IMAGE_iconeAPropos, ?iconeAPropos)


; -------------------------------------------------------------------------------------------
;- Images incrustées en ressources.
; -------------------------------------------------------------------------------------------
DataSection
      ;/ Menus 
      iconeQuit    : IncludeBinary "images/Quit.png"
      iconeForum   : IncludeBinary "images/Url.png"
      iconeAPropos : IncludeBinary "images/Eye.png"
EndDataSection



; -------------------------------------------------------------------------------------------
;- GUI.
; -------------------------------------------------------------------------------------------
If OpenWindow(#WINDOW_Menu, 399, 203, 600, 520, "Menu général", #PB_Window_ScreenCentered|#PB_Window_TitleBar|#PB_Window_SystemMenu) ; qsd
      menu = CreateImageMenu(#MENU_Window_Menu, WindowID(#WINDOW_Menu))
      If menu
            
            MenuTitle("Fichier")
            MenuItem(#MENU_Quitter,    "Quitter", ImageID(#IMAGE_iconeQuit))
            
            MenuTitle("Aide")
            MenuItem(#MENU_SiteWeb,    "Site de A.I-Pifou, livre d'or", ImageID(#IMAGE_iconeForum))
            MenuItem(#MENU_Forum,      "Forum de A.I-Pifou, livre d'or", ImageID(#IMAGE_iconeForum))
            MenuItem(#MENU_APropos,    "A propos", ImageID(#IMAGE_iconeAPropos))
            
            MenuTitle("Vérifier les mises à jour")
            MenuItem(#MENU_VerifierLesMisesAJour, "Vérifier les mises à jour", ImageID(#IMAGE_iconeAPropos))               
            
      EndIf
      
EndIf

L'avantage c'est que cela fonctionne aussi sous Linux.
Autre avantage, c'est que tu profites de la transparence du .png.

Exemple en image :

Maintenant si tu veux mettre des images devant les mots :
Fichier, Aide et Vérifier les mises à jour, alors je ne sais pas comment faire.

Bye.

Merci à vous tous ! ça fonctionne !

PureBasic

[RESOLU)] Titre du menu précédé par une icône

[RESOLU)] Titre du menu précédé par une icône

Re: Titre du menu précédé par une icône

Re: Titre du menu précédé par une icône

Re: Titre du menu précédé par une icône