PureBasic

Code : Tout sélectionner

EnableExplicit

Structure IpHeader
  IhlVersion.b
  typeOfService.b
  totalLength.w
  ID.w
  flagOffset.b
  fragOffset.b
  timeToLive.b
  protocol.b
  checksum.w
  source.l
  destination.l
EndStructure

Structure TcpHeader
  portSource.w
  portDestination.w
  seqNum.l
  ackNum.l
  dataOffset.b
  flags.b
  window.w
  checksum.w
  urgentPointer.w
EndStructure

#WSA_VER = $202
#SIO_RCVALL=$98000001
#TcpProtocol = 6
#BufferSize = 2048

Procedure processData(*buffer, size.i)
  Protected ipHeader.IPHeader, tcpHeader.TcpHeader, sourcePort.i, destinationPort.i, stringData.s
  
  If size > 40 ;on veut un paquet TCP/IP complet avec des données utiles
    ;récupération de l'en-tete IP
    CopyMemory(*buffer, @ipHeader, SizeOf(IpHeader))
    If ipHeader\protocol = #TcpProtocol
      
      ;récupération de l'en-tete TCP
      CopyMemory(*buffer+SizeOf(IpHeader), @tcpHeader, SizeOf(TcpHeader))
      sourcePort = ntohs_(tcpHeader\portSource)
      destinationPort = ntohs_(tcpHeader\portDestination)
      stringData = Space(256)
      CopyMemory(*buffer+SizeOf(IpHeader)+SizeOf(TcpHeader), @stringData, 255)
      
      
      PrintN("*************************************************")
      PrintN("Source: "+IPString(ipHeader\source))
      PrintN("Destination:"+IPString(ipHeader\destination))
      PrintN("Port source:"+Str(sourcePort))
      PrintN("Port destination:"+Str(destinationPort))
      PrintN("Donnees:"+stringData+" [...]")
      PrintN("*************************************************")
      PrintN("")
    EndIf
  EndIf
EndProcedure

Procedure sniff()
  Protected ip.i, wsaData.WSADATA, sin.SOCKADDR_IN, promiscuous_mode.l, sock.i, *buffer, size.i
  promiscuous_mode = 1
  
  ;récupération de l'IP
  If InitNetwork()
    ExamineIPAddresses()
    ip = NextIPAddress()
  Else
    ProcedureReturn 0
  EndIf
  
  ;Démarrage
  If WSAStartup_(#WSA_VER, @wsaData)
    WSACleanup_()
    ProcedureReturn 0
  EndIf
  
  ;Creattion du socket
  sock = SOCKET_(#AF_INET, #SOCK_RAW, #IPPROTO_IP)
  If sock = #INVALID_SOCKET
    WSACleanup_()
    ProcedureReturn 0
  EndIf
  sin\sin_family = #AF_INET 
  sin\sin_addr = ip
  
  ;mode sniffing
  If bind_(sock, @sin, SizeOf(SOCKADDR_IN))
    WSACleanup_()
    ProcedureReturn 0
  EndIf
  If ioctlsocket_(sock, #SIO_RCVALL, @promiscuous_mode)
    WSACleanup_()
    ProcedureReturn 0
  EndIf
  
  
  *buffer = AllocateMemory(#BufferSize) ;allocation de la memoire de reception 
  
  Repeat
    size = recv_(sock, *buffer, #BufferSize, 0)
    processData(*buffer, size) ;traitement des données
    Delay(1)
  ForEver
EndProcedure

OpenConsole()
sniff()