PureBasic

Code : Tout sélectionner

Repeat
	GetSystemTime_(DateUTC.SYSTEMTIME)
	GetLocalTime_(DateLocale.SYSTEMTIME)
Until DateUTC\wSecond = DateLocale\wSecond ; Garantit que la lecture de la date s'est effectuée sur la même seconde
DateUTC_Seconde.q = Date(DateUTC\wYear, DateUTC\wMonth, DateUTC\wDay, DateUTC\wHour, DateUTC\wMinute, DateUTC\wSecond)
DateLocale_Seconde.q = Date(DateLocale\wYear, DateLocale\wMonth, DateLocale\wDay, DateLocale\wHour, DateLocale\wMinute, DateLocale\wSecond)

DecalageHoraire_Seconde.q = DateLocale_Seconde - DateUTC_Seconde
DecalageHoraire = DecalageHoraire_Seconde / 3600

CompilerIf #PB_Compiler_Debugger
	If DecalageHoraire > 0
		Debug "Votre fuseau horaire : GMT+" + Str(DecalageHoraire)
	Else
		Debug "Votre fuseau horaire : GMT" + Str(DecalageHoraire)
	EndIf
CompilerEndIf

Code : Tout sélectionner

; by Ar-S 2011


If InitNetwork()=0
  MessageRequester("Erreur","Connexion Internet introuvable, ce programme va se fermer",#MB_ICONEXCLAMATION)
  End
EndIf

Enumeration
  #ARS
  #BT_Jardin
  #BT_Coupe
  #BT_Peche
  #Progress
EndEnumeration


Global annee.s="2011"
Global path$=GetCurrentDirectory()
Global UrlLune$="http://www.calendrier-lunaire.net/imgs/calendriers/"

; Récupération image selon catégorie
Procedure RecupeImage(Categorie)
  
  If Categorie=1 ; Coupe et Epilation
    Categorie$="cheveux-"
    OutFile$="Coupe_"
  ElseIf Categorie=2 ; Jardin
    Categorie$="jardiner-avec-la-lune-"
    OutFile$="Jardin_"
  ElseIf Categorie=3 ; Peche
    Categorie$="pecher-avec-la-lune-"
    OutFile$="Peche_"
  EndIf
  erreur=0
  For I = 1 To 12  
    If ReceiveHTTPFile(UrlLune$+Categorie$+Str(I)+"-"+annee.s+".jpg", path$+OutFile$+Str(I)+".jpg")
      SetGadgetColor(#Progress,#PB_Gadget_FrontColor,RGB(AA,AA,I*15))
      SetGadgetState(#Progress,I)
      Debug Str(I)+" Succes "
      Delay(10)
    Else
      erreur+1
      Debug "Erreur"
    EndIf
  Next 
  
  If erreur>0
    MessageRequester("Terminé","Opération terminée, il y a eu "+Str(erreur)+" erreur(s).")
  Else
    MessageRequester("Terminé","Toutes les images ont été récupérées")
  EndIf
  
EndProcedure

If OpenWindow(#ARS, 410, 150, 392, 104, "Jardin/Pêche/Coupe via phase lunaire by Ar-S", #PB_Window_SystemMenu|#PB_Window_TitleBar|#PB_Window_MinimizeGadget)
  ButtonGadget(#BT_Jardin, 5, 5, 175, 30, "Jardin")
  ButtonGadget(#BT_Coupe, 5, 37, 175, 30, "Coupe et Epilation")
  ButtonGadget(#BT_Peche, 5, 70, 175, 30, "Peche")
  ProgressBarGadget(#Progress, 190, 5, 197, 95, 0, 12, #PB_ProgressBar_Smooth)
  
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #BT_Jardin
            RecupeImage(2)
          Case #BT_Coupe
            RecupeImage(1)
          Case #BT_Peche
            RecupeImage(3)
          Case #Progress
        EndSelect
      Case #PB_Event_CloseWindow
        Select EventWindow()
          Case #ARS
            CloseWindow(#ARS)
            Break
        EndSelect
    EndSelect
  ForEver
  
Else
  MessageRequester("Erreur","Impossible d'ouvrir le programme",$50)
EndIf

Code : Tout sélectionner

Declare.d FNMoonPhase(Year,Month,Day)
Declare.s mois_string(mois)

annee=2009
mois=06
Debug "Les phases lunaire pour le mois de "+mois_string(mois) +" auront lieu les :"
Debug " "
For i=1 To 31
    CircleType.d=FNMoonPhase(annee,mois,i)
    If CircleType>0.97 
        Debug Str(i)+" "+mois_string(mois)+"  Phase de la lune: Pleine lune"
        ElseIf CircleType<0.03 
        Debug Str(i)+" "+mois_string(mois)+"  Phase de la lune: Pas de lune"
        ElseIf(CircleType>0.46) And (CircleType<0.53)
        Debug Str(i)+" "+mois_string(mois)+"  Phase de la lune: 3/4 lune"
    EndIf
Next
; ******************************************************************************

Procedure.d FNMoonPhase(Year,Month,Day) 
    If Month<=2 
        Year=Year-1
        Month=Month+12
    EndIf
    
    Month=Month-3
    XYear=Year % 100
    Century=Int((Int(Year / 100)*146097) / 4)
    XYear=Int((XYear*1461) / 4)
    M.d=(Int(((((Month*153)+2)/ 5)+Day)+1721119+XYear+Century)+4.867)/29.53058
    ProcedureReturn Abs(2*(M-Int(M))-1) 
EndProcedure

Procedure.s mois_string(num)
    ProcedureReturn StringField("Janvier,Fevrier,Mars,Avril,Mai,Juin,Juillet,Aout,Septembre,Octobre,Novembre,Decembre",num,",")    
EndProcedure