Désactiver les barres de scrolling dans un webgadget ?

[Oliv]

Est-ce possible ? même si ça doit être dans le code HTML<>javascript<>PHP d'une mage ça ne me gène pas mais le mieux serait dans PB

[nico]

Rah, j'avais écrit ce code mais j'arrive plus à mettre la main dessus.

[nico]

Code : Tout sélectionner

Enumeration
  #WebGadget
  #Window=0
EndEnumeration

Procedure.l Ansi2Uni(ansi.s)
  size.l=MultiByteToWideChar_(#CP_ACP,0,ansi,-1,0,0)
  Dim unicode.w(size)
  MultiByteToWideChar_(#CP_ACP, 0, ansi, Len(ansi), unicode(), size)
  ProcedureReturn @unicode()  
EndProcedure 

If OpenWindow(#Window, 0, 0, 640, 480, #PB_Window_ScreenCentered|#PB_Window_SystemMenu, "Catch webbrowser events...") 
  If CreateGadgetList(WindowID())   
    WebGadget(#WebGadget, 5, 5, 630, 470, "c:\PureBasic  Index.htm") 
    Browser.IWebBrowser2 = GetWindowLong_(GadgetID(#WebGadget), #GWL_USERDATA)    

    Repeat 
      While WindowEvent(): Wend 
      Delay(1) 
      Browser\get_busy(@isBusy.l) 
    Until isBusy = 0 
    
    If Browser\get_Document(@DocumentDispatch.IDispatch) = #S_OK 
      If DocumentDispatch\QueryInterface(?IID_IHTMLDocument2, @Document.IHTMLDocument2) = #S_OK 
        If Document\get_body(@Element.IHTMLElement) = #S_OK 
          If Element\get_style(@Style.IHTMLStyle)  = #S_OK
            Style\put_overflow(Ansi2Uni("hidden"))
          EndIf  
        EndIf
        Document\Release() 
      EndIf  
      DocumentDispatch\Release()    
    EndIf 
    
    Repeat 
    Until WaitWindowEvent() = #PB_EventCloseWindow 
  EndIf 
EndIf 

DataSection 
IID_IHTMLDocument2:  ;  {332C4425-26CB-11D0-B483-00C04FD90119}
Data.l $332C4425 
Data.w $26CB, $11D0 
Data.b $B4, $83, $00, $C0, $4F, $D9, $01, $19 

IID_IHTMLElement:  ; {3050F1FF-98B5-11CF-BB82-00AA00BDCE0B}
Data.l $3050F1FF 
Data.w $98B5, $11CF 
Data.b $BB, $82, $00, $AA, $00, $BD, $CE, $0B  
EndDataSection

[Oliv]

encore une fois tu me sauves
Je regaderais ça demain