problème Ecrire et Lire un texte

[david]

je débute, j'ai lu tous les messages faisant allusion au Bloc-Note...
Mais je n'ai pas trouvé mon bonheur. J'ai besoin de deux programmes :

Le premier ouvre une petite fenêtre de texte à écrire et 3 boutons pour sauvegarder le texte dans 3 répertoires différents.

Le deuxième va chercher le texte dans un des 3 répertoires au choix et l'affiche.

Ca à l'air si simple, mais si qq'1 pouvait me venir en aide......
Merci d'avance

[Flype]

le programme pour ecrire :

Code : Tout sélectionner

#TITRE    = "Bloc Note"
#LARGEUR  = 400
#HAUTEUR  = 300

#FICHIER1 = "C:\blocnote_1.txt"
#FICHIER2 = "C:\blocnote_2.txt"
#FICHIER3 = "C:\blocnote_3.txt"

Procedure Sauver(texte.s,fichier.s)
  
  If CreateFile(0,fichier)
    WriteString(texte)
    CloseFile(0)
  EndIf
  
EndProcedure

OpenWindow(0, 0, 0, #LARGEUR, #HAUTEUR, #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MinimizeGadget, #TITRE)
CreateGadgetList(WindowID())
EditorGadget(0,5,5,#LARGEUR-10,#HAUTEUR-35)
ButtonGadget(1,#LARGEUR-80,#HAUTEUR-25,75,20,"Quitter")

ButtonGadget(2,5,#HAUTEUR-25,75,20,"Sauver [1]")
ButtonGadget(3,85,#HAUTEUR-25,75,20,"Sauver [2]")
ButtonGadget(4,165,#HAUTEUR-25,75,20,"Sauver [3]")

Repeat 
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow : Break
    Case #PB_Event_Gadget
      Select EventGadgetID()
        Case 1 : Break
        Case 2 : Sauver(GetGadgetText(0),#FICHIER1)
        Case 3 : Sauver(GetGadgetText(0),#FICHIER2)
        Case 4 : Sauver(GetGadgetText(0),#FICHIER3)
      EndSelect
  EndSelect
ForEver

End

le programme pour lire :

Code : Tout sélectionner

#TITRE    = "Bloc Note"
#LARGEUR  = 400
#HAUTEUR  = 300

#FICHIER1 = "C:\blocnote_1.txt"
#FICHIER2 = "C:\blocnote_2.txt"
#FICHIER3 = "C:\blocnote_3.txt"

Procedure.s Lire(fichier.s)
  
  texte.s = ""
  
  If ReadFile(0,fichier)
    While Eof(0)=0
      texte + ReadString() + Chr(13)
    Wend
    CloseFile(0)
  EndIf
  
  ProcedureReturn texte
  
EndProcedure

OpenWindow(0, 0, 0, #LARGEUR, #HAUTEUR, #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MinimizeGadget, #TITRE)
CreateGadgetList(WindowID())
EditorGadget(0,5,5,#LARGEUR-10,#HAUTEUR-35)
ButtonGadget(1,#LARGEUR-80,#HAUTEUR-25,75,20,"Quitter")

ButtonGadget(2,5,#HAUTEUR-25,75,20,"Charger [1]")
ButtonGadget(3,85,#HAUTEUR-25,75,20,"Charger [2]")
ButtonGadget(4,165,#HAUTEUR-25,75,20,"Charger [3]")

Repeat 
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow : Break
    Case #PB_Event_Gadget
      Select EventGadgetID()
        Case 1 : Break
        Case 2 : SetGadgetText(0,Lire(#FICHIER1))
        Case 3 : SetGadgetText(0,Lire(#FICHIER2))
        Case 4 : SetGadgetText(0,Lire(#FICHIER3))
      EndSelect
  EndSelect
ForEver

End

j'espere que ca t'aidera

[david]

c'est super.
Merci beaucoup
On ne pouvait pas rêver mieux!!!!