PureBasic

Salut,

Je n'arrive pas à initialiser une valeur dans un DateGadget.

Si vous pouviez m'éclairer.

  If OpenWindow(0, 0, 0, 250, 250,"DateGadget", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
    If CreateGadgetList(WindowID(0))
      DateGadget(0, 10, 10, 190, 25, "Date : %dd/%mm/%yyyy Heure : %hh:%ii")
      SetGadgetState(0,Date(2006,9,1,10,12,50))
      Repeat: Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf
  EndIf

Merci!

Sinon il est possible de laisser le champ vide?

Quel champ ?

Le champ DateGadget, est-il possible de le laisser vide ("")?

Je voudrais qu'il n'y ai pas de valeur par défaut!

tu met un espace !

If OpenWindow (0, 0, 0, 250, 250, "DateGadget" , #PB_Window_SystemMenu|#PB_Window_ScreenCentered )
     If CreateGadgetList ( WindowID (0))
         DateGadget (0, 10, 10, 190, 25, " " )
         SetGadgetState (0, Date (2006,9,1,10,12,50))
         Repeat : Until WaitWindowEvent () = #PB_Event_CloseWindow
     EndIf
EndIf

Tu peux feinter en mettant un espace dans le masque au départ, puis remettre le masque normal après avoir choisi la date.

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 250, 250,"DateGadget", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
    If CreateGadgetList(WindowID(0))
      DateGadget(0, 10, 10, 190, 25, " ")
      Repeat
       Evenement = WaitWindowEvent() 
       If Evenement = #PB_Event_Gadget
         If EventGadget() = 0
           SetGadgetText(0,"Date : %dd/%mm/%yyyy")
         EndIf
       EndIf
      Until evenement = #PB_Event_CloseWindow
    EndIf
  EndIf

oui genre çà :

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 250, 250, "DateGadget", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  If CreateGadgetList(WindowID(0))
    DateGadget(0, 10, 10, 200, 21, " Saisir une date...", 0, #PB_Date_CheckBox)
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_Gadget
          Select EventGadget()
            Case 0
              If GetGadgetState(0)
                SetGadgetText(0, "  Le  %dd . %mm . %yyyy  à  %hh h %ii")
              Else
                SetGadgetText(0, " Saisir une date...")
              EndIf
          EndSelect
        Case #PB_Event_CloseWindow
          Break
      EndSelect
    ForEver
  EndIf
EndIf

Apparemment on pourrait laisser un champ vide à la création du DateGadget, mais après si on remet le champ vide, il est alors impossible de choisir une Date, rien ne s'affiche.

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 250, 250, "DateGadget", #PB_Window_SystemMenu|#PB_Window_ScreenCentered) 
  If CreateGadgetList(WindowID(0)) 
    DateGadget(0, 10, 10, 200, 21, "%dd/%mm/%yyyy") 
    ButtonGadget(1,10,40,100,20,"Effacer la date")
    Repeat 
      Select WaitWindowEvent() 
        Case #PB_Event_Gadget 
          Select EventGadget() 
            Case 0 
 
          Case 1
              SetGadgetText(0, " ")
              
          EndSelect 
        Case #PB_Event_CloseWindow 
          Break 
      EndSelect 
    ForEver 
  EndIf 
EndIf

tu peux facilement résoudre ce probleme :

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 250, 250, "DateGadget", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  If CreateGadgetList(WindowID(0))
    DateGadget(0, 10, 10, 200, 21, "%dd/%mm/%yyyy")
    ButtonGadget(1,10,40,100,20,"Effacer la date")
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_Gadget
          Select EventGadget()
            Case 0
              If GetGadgetState(0) ;And (EventType()=0)
                SetGadgetText(0, "%dd/%mm/%yyyy")
              EndIf
            Case 1
              SetGadgetText(0, " ")
          EndSelect
        Case #PB_Event_CloseWindow
          Break
      EndSelect
    ForEver
  EndIf
EndIf

Merci à vous tous!

PureBasic

Initialiser une valeur dans un DateGadget

Initialiser une valeur dans un DateGadget