PureBasic

Code : Tout sélectionner

EnableExplicit

Enumeration #PB_Event_FirstCustomValue
	#Serial_Event_StringForUs
	#Serial_Event_StringForOthers
	#Serial_Event_Exit
EndEnumeration



Structure ThreadParameterStructure
	Port$
	Semaphore.i
	Port.i
	nx$
	Exit.i
EndStructure


Procedure serial_rd(*Parameter.ThreadParameterStructure)
	
	Protected.i position, size, reslen, i, State
	Protected Port$, Rx$, l$
	Protected Byte.a
	
	
	
	If IsSerialPort(*Parameter\Port)
		
		position = 0
		Repeat
			;  receive serial data
			size = AvailableSerialPortInput(*Parameter\Port)
			If size > 0     ; only if someting to read
				
				If ReadSerialPortData(*Parameter\Port, @Byte, 1)
					
					Select State
						Case 0
							If Byte = #LF
								State = 1
							EndIf
							
						Case 1
							If Byte <> #LF
								Rx$ + Chr(Byte)
								Debug Rx$
							Else
								*Parameter\nx$ = Rx$
								If Left(*Parameter\nx$, 3) = "sfs"
									PostEvent(#Serial_Event_StringForUs)
								Else
									PostEvent(#Serial_Event_StringForOthers)
								EndIf
								WaitSemaphore(*Parameter\Semaphore)
								Rx$ = ""
							EndIf
							
					EndSelect
					
				EndIf
			Else
				Delay(1)    ; to avoid a high CPU load if nothing to receive
			EndIf
		Until *Parameter\Exit
		
	EndIf
	
	PostEvent(#Serial_Event_Exit)
	
EndProcedure


Define.i Exit, Event, Thread
Define ThreadParameter.ThreadParameterStructure


CompilerIf Not #PB_Compiler_Thread
	MessageRequester("PureBasic Info", "COCHEZ Menu 'Compilateur/Options du compilateur.../Activer la gestion des Threads'.")
	End
CompilerEndIf



If OpenWindow(0, 0, 0, 400, 500, "Test", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
	
	ListIconGadget(0, 10, 10, 380, 200, "For Us", 270)
	ListIconGadget(1, 10, 220, 380, 200, "For Other", 270)
	
	
	ThreadParameter\Port$ = "COM4"
	ThreadParameter\Semaphore = CreateSemaphore()
	
	ThreadParameter\Port = OpenSerialPort(#PB_Any, ThreadParameter\Port$, 230400, #PB_SerialPort_NoParity, 8, 1, #PB_SerialPort_NoHandshake, 1024, 1024)
	If ThreadParameter\Port
		
		Thread = CreateThread(@serial_rd(), @ThreadParameter)
		
		Repeat
			
			Event = WaitWindowEvent()
			
			Select Event
					
				Case #Serial_Event_StringForUs
					AddGadgetItem(0, -1, ThreadParameter\nx$)
					SignalSemaphore(ThreadParameter\Semaphore)
					
				Case #Serial_Event_StringForOthers
					AddGadgetItem(1, -1, ThreadParameter\nx$)
					SignalSemaphore(ThreadParameter\Semaphore)
					
				Case #Serial_Event_Exit
					; do something or not
					Exit = #True
					
				Case #PB_Event_CloseWindow
					Exit = #True
					
			EndSelect
			
		Until Exit
		
		If IsThread(Thread)
			ThreadParameter\Exit = #True
			SignalSemaphore(ThreadParameter\Semaphore)  ; to be sure it is not waiting
			If WaitThread(Thread, 1000) = 0
				KillThread(Thread)
			EndIf
		EndIf
		
		CloseSerialPort(ThreadParameter\Port)
		
	Else
		
		MessageRequester("Error", "Was not able to open " + ThreadParameter\Port$)
		
	EndIf
	
EndIf