peux t'on mettre une touche de raccouci a un bouton?

[bernard13]

bonjour

peux t'on mettre une touche de raccouci a un bouton?

j'arrive a mettre les touches de raccourci dans un menu
mais pas dans un bouton .

merci si il ya une solution

[flaith]

Essaye ca

Code : Tout sélectionner

Enumeration
  #ALTF4
  #CTRL_O
EndEnumeration
;
; ton code pour ta fenêtre
; puis affichage
;
AddKeyboardShortcut(#Window, #PB_Shortcut_Control | #PB_Shortcut_O, #CTRL_O) ; Crée un raccourci clavier CTRL+O sur la fenêtre 0
                                                                    ; qui generera un evenement de valeur #CTRL_O.

Repeat
  Event = WaitWindowEvent() ; on récupère les évènements
  
  If Event = #PB_Event_CloseWindow 
    Quit = 1
  EndIf
  
  If Event = #PB_EventGadget ; si on appuie sur un gadget
    Select EventGadgetID()
      Case #Button ; on appuie sur le bouton OK
        Quit = 1
    EndSelect
  EndIf
  
  If Event = #PB_EventMenu
    Select EventMenuID()
      Case #ALTF4
        Quit = 1
      Case #CTRL_O
        Quit = 1
    EndSelect
  EndIf 
  
Until Quit = 1 

[Guimauve]

C'est comme ceci qu'il faut faire selon les règles de l'art :

A+
Guimauve

Code : Tout sélectionner

Enumeration
   
   #Main_Win
   #txt_allo
   #Btn_Quitter
   
EndEnumeration

#Main_Win_Style = #PB_Window_ScreenCentered | #PB_Window_SystemMenu | #PB_Window_SizeGadget

If OpenWindow(#Main_Win, 0, 0, 400, 300, #Main_Win_Style, "Nom du programme") <> 0
   
   If CreateGadgetList(WindowID(#Main_Win)) <> 0
      TextGadget(#txt_allo,5,5,390,20,"Appuyer sur le bouton ou 'CTRL + Q' pour quitter")
      ButtonGadget(#Btn_Quitter,5,30,100,25,"Quitter")
   EndIf
   
   AddKeyboardShortcut(#Main_Win, #PB_Shortcut_Control | #PB_Shortcut_Q , #Btn_Quitter)
EndIf

Repeat
   
   EventID = WaitWindowEvent()
   
   Select EventID
         
      Case #PB_EventGadget
         
         Select EventGadgetID()
               
            Case #Btn_Quitter
               MessageRequester("Message", "On quitte avec un clique sur le bouton", #MB_OK)
               EventID = #PB_EventCloseWindow
               
         EndSelect
         
      Case #PB_EventMenu
         
         Select EventMenuID()
               
            Case #Btn_Quitter
               MessageRequester("Message", "On quitte avec Ctrl + Q", #MB_OK)
               EventID = #PB_EventCloseWindow
               
         EndSelect
         
   EndSelect
   
Until EventID = #PB_EventCloseWindow

End