PureBasic

Forums PureBasic - Français
http://forums.purebasic.com/french/

help!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

http://forums.purebasic.com/french/viewtopic.php?t=314

Page 1 sur 1

help!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

Publié : lun. 15/mars/2004 13:42
par france
je craque :mad:

je n'y arrive pas

a qui saura m'aider, j'envoie mon programme

vous allez voir que je n'arrive pas a sauvegarder une fiche et à la rappeler


je suis trop nulle :cry:

merci de m'aider :wink:

Code : Tout sélectionner



;déclaration des constantes

Enumeration

#menu
#Text_0 
     #Text_1 
     #Text_2 
     #Text_3 
     #Text_4 
     #Text_5 
     #Text_6 
     #Text_7 
     #Text_8 
     #text_9
     #text_10
     #text_11
     #text_12
     #text_13
     #text_14
     #text_15
     #text_16
     #text_17
     #text_18
     #text_19
     #text_20
     #text_21
     #text_22
     #text_23
     #text_24
     #text_25
     #String_0 
     #String_1 
     #String_2 
     #String_3 
     #String_4 
     #String_5 
     #String_6 
     #String_7 
     #String_8 
     #Button_0 
     #Button_1 
     #button_2
      #button_consultation_film
      #consultation
    #film_du_catalogue
EndEnumeration


Enumeration
#message 
#bouton_inserer
#page_film
#sauvegarder
#corriger
#gadget_editeur
#bouton_consulter
#page_consultation
EndEnumeration
Global titre$, acteur1$, realisateur$, acteur2$, acteur3$, duree$, origine$, annee$, producteur$ 
Declare creation_de_film()
Declare recapitulatif()
Declare creation_fichier()
Declare consultation_de_film()
Declare film_video()
Procedure ouverture_menu()


  If OpenWindow(#menu,0,0,200,200,#pb_window_systemmenu|#pb_window_windowcentered,"menu")
  
    If CreateGadgetList (WindowID())
    
      ButtonGadget(#bouton_inserer,10,10,180,20,"INSERER UN FILM")
      ButtonGadget(#bouton_consulter,10,40,180,20,"CONSULTER LE CATALOGUE")
      
    EndIf
  
  
  EndIf
  
      Repeat
      
  
      eventid = WaitWindowEvent()
      
      
       If EventID = #PB_EventGadget 
          Select EventGadgetID()
  
  Case #bouton_inserer
  CloseWindow(#menu)
  creation_de_film()

   Case #bouton_consulter
   CloseWindow(#menu)
   consultation_de_film()
  
   
  
  
  
  
     EndSelect 
     EndIf 
Until EventID = #PB_EventCloseWindow 

EndProcedure 

Procedure creation_de_film() 


      If OpenWindow(#page_film, 216, 0, 343, 333, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar | #PB_Window_WindowCentered, "information pour le film") 
          If CreateGadgetList(WindowID()) 
               TextGadget(#Text_0, 10, 10, 90, 20, "Titre du film :") 
               TextGadget(#Text_1, 10, 40, 90, 20, "Réalisateur :") 
               TextGadget(#Text_2, 10, 70, 90, 20, "Premier acteur :") 
               TextGadget(#Text_3, 10, 100, 90, 20, "Deuxième acteur :") 
               TextGadget(#Text_4, 10, 130, 90, 20, "Troisième acteur :") 
               TextGadget(#Text_5, 10, 160, 90, 20, "Durée :") 
               TextGadget(#Text_6, 10, 190, 90, 20, "Origine :") 
               TextGadget(#Text_7, 10, 220, 90, 20, "Année :") 
               TextGadget(#Text_8, 10, 250, 90, 20, "Producteur :") 
               StringGadget(#String_0, 100, 10, 210, 20, "") 
               StringGadget(#String_1, 100, 40, 210, 20, "") 
               StringGadget(#String_2, 100, 70, 210, 20, "") 
               StringGadget(#String_3, 100, 100, 210, 20, "") 
               StringGadget(#String_4, 100, 130, 210, 20, "") 
               StringGadget(#String_5, 100, 160, 210, 20, "") 
               StringGadget(#String_6, 100, 190, 210, 20, "") 
               StringGadget(#String_7, 100, 220, 210, 20, "") 
               StringGadget(#String_8, 100, 250, 210, 20, "") 
               ButtonGadget(#Button_0, 30, 290, 120, 30, "Terminer") 
               ButtonGadget(#Button_1, 190, 290, 120, 30, "Annuler") 
               
          EndIf 
          
          Repeat 
                
               EventID = WaitWindowEvent() 
                
               If EventID = #PB_EventGadget 
                    Select EventGadgetID() ; La gestion des évenements 
                              
                         Case #Button_0 
                              ; L'utilistateur à terminer la saisie des informations 
                              titre$ = GetGadgetText(#String_0) 
                              realisateur$ = GetGadgetText(#String_1) 
                             acteur1$ = GetGadgetText(#String_2) 
                              acteur2$ = GetGadgetText(#String_3) 
                              acteur3$ = GetGadgetText(#String_4) 
                              duree$ = GetGadgetText(#String_5) 
                              origine$ = GetGadgetText(#String_6) 
                              annee$ = GetGadgetText(#String_7) 
                              producteur$ = GetGadgetText(#String_8) 
                              ; On a mémorisé toute les informations utiles 
                              ; on ferme la fenetre. 
                              
                            recapitulatif()
                         Case #Button_1 
                              ; L'utilisateur à changer d'idée, on ferme la fenètre 
                              EventID = #PB_EventCloseWindow 
                              
                    EndSelect 
               EndIf 
          Until EventID = #PB_EventCloseWindow 
          
     EndIf 
     ; On ferme la Fenètre pour la saisie des informations d'un film 
     CloseWindow(#page_film) 

EndProcedure
ouverture_menu()

Procedure recapitulatif()


If OpenWindow(#page_film, 216, 0,430, 400, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar | #PB_Window_WindowCentered, "Récapitulatif des informations pour le nouveau film") 

 

If CreateGadgetList(WindowID())

 ButtonGadget(#sauvegarder,10,340,200,20,"sauvegarder")
  ButtonGadget(#corriger,220,340,200,20,"corriger")
ButtonGadget(#button_2,150,370,200,20,"retour au menu")
 If LoadFont(0,"arial",25,#PB_Font_Underline   )
SetGadgetFont(#pb_default,FontID())


TextGadget(#text_9,10,10,430,40,titre$,#pb_text_center)


SetGadgetFont(#pb_default,#pb_default)
TextGadget(#text_10,10,100,100,20,"Réalisé par :")
TextGadget(#text_11,200,100,50,20,realisateur$)
TextGadget(#text_12,10,130,100,20,"avec entre autre : ")
TextGadget(#text_13,200,130,100,15,acteur1$)
TextGadget(#text_14,200,150,100,15,acteur2$)
TextGadget(#text_15,200,170,100,15,acteur3$)
TextGadget(#text_16,10,200,150,20,"La duree du film est de :")
TextGadget(#text_17,200,200,100,200,duree$)
TextGadget(#text_18,10,230,100,20,"l'origine est : ")
TextGadget(#text_19,200,230,100,20,origine$)
TextGadget(#text_20,10,260,190,20,"l'année de création de "+titre$+" est :")
TextGadget(#text_21,200,260,100,20,annee$)
TextGadget(#text_22,10,290,100,20,"produit par : ")
TextGadget(#text_23,200,290,100,20,producteur$)
EndIf

Repeat
eventid = WaitWindowEvent()
      
      
       If EventID = #PB_EventGadget 
          Select EventGadgetID()
  
  
  Case #corriger
  HideWindow(#page_film,1)
  creation_de_film()
  HideWindow(#page_film,0)
  Case#sauvegarder
 creation_fichier()
  Case#button_2
  HideWindow(#page_film,1)
  
  ouverture_menu()
 HideWindow(#page_film,0)
 EndSelect
EndIf




Until EventID = #PB_EventCloseWindow 
          
EndIf
EndIf

EndProcedure
Procedure creation_fichier()
If CreateFile(0,"catalogue.Txt") 

          
         Titre.s= GetGadgetText(#text_9) 
         realisateur.s=GetGadgetText(#text_11) 
         acteur1.s = GetGadgetText(#text_13) 
         acteur2.s=GetGadgetText(#text_14) 
         acteur3.s=GetGadgetText(#text_15) 
         duree.s=GetGadgetText(#text_17) 
         origine.s=GetGadgetText(#text_19) 
         annee.s=GetGadgetText(#text_21) 
         producteur.s=GetGadgetText(#text_23) 
          
         WriteStringN(Titre) 
         WriteStringN(realisateur) 
         WriteStringN(acteur1) 
         WriteStringN(acteur2) 
         WriteStringN(acteur3) 
          
         WriteStringN(duree) 
         WriteStringN(origine) 
         WriteStringN(annee) 
         WriteStringN(producteur) 
         
         Debug titre
         Debug realisateur
         Debug acteur1
         Debug acteur2
         Debug acteur3
         Debug duree
         Debug origine
         Debug annee
         Debug producteur
          
         CloseFile(0) 
    MessageRequester("validation","le film "+titre+" est bien enregistre")    
Else
MessageRequester("probleme","impossible de creer le fichier",0)
EndIf

EndProcedure

Procedure consultation_de_film()
If OpenWindow(#page_consultation, 216, 0, 343, 333, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar |#pb_window_windowcentered,"consultation du catalogue")

    If CreateGadgetList (WindowID())

    ButtonGadget(#button_consultation_film,8,40,330,20,"consultation film")



Repeat 
                
               EventID = WaitWindowEvent() 
                
               If EventID = #PB_EventGadget 
                    Select EventGadgetID() ; La gestion des évenements 
                              
                         Case #button_consultation_film
                         CloseWindow(#page_consultation)
                         film_video()

EndSelect


EndIf

Until EventID = #PB_EventCloseWindow 


EndIf
EndIf



EndProcedure


Procedure film_video()

If OpenWindow(#film_du_catalogue, 216, 0, 343, 333, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar |#pb_window_windowcentered,"film du catalogue")

If OpenFile(0,"catalogue.txt")

    
 If LoadFont(0,"arial",25,#PB_Font_Underline   )
SetGadgetFont(#pb_default,FontID())


TextGadget(#text_9,10,10,430,40,titre$,#pb_text_center)


SetGadgetFont(#pb_default,#pb_default)
TextGadget(#text_10,10,100,100,20,"Réalisé par :")
TextGadget(#text_11,200,100,50,20,realisateur$)
TextGadget(#text_12,10,130,100,20,"avec entre autre : ")
TextGadget(#text_13,200,130,100,15,acteur1$)
TextGadget(#text_14,200,150,100,15,acteur2$)
TextGadget(#text_15,200,170,100,15,acteur3$)
TextGadget(#text_16,10,200,150,20,"La duree du film est de :")
TextGadget(#text_17,200,200,100,200,duree$)
TextGadget(#text_18,10,230,100,20,"l'origine est : ")
TextGadget(#text_19,200,230,100,20,origine$)
TextGadget(#text_20,10,260,190,20,"l'année de création de "+titre$+" est :")
TextGadget(#text_21,200,260,100,20,annee$)
TextGadget(#text_22,10,290,100,20,"produit par : ")
TextGadget(#text_23,200,290,100,20,producteur$)
EndIf





EndIf
EndIf


EndProcedure

Publié : lun. 15/mars/2004 18:00
par Le Soldat Inconnu
Pour la sauvegarde de la fiche, ça marche : tu crée un fichier "catalogue.txt" dans le m^me répertoire que ton code qui contient bien les infos que j'ai rentré.

Pour la lecture, j'ai pas vu le code qui correspond, tu l'a caché ou ?

bon, c'est plein de prob au niveau de la navigation dans les fenêtres. je vois pour corriger

Publié : lun. 15/mars/2004 18:35
par Le Soldat Inconnu

Code : Tout sélectionner

; déclaration des constantes

Enumeration
  
  #menu
  #Text_0
  #Text_1
  #Text_2
  #Text_3
  #Text_4
  #Text_5
  #Text_6
  #Text_7
  #Text_8
  #text_9
  #text_10
  #text_11
  #text_12
  #text_13
  #text_14
  #text_15
  #text_16
  #text_17
  #text_18
  #text_19
  #text_20
  #text_21
  #text_22
  #text_23
  #text_24
  #text_25
  #String_0
  #String_1
  #String_2
  #String_3
  #String_4
  #String_5
  #String_6
  #String_7
  #String_8
  #Button_0
  #Button_1
  #button_2
  #button_consultation_film
  #consultation
  #film_du_catalogue
  
  #message
  #bouton_inserer
  #page_film
  #sauvegarder
  #corriger
  #gadget_editeur
  #bouton_consulter
  #page_consultation
EndEnumeration

Global titre.s, acteur1.s, realisateur.s, acteur2.s, acteur3.s, duree.s, origine.s, annee.s, producteur.s

Declare creation_de_film(Modification.l)
Declare recapitulatif()
Declare creation_fichier()
Declare consultation_de_film()


Procedure ouverture_menu()
  
  If OpenWindow(#menu, 0, 0, 200, 200, #pb_window_systemmenu | #pb_window_windowcentered, "menu")
    If CreateGadgetList (WindowID())
      ButtonGadget(#bouton_inserer, 10, 10, 180, 20, "INSERER UN FILM")
      ButtonGadget(#bouton_consulter, 10, 40, 180, 20, "CONSULTER LE CATALOGUE")
    EndIf
  EndIf
  
  Repeat
    EventID = WaitWindowEvent()
    
  Until EventID = #PB_EventCloseWindow Or EventID = #PB_EventGadget
  
  CloseWindow(#menu)
  
  If EventID = #PB_EventGadget
    Select EventGadgetID()
        
      Case #bouton_inserer
        ; On initialise les variables, important !
        Titre = ReadPreferenceString("Titre", "")
        realisateur = ""
        acteur1 = ""
        acteur2 = ""
        acteur3 = ""
        duree = ""
        origine = ""
        annee = ""
        producteur = ""
        
        creation_de_film(0)
        
      Case #bouton_consulter
        consultation_de_film()
        
    EndSelect
  EndIf
  
  
  
EndProcedure

Procedure creation_de_film(Modification.l)
  ; Modification = 1 si on modifie la page
  
  If OpenWindow(#page_film, 216, 0, 343, 333, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar | #PB_Window_WindowCentered, "information pour le film")
    If CreateGadgetList(WindowID())
      TextGadget(#Text_0, 10, 10, 90, 20, "Titre du film :")
      TextGadget(#Text_1, 10, 40, 90, 20, "Réalisateur :")
      TextGadget(#Text_2, 10, 70, 90, 20, "Premier acteur :")
      TextGadget(#Text_3, 10, 100, 90, 20, "Deuxième acteur :")
      TextGadget(#Text_4, 10, 130, 90, 20, "Troisième acteur :")
      TextGadget(#Text_5, 10, 160, 90, 20, "Durée :")
      TextGadget(#Text_6, 10, 190, 90, 20, "Origine :")
      TextGadget(#Text_7, 10, 220, 90, 20, "Année :")
      TextGadget(#Text_8, 10, 250, 90, 20, "Producteur :")
      StringGadget(#String_0, 100, 10, 210, 20, Titre)
      StringGadget(#String_1, 100, 40, 210, 20, realisateur)
      StringGadget(#String_2, 100, 70, 210, 20, acteur1)
      StringGadget(#String_3, 100, 100, 210, 20, acteur2)
      StringGadget(#String_4, 100, 130, 210, 20, acteur3)
      StringGadget(#String_5, 100, 160, 210, 20, duree)
      StringGadget(#String_6, 100, 190, 210, 20, origine)
      StringGadget(#String_7, 100, 220, 210, 20, annee)
      StringGadget(#String_8, 100, 250, 210, 20, producteur)
      ButtonGadget(#Button_0, 30, 290, 120, 30, "Terminer")
      ButtonGadget(#Button_1, 190, 290, 120, 30, "Annuler")
      
    EndIf
    
    Recapitulatif = 0
    
    Repeat
      
      EventID = WaitWindowEvent()
      
      If EventID = #PB_EventGadget
        Select EventGadgetID() ; La gestion des évenements
            
          Case #Button_0
            ; L'utilistateur à terminer la saisie des informations
            titre = GetGadgetText(#String_0)
            realisateur = GetGadgetText(#String_1)
            acteur1 = GetGadgetText(#String_2)
            acteur2 = GetGadgetText(#String_3)
            acteur3 = GetGadgetText(#String_4)
            duree = GetGadgetText(#String_5)
            origine = GetGadgetText(#String_6)
            annee = GetGadgetText(#String_7)
            producteur = GetGadgetText(#String_8)
            ; On a mémorisé toute les informations utiles
            ; on ferme la fenetre et on quitte
            CloseWindow(#page_film)
            Recapitulatif = 1
            
          Case #Button_1
            ; L'utilisateur à changer d'idée, on ferme la fenètre
            If Modification ; Si on ne fait que modifier le film, on retourne au récapitulatif
              Recapitulatif = 1
            EndIf
            EventID = #PB_EventCloseWindow
            
        EndSelect
      EndIf
    Until EventID = #PB_EventCloseWindow Or Recapitulatif
    
    ; On ferme la Fenètre pour la saisie des informations d'un film
    CloseWindow(#page_film)
    
    If Recapitulatif
      Recapitulatif()
    Else
      ouverture_menu()
    EndIf
    
  EndIf
EndProcedure

Procedure recapitulatif()
  
  
  If OpenWindow(#page_film, 216, 0, 430, 400, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar | #PB_Window_WindowCentered, "Récapitulatif des informations pour le nouveau film")
    
    If CreateGadgetList(WindowID())
      
      ButtonGadget(#sauvegarder, 10, 340, 200, 20, "sauvegarder")
      ButtonGadget(#corriger, 220, 340, 200, 20, "corriger")
      ButtonGadget(#button_2, 130, 370, 200, 20, "retour au menu")
      
      If LoadFont(0, "arial", 25, #PB_Font_Underline)
        
        
        TextGadget(#text_9, 10, 10, 430, 40, titre, #pb_text_center)
        SetGadgetFont(#text_9, FontID())
        

        TextGadget(#text_10, 10, 100, 100, 20, "Réalisé par :")
        TextGadget(#text_11, 200, 100, 50, 20, realisateur)
        TextGadget(#text_12, 10, 130, 100, 20, "avec entre autre : ")
        TextGadget(#text_13, 200, 130, 100, 15, acteur1)
        TextGadget(#text_14, 200, 150, 100, 15, acteur2)
        TextGadget(#text_15, 200, 170, 100, 15, acteur3)
        TextGadget(#text_16, 10, 200, 150, 20, "La duree du film est de :")
        TextGadget(#text_17, 200, 200, 100, 20, duree)
        TextGadget(#text_18, 10, 230, 100, 20, "l'origine est : ")
        TextGadget(#text_19, 200, 230, 100, 20, origine)
        TextGadget(#text_20, 10, 260, 190, 20, "l'année de création de " + titre + " est :")
        TextGadget(#text_21, 200, 260, 100, 20, annee)
        TextGadget(#text_22, 10, 290, 100, 20, "produit par : ")
        TextGadget(#text_23, 200, 290, 100, 20, producteur)
      EndIf
      
      Repeat
        EventID = WaitWindowEvent()
        
      Until EventID = #PB_EventCloseWindow Or EventID = #PB_EventGadget
      
      CloseWindow(#page_film)
      
      If EventID = #PB_EventGadget
        Select EventGadgetID()
            
          Case #corriger
            creation_de_film(1)
            
          Case #sauvegarder
            creation_fichier()
            
          Case #button_2
            ouverture_menu()
            
        EndSelect
      EndIf
      
    EndIf
  EndIf
  
EndProcedure


Procedure creation_fichier()
  
  ; Demande le nom du fichier à l'utilisateur avec le titre du film en nom par défaut
  Fichier.s = SaveFileRequester("Sauver le fichier", "c:\PureBasic\catalogue\" + Titre + ".txt", "Fichiers texte|*.txt", 0)
  
  If Fichier = "" ; Si la function retourne un texte vide, vous avez appuyé sur annulé
    
    
  Else ; si la fonction SaveFileRequester retourne une valeur
    
    If GetExtensionPart(Fichier) = "" ; si le nom de fichier ne comporte pas d'extension
      Fichier = Fichier + ".txt" ; on ajoute l'extension
    EndIf
    
    If CreatePreferences(Fichier) ; On crée un fichier de préférences, c'est plus simple qu'un fichier normal au niveau de la gestion
      
      WritePreferenceString("Titre", Titre)
      WritePreferenceString("Réalisateur", realisateur)
      WritePreferenceString("Acteur 1", acteur1)
      WritePreferenceString("Acteur 2", acteur2)
      WritePreferenceString("Acteur 3", acteur3)
      WritePreferenceString("Durée", duree)
      WritePreferenceString("Origine", origine)
      WritePreferenceString("Année", annee)
      WritePreferenceString("Producteur", producteur)
      
      ClosePreferences()
      
      MessageRequester("Validation", "Le film " + titre + " est bien enregistré")
      
    Else
      MessageRequester("probleme", "impossible de creer le fichier", 0)
    EndIf
    
  EndIf
  
  Recapitulatif()
  
EndProcedure

Procedure consultation_de_film()
  ; on demande le fichier a ouvrir
  Fichier.s = OpenFileRequester("Ouvrir", "c:\PureBasic\catalogue\", "Films|*.txt", 0)
  
  If Fichier = "" ; on a annulé la demande d'ouverture de fichier
    Ouverture_Menu() ; on retourne au menu
  Else
    If  OpenPreferences(Fichier)
      
      Titre = ReadPreferenceString("Titre", "")
      realisateur = ReadPreferenceString("Réalisateur", "")
      acteur1 = ReadPreferenceString("Acteur 1", "")
      acteur2 = ReadPreferenceString("Acteur 2", "")
      acteur3 = ReadPreferenceString("Acteur 3", "")
      duree = ReadPreferenceString("Durée", "")
      origine = ReadPreferenceString("Origine", "")
      annee = ReadPreferenceString("Année", "")
      producteur = ReadPreferenceString("Producteur", "")
      
      ClosePreferences()
      
      ; on affiche le film
      Recapitulatif()
      
    EndIf
  EndIf
EndProcedure


ouverture_menu()
Donc, les problème sous surtout au niveau de la gestion des fenêtres, ou ça ouvrait des fenêtres sans les fermer, ça en masquait certaine, etc...
j'ai uniformisé en décidant de toujours fermée la fenêtre quan on sorrt d'une procedure.

sinon, pour la gestion de fichier, j'ai utilisé le code que je t'avais passé.
et je suis passé par des fichiers de preferences, je te laisse décourvrir tout ça car ton logiciel marche :wink: sisi

Et pour le "je suis trop nul", on a le droit de te prendre au mot ??

Faut pas être défaitiste :mrgreen:, ton code était pas si mal. on fait toujours ce genre d'erreur quand on débute.

Publié : lun. 15/mars/2004 20:57
par Guimauve
je suis trop nulle
Euh, j'ai eu un cours d'introduction au language C et j'ai des problèmes à coder en PB correctement du premier coup. Ça fait 5 mois déja et je corrige encore des bogues sur mes premiers programmes. Et même sur mon petit dernier, ça fait 3 semaines que je butte sur le même problème. Et pourtant ça l'air facile.

La seule chose que tu peux te reprocher est d'avoir commencer avec un gros projet pour apprendre PB.

Donne toi une chance. Et surtout lâche pas la patate comme on dit. :wink:

A+
Guimauve

Publié : lun. 15/mars/2004 21:25
par Invité
Un autre exemple illustratif avec des tableaux:

Code : Tout sélectionner

;déclaration des constantes 

Enumeration  
  #menu 
  #Text_0 
  #Text_1 
  #Text_2 
  #Text_3 
  #Text_4 
  #Text_5 
  #Text_6 
  #Text_7 
  #Text_8 
  #text_9 
  #text_10 
  #text_11 
  #text_12 
  #text_13 
  #text_14 
  #text_15 
  #text_16 
  #text_17 
  #text_18 
  #text_19 
  #text_20 
  #text_21 
  #text_22 
  #text_23 
  #text_24 
  #text_25 
  #String_0 
  #String_1 
  #String_2 
  #String_3 
  #String_4 
  #String_5 
  #String_6 
  #String_7 
  #String_8
  #String_9  
  #Button_0 
  #Button_1 
  #button_2 
  #button_consultation_film 
  #consultation 
  #film_du_catalogue
  #suivant
EndEnumeration 


Enumeration 
  #page_film 
  #page_consultation 
EndEnumeration

Dim film$(100,9)

Global fiches.l

If CreateFile(0,"catalogue.Txt")=0
  MessageRequester("Info","Fichier non créé")
EndIf

Procedure creation_de_film()  
  If OpenWindow(#page_film, 216, 0, 343, 363, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar | #PB_Window_WindowCentered, "information pour le film") 
    If CreateGadgetList(WindowID())
      TextGadget(#Text_0, 10, 10, 90, 20, "Fiche N°:")
      TextGadget(#Text_0, 10, 40, 90, 20, "Titre du film :") 
      TextGadget(#Text_1, 10, 70, 90, 20, "Réalisateur :") 
      TextGadget(#Text_2, 10, 100, 90, 20, "Premier acteur :") 
      TextGadget(#Text_3, 10, 130, 90, 20, "Deuxième acteur :") 
      TextGadget(#Text_4, 10, 160, 90, 20, "Troisième acteur :") 
      TextGadget(#Text_5, 10, 190, 90, 20, "Durée :") 
      TextGadget(#Text_6, 10, 220, 90, 20, "Origine :") 
      TextGadget(#Text_7, 10, 250, 90, 20, "Année :") 
      TextGadget(#Text_8, 10, 280, 90, 20, "Producteur :")
      StringGadget(#String_9, 100, 10, 50, 20, "")
      StringGadget(#String_0, 100, 40, 210, 20, "") 
      StringGadget(#String_1, 100, 70, 210, 20, "") 
      StringGadget(#String_2, 100, 100, 210, 20, "") 
      StringGadget(#String_3, 100, 130, 210, 20, "") 
      StringGadget(#String_4, 100, 160, 210, 20, "") 
      StringGadget(#String_5, 100, 190, 210, 20, "") 
      StringGadget(#String_6, 100, 220, 210, 20, "") 
      StringGadget(#String_7, 100, 250, 210, 20, "") 
      StringGadget(#String_8, 100, 280, 210, 20, "") 
      ButtonGadget(#Button_0, 100, 320, 80, 30, "Enregistrer") 
      ButtonGadget(#Button_1, 200, 320, 80, 30, "Quitter")
    EndIf 
    fiches=0
    Repeat  
      EventID = WaitWindowEvent()  
      If EventID = #PB_EventGadget 
        Select EventGadgetID() ; La gestion des évenements 
          
          Case #Button_0 ;Bouton enregistrer
            film$(fiches,0) = GetGadgetText(#String_0) 
            film$(fiches,1) = GetGadgetText(#String_1) 
            film$(fiches,2) = GetGadgetText(#String_2) 
            film$(fiches,3) = GetGadgetText(#String_3) 
            film$(fiches,4) = GetGadgetText(#String_4) 
            film$(fiches,5) = GetGadgetText(#String_5) 
            film$(fiches,6) = GetGadgetText(#String_6) 
            film$(fiches,7) = GetGadgetText(#String_7) 
            film$(fiches,8) = GetGadgetText(#String_8)
            film$(fiches,9) = GetGadgetText(#String_9)
            ; On a mémorisé toute les informations utiles 
            
            ;on prépare une nouvelle fiche
            fiches=fiches+1
            SetGadgetText(#String_0,"") 
            SetGadgetText(#String_1,"") 
            SetGadgetText(#String_2,"") 
            SetGadgetText(#String_3,"")
            SetGadgetText(#String_4,"") 
            SetGadgetText(#String_5,"") 
            SetGadgetText(#String_6,"") 
            SetGadgetText(#String_7,"") 
            SetGadgetText(#String_8,"")             
            SetGadgetText(#String_9,"")
            
          Case #Button_1 ;Bouton quitter
            
            ;on enregistre toutes les fiches 
            If OpenFile(0,"catalogue.Txt")
              Debug "------------------"
              encore=0
              While encore<fiches+1
                For a= 0 To 8    
                  WriteStringN(film$(encore,a))
                  Debug a
                Next a
                encore=encore+1
              Wend
              CloseFile(0)
            EndIf
            
            EventID = #PB_EventCloseWindow 
            
        EndSelect 
      EndIf 
    Until EventID = #PB_EventCloseWindow 
    
  EndIf 
EndProcedure 

Procedure Lecture_film_video()  
  If OpenWindow(#film_du_catalogue, 216, 0, 343, 363, #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar |#PB_Window_WindowCentered,"film du catalogue")  
    If OpenFile(0,"catalogue.txt")
      ;Lecture de toutes les fihes et on les rangent dans le tableau
      Repeat
        film$(fiches,0)=ReadString()
        film$(fiches,1)=ReadString()
        film$(fiches,2)=ReadString()
        film$(fiches,3)=ReadString()
        film$(fiches,4)=ReadString()
        film$(fiches,5)=ReadString()
        film$(fiches,6)=ReadString()
        film$(fiches,7)=ReadString()
        film$(fiches,8)=ReadString()
        film$(fiches,9)=ReadString()
        fiches=fiches+1
      Until Eof(0)
    EndIf
    
    If CreateGadgetList(WindowID())       
      If LoadFont(0,"arial",25,#PB_Font_Underline   ) 
        SetGadgetFont(#PB_Default,FontID()) 
        
        TextGadget(#text_9,10,30,430,40,film$(I,0),#PB_Text_Center) 
        
        SetGadgetFont(#PB_Default,#PB_Default) 
        TextGadget(#text_10,10,100,100,20,"Réalisé par :") 
        TextGadget(#text_11,200,100,50,20,film$(I,1)) 
        TextGadget(#text_12,10,130,100,20,"avec entre autre : ") 
        TextGadget(#text_13,200,130,100,15,film$(I,2)) 
        TextGadget(#text_14,200,150,100,15,film$(I,3)) 
        TextGadget(#text_15,200,170,100,15,film$(I,4)) 
        TextGadget(#text_16,10,200,150,20,"La duree du film est de :") 
        TextGadget(#text_17,200,200,100,20,film$(I,5)) 
        TextGadget(#text_18,10,230,100,20,"l'origine est : ") 
        TextGadget(#text_19,200,230,100,20,film$(I,6)) 
        TextGadget(#text_20,10,260,190,20,"l'année de création de "+film$(I,0)+" est :") 
        TextGadget(#text_21,200,260,100,20,film$(I,7)) 
        TextGadget(#text_22,10,290,100,20,"produit par : ") 
        TextGadget(#text_23,200,290,100,20,film$(I,8))
        TextGadget(#text_24,10,10,50,20,"Fiche N°:")
        TextGadget(#text_25,62,10,60,20,film$(I,9))
        
        ButtonGadget(#suivant,100,320,100,20,"Suivant")
        ButtonGadget(#button_2,220,320,100,20,"Quitter")
        
        fiches=0
        Repeat 
          EventID = WaitWindowEvent()  
          If EventID = #PB_EventGadget 
            Select EventGadgetID() 
              
              Case #suivant    ;Bouton suivant
                ; Affichage de l'enregistrement suivant
                fiches=fiches+1
                SetGadgetText(#text_9,film$(fiches,0)) 
                SetGadgetText(#text_11,film$(fiches,1)) 
                SetGadgetText(#text_13,film$(fiches,2)) 
                SetGadgetText(#text_14,film$(fiches,3))
                SetGadgetText(#text_15,film$(fiches,4))
                SetGadgetText(#text_17,film$(fiches,5))
                SetGadgetText(#text_19,film$(fiches,6)) 
                SetGadgetText(#text_20,"l'année de création de "+film$(fiches,0)+" est :") 
                SetGadgetText(#text_21,film$(fiches,7)) 
                SetGadgetText(#text_23,film$(fiches,8))
                SetGadgetText(#text_25,film$(fiches,9))
                
              Case #button_2                
                EventID = #PB_EventCloseWindow
                
            EndSelect 
          EndIf 
          
        Until EventID = #PB_EventCloseWindow  
      EndIf  
    EndIf 
  EndIf  
EndProcedure 

creation_de_film()

Lecture_film_video()
End

Publié : lun. 15/mars/2004 21:27
par nico
:)

Publié : lun. 15/mars/2004 22:35
par Invité
je tiens a vous remercier tous de vos remerciements

ils me vont droit au coeur

et vous m'avez tous donné de quoi travailler

je vous iinforme de la suite des evenements

merci beaucoup
Fuseau horaire sur UTC+01:00
Page 1 sur 1

Développé par phpBB® Forum Software © phpBB Limited

Traduction française officielle © Qiaeru