ListIconGadget selectioné ou sélectionner

[david]

bonjour, je suis en train de faire un programme dans lequel j'aurais un sous-menu du genre:

Code : Tout sélectionner

nbobj=4

If nbobj<=2:augm=0:EndIf 
If nbobj>2:augm=nbobj*55:EndIf
  
  
  If OpenWindow(0, 0, 0, 240+augm, 200, "Choisissez l'imprimante", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) And CreateGadgetList(WindowID(0))
     TextGadget   (11, 20, 20, 200, 30, "Vous devez sélectionner une imprimante compatible avec le mode Recto/Verso",#PB_Text_Center)
    ListIconGadget(5, 20, 60, 200+augm, 65, "", 200,#PB_ListIcon_GridLines)
     ButtonGadget(0, 20, 150, 200+augm, 20, "VALIDER")
    If LoadImage(0, "IMPRIMER.ICO") 
      ChangeListIconGadgetDisplay(5, 0)
      
        For a=1 To nbobj
      AddGadgetItem(5, 1, Str(a), ImageID(0))
      Next
     EndIf  
 

  Repeat
    EventID = WaitWindowEvent()
       If EventID = #PB_Event_Gadget
      Select EventGadget()
        Case 0:Goto impvalide
        EndSelect
            EndIf
  Until EventID = #PB_Event_CloseWindow
EndIf
End 


impvalide:

MessageRequester("Resultat","hhh")

Dans mon programme principal, nbobj aura comme valeur : 0 a 5 maximum
Le sous programme m'affiche les icones avec le nom correspondant
- Mais je voudrais qu'il sélectionne par défaut un des objets en question selon son nom
- Je voudrais qu'après validation, il m'affiche le nom de l'objet qui était en 'sélection'

J'ai bien vu du côté des GetGadgetState() & SetGadgetState()...
mais je ne dois pas m'y prendre comme il faut car je plante quoi que je fasse...

[david]

bon j'ai trouvé:

Code : Tout sélectionner

Resultat = GetGadgetItemState(5, a)

par contre le SetGadget permet d'identifier la sélection en mémoire mais ne sélectionne pas visuellement

[Le Soldat Inconnu]

comme ceci

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 240 + augm, 200, "Choisissez l'imprimante", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) And CreateGadgetList(WindowID(0))
	TextGadget(11, 20, 20, 200, 30, "Vous devez sélectionner une imprimante compatible avec le mode Recto/Verso", #PB_Text_Center)
	ListIconGadget(5, 20, 60, 200 + augm, 80, "", 200 - 32, #PB_ListIcon_GridLines | #PB_ListIcon_AlwaysShowSelection | #PB_ListIcon_FullRowSelect)
	ButtonGadget(0, 20, 150, 200 + augm, 20, "VALIDER")
	
	; ChangeListIconGadgetDisplay(5, 0)
	
	For a = 1 To 10
		AddGadgetItem(5, -1, Str(a))
	Next
	
	SetGadgetState(5, 2) ; Sélectionne le troisième élément
	
	Repeat
		EventID = WaitWindowEvent()
		If EventID = #PB_Event_Gadget
			Select EventGadget()
				Case 0 ; pas de Goto
					Position = GetGadgetState(5)
					If Position >= 0
						MessageRequester("Resultat", GetGadgetItemText(5, Position))
					EndIf
			EndSelect
		EndIf
	Until EventID = #PB_Event_CloseWindow
EndIf
End