Aktuelle Zeit: 23.01.2018 19:40

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]




Ein neues Thema erstellen Auf das Thema antworten  [ 6 Beiträge ] 
Autor Nachricht
 Betreff des Beitrags: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 03.11.2017 19:28 
Offline
Benutzeravatar

Registriert: 15.11.2010 10:56
Hallo Leute,

mit dem Befehl

Zitat:
Debug GetPathPart("D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\Folder.jpg")


erhalte ich den

Zitat:
"D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\"


Gibt es eine Möglichkeit das ich

Zitat:
"00 Schneider Im Wendezeichen der Eidechse (2013)"


als String zurück bekomme!

Hat jemand eine Idee?

Gruss ... Velindos

_________________
Windows 7/8/8.1/10 (32/64-Bit) |Ubuntu 10.4 (64-Bit) |Purebasic 5.43 LTS (32/64-Bit)


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 03.11.2017 19:45 
Offline
Benutzeravatar

Registriert: 08.09.2004 00:57
Wohnort: Berlin
Zitat:
Gibt es eine Möglichkeit das ich

Sehr viele :D
z.B.
Code:
Debug StringField("D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\Folder.jpg", CountString("D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\Folder.jpg", "\"), "\")

_________________
PureBasic 5.61 | SpiderBasic 2.10 | Windows 10 Pro (x64) | Linux Mint 18.3 (x64)
"Ich möchte gerne die Welt verändern, doch Gott gibt den Quellcode nicht frei."
Bild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 03.11.2017 19:52 
Offline
Benutzeravatar

Registriert: 11.08.2005 19:08
Code:
Debug GetFilePart(RTrim(GetPathPart("D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\Folder.jpg"), "\"))

_________________
Bild

PureBasic-CodeArchiv-Rebirth: Git-Repository / Download -- Jede Hilfe ist willkommen!

Manjaro Xfce x64 (Hauptsystem) :: WindowsXP/Xubuntu x86 (VirtualBox) :: PureBasic (Linux: x86/x64, Windows: x86) :: jeweils neueste Version


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 03.11.2017 20:04 
Offline
Benutzeravatar

Registriert: 24.11.2004 13:12
Wohnort: Germany
Gerade im englischen Forum gepostet
Code:
;-TOP

; Comment : SplitString to list with option double-quotes
; Author  : mk-soft
; Version : v1.03
; Created : 03.11.2017
; Updated :
; Link GR :
; Link EN :

; OS      : All

; ***************************************************************************************

Procedure SplitString(String.s, Separator.s, List Result.s(), DQuote = #False)
  Protected *String.character, *Separator.character
  Protected *Start, *End, exit, lock, do, dq, len
 
  ClearList(Result())
  *String = @String
  *Separator = @Separator
  *Start = *String
  *End = *String
  Repeat
    If *String\c = 0
      exit = #True
      do = #True
      If Not dq
        *End = *String
      EndIf
    Else
      If DQuote And *String\c = '"'
        If Not lock
          lock = #True
          dq = #True
          *Start = *String + SizeOf(character)
        Else
          lock = #False
          *End = *String
        EndIf
      EndIf
      If *String\c = *Separator\c And Not lock
        do = #True
        If Not dq
          *End = *String
        EndIf
      EndIf
    EndIf
    If do
      AddElement(Result())
      len = (*End - *Start) / SizeOf(character)
      If Len > 0
        Result() = PeekS(*Start, len)
      EndIf
      *Start = *String + SizeOf(character)
      do = #False
      dq = #False
    EndIf
    *String + SizeOf(character)
  Until exit
  ProcedureReturn ListSize(Result())
EndProcedure

; ***************************************************************************************

;-Test

CompilerIf #PB_Compiler_IsMainFile
 
  Global NewList r1.s()
  Global text.s = "0;1x;2xx;'Text with separator (;)';4xxxx;5xxxxx;'Text with linefeed " + #LF$ + "and separator (;)';End"
  text = ReplaceString(text, "'", #DQUOTE$)
  ;text = "Hello World"
  Debug "Text = " + text
  Debug "Count = " + SplitString(text, ";", r1(), #True)
  ForEach r1()
    Debug "#"+r1()+"#"
  Next
 
  text = "D:\INFORMENT\[TRAILER]\00 Schneider Im Wendezeichen der Eidechse (2013)\Folder.jpg"
  Debug "Count = " + SplitString(text, "\", r1())
  ForEach r1()
    Debug "#"+r1()+"#"
  Next
 
CompilerEndIf

_________________
Alles ist möglich, fragt sich nur wie...
Projekte EventDesigner v1.x / OOP-BaseClass-Modul / OPC-Helper DLL
PB v3.30 / v5.4x - OS Mac Mini OSX 10.xx / Window 10 Pro. (X64) /Window 7 Pro. (X64) / Window XP Pro. (X86) / Ubuntu 14.04
Downloads auf Webspace


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 04.11.2017 13:03 
Offline
Benutzeravatar

Registriert: 15.11.2010 10:56
Hallo Leute,

DANKE für die Tips, jetzt kann ich das Verzeichnis auslesen!

Gruss ... Velindos

_________________
Windows 7/8/8.1/10 (32/64-Bit) |Ubuntu 10.4 (64-Bit) |Purebasic 5.43 LTS (32/64-Bit)


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Verzeichnis Namen aus Pfad auslesen
BeitragVerfasst: 04.11.2017 19:51 
Offline
Benutzeravatar

Registriert: 20.06.2013 23:27
da gibts ein schönes Tool:

folder2txt Info und Runterladen

Bild

programmiert mit PureBasic :)

_________________
PureBasic v5.3 + v5.44 LTS + v5.6 | Windows 7 x64 - Gforce GTX 950 - AMD FX6200 Six Core 3.80 | 26GB RAM


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 6 Beiträge ] 

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.

Suche nach:
Gehe zu:  

 


Powered by phpBB © 2008 phpBB Group | Deutsche Übersetzung durch phpBB.de
subSilver+ theme by Canver Software, sponsor Sanal Modifiye