PureBasic

Code : Tout sélectionner

Enumeration ;- Menu
  #MenuOpen
  #MenuSave
  #MenuQuit
  #MenuHelp
  #MenuAbout
EndEnumeration

Enumeration ;- Gadget 
  #Image1
  #Button1
EndEnumeration

Procedure ShowInformation(Text1.s,Text2.s) ; Show information in the StatusBar
  StatusBarText(0,0,Text1)
  StatusBarText(0,1,Text2)
EndProcedure

OpenWindow(0, 0, 0, 220, 120, #PB_Window_SystemMenu|#PB_Window_ScreenCentered , "Event Example")

;{/ Create the Menu
CreateMenu(0, WindowID())    
MenuTitle("File")
MenuItem(#MenuOpen, "Open")
MenuItem(#MenuSave, "Save")
MenuBar()
MenuItem(#MenuQuit, "Quit")
MenuTitle("Help")
MenuItem(#MenuHelp,"Help")
MenuBar()
MenuItem(#MenuAbout,"About")
;}

;{/ Create the Gadgets
CreateGadgetList(WindowID())
ImageGadget(#Image1, 10, 10, 200, 20, 0,#PB_Image_Border)
ButtonGadget(#Button1, 10, 40, 200, 20, "Button")
;}

;{/ Create the StatusBar
CreateStatusBar(0,WindowID())
AddStatusBarField(110)
AddStatusBarField(110)
;}

;{/ Manage Events
Repeat
  Select WaitWindowEvent()
    
    Case #PB_EventMenu ;- MENU
      Select EventMenuID()  ; To see which menu has been selected
        Case #MenuOpen
          ShowInformation("Menu","Open")
        Case #MenuSave
          ShowInformation("Menu","Save")
        Case #MenuQuit
          ShowInformation("Menu","Quit")
        Case #MenuHelp
          ShowInformation("Menu","Help")
        Case #MenuAbout
          ShowInformation("Menu","About")
      EndSelect
      
    Case #PB_Event_Gadget ;- GADGETS
      Select EventGadgetID()
        
        Case #Image1
          Select EventType() ;- Type of Events
            Case #PB_EventType_LeftClick 
              ShowInformation("Gadget Image 1","Left Click")
            Case #PB_EventType_RightClick
              ShowInformation("Gadget Image 1","Right Click")
          EndSelect
          
        Case #Button1
          ShowInformation("Gadget Button 1","No matter")
      EndSelect
      
    Case #WM_CLOSE ;- CLOSE WINDOWS
      ShowInformation("Close","Windows")
      Delay(1000)
      End
      
  EndSelect
ForEver
;}