Aktuelle Zeit: 05.07.2020 18:09

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]




Ein neues Thema erstellen Auf das Thema antworten  [ 3 Beiträge ] 
Autor Nachricht
 Betreff des Beitrags: Font ändern über Requester
BeitragVerfasst: 08.04.2019 13:21 
Offline
Benutzeravatar

Registriert: 15.11.2010 10:56
Hallo Leute,

wähle italic und wird nicht übernommen.
Auch zwei Para´s übernimmt er nicht!

Code:
; ----------------------
; FONT ÄNDERN über REQUESTER
; ----------------------

Global Hwnd
Global Rt_Btn_Fontrequeter
Global Rt_Gadget_FontText

Global Rt_Req_Font_Name$  = "Arial"
Global Rt_Req_Font_Size   = 10
Global Rt_Req_Font_Color  = $0045FF
Global Rt_Req_Back_Color  = $FFFFFF
Global Rt_DrawingFont_Requester = LoadFont(#PB_Any, Rt_Req_Font_Name$, Rt_Req_Font_Size)

Procedure Rt_Requester_Font_Wahl()
  Protected Rt_Req_Font_Result
  ; ----------------------------------------
  Rt_Req_Font_Result = FontRequester(Rt_Req_Font_Name$, Rt_Req_Font_Size, #PB_FontRequester_Effects, Rt_Req_Font_Color)
  ; ----------------------------------------
  If Rt_Req_Font_Result
    ; ----------------------------------------
    If IsFont(Rt_DrawingFont_Requester) : FreeFont(Rt_DrawingFont_Requester): EndIf
    ; ----------------------------------------
    Rt_Req_Font_Name$ = SelectedFontName()
    Rt_Req_Font_Size  = SelectedFontSize()
    Rt_Req_Font_Color = SelectedFontColor()
    ; ----------------------------------------
    Rt_DrawingFont_Requester = LoadFont(#PB_Any, Rt_Req_Font_Name$, Rt_Req_Font_Size,
                              SelectedFontStyle() & #PB_Font_Bold|
                              SelectedFontStyle() & #PB_Font_Italic|
                              SelectedFontStyle() & #PB_Font_Underline|
                              SelectedFontStyle() & #PB_Font_StrikeOut|
                              #PB_Font_HighQuality )
    ; ----------------------------------------
    SetGadgetFont(Rt_Gadget_FontText,FontID(Rt_DrawingFont_Requester))
   SetGadgetColor(Rt_Gadget_FontText, #PB_Gadget_FrontColor, Rt_Req_Font_Color)
  SetGadgetColor(Rt_Gadget_FontText, #PB_Gadget_BackColor, Rt_Req_Back_Color)
 EndIf
  ; ----------------------------------------
EndProcedure

;{ Window
Hwnd = OpenWindow(#PB_Any, 0, 0, 300, 200, "FONT ÄNDERN über REQUESTER", #PB_Window_ScreenCentered | #PB_Window_SystemMenu)
Rt_Btn_Fontrequeter = ButtonGadget(#PB_Any, 10,150, 100, 20, "Font ändern")
Rt_Gadget_FontText = TextGadget(#PB_Any, 10,10, 280, 140, "Beispieltext")
SetGadgetFont(Rt_Gadget_FontText, FontID(Rt_DrawingFont_Requester))

;}

Repeat
  Event = WaitWindowEvent()
  Select Event
    Case #PB_Event_Gadget
      ;{ GADGET
      Select EventGadget()
         
        Case Rt_Btn_Fontrequeter
          Rt_Requester_Font_Wahl()
      EndSelect
  EndSelect
Until Event = #PB_Event_CloseWindow


Gruss ... Velindos!

_________________
Windows 7/8/8.1/10 (32/64-Bit) |Ubuntu 10.4 (64-Bit) |Purebasic 5.43 LTS (32/64-Bit)


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: FONT ÄNDERN über REQUESTER
BeitragVerfasst: 08.04.2019 13:43 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Gernsbach
So geht es:
Code:
; ----------------------
; FONT ÄNDERN über REQUESTER
; ----------------------

Global Hwnd
Global Rt_Btn_Fontrequeter
Global Rt_Gadget_FontText

Global Rt_Req_Font_Name$  = "Arial"
Global Rt_Req_Font_Size   = 10
Global Rt_Req_Font_Color  = $0045FF
Global Rt_Req_Back_Color  = $FFFFFF
Global Rt_Req_Font_Style  = 0
Global Rt_DrawingFont_Requester = LoadFont(#PB_Any, Rt_Req_Font_Name$, Rt_Req_Font_Size)

Procedure Rt_Requester_Font_Wahl()
  Protected Rt_Req_Font_Result
  ; ----------------------------------------
  Rt_Req_Font_Result = FontRequester(Rt_Req_Font_Name$, Rt_Req_Font_Size, #PB_FontRequester_Effects, Rt_Req_Font_Color)
  ; ----------------------------------------
  If Rt_Req_Font_Result
    ; ----------------------------------------
    If IsFont(Rt_DrawingFont_Requester) : FreeFont(Rt_DrawingFont_Requester): EndIf
    ; ----------------------------------------
    Rt_Req_Font_Name$ = SelectedFontName()
    Rt_Req_Font_Size  = SelectedFontSize()
    Rt_Req_Font_Color = SelectedFontColor()
    Rt_Req_Font_Style = SelectedFontStyle()
    ; ----------------------------------------
    Rt_DrawingFont_Requester = LoadFont(#PB_Any, Rt_Req_Font_Name$, Rt_Req_Font_Size, Rt_Req_Font_Style)
    ; ----------------------------------------
    SetGadgetFont(Rt_Gadget_FontText,FontID(Rt_DrawingFont_Requester))
   SetGadgetColor(Rt_Gadget_FontText, #PB_Gadget_FrontColor, Rt_Req_Font_Color)
  SetGadgetColor(Rt_Gadget_FontText, #PB_Gadget_BackColor, Rt_Req_Back_Color)
 EndIf
  ; ----------------------------------------
EndProcedure

;{ Window
Hwnd = OpenWindow(#PB_Any, 0, 0, 300, 200, "FONT ÄNDERN über REQUESTER", #PB_Window_ScreenCentered | #PB_Window_SystemMenu)
Rt_Btn_Fontrequeter = ButtonGadget(#PB_Any, 10,150, 100, 20, "Font ändern")
Rt_Gadget_FontText = TextGadget(#PB_Any, 10,10, 280, 140, "Beispieltext")
SetGadgetFont(Rt_Gadget_FontText, FontID(Rt_DrawingFont_Requester))

;}

Repeat
  Event = WaitWindowEvent()
  Select Event
    Case #PB_Event_Gadget
      ;{ GADGET
      Select EventGadget()
         
        Case Rt_Btn_Fontrequeter
          Rt_Requester_Font_Wahl()
      EndSelect
  EndSelect
Until Event = #PB_Event_CloseWindow

_________________
BildBildBildBild BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Font ändern über Requester
BeitragVerfasst: 08.04.2019 14:54 
Offline
Benutzeravatar

Registriert: 15.11.2010 10:56
Hallo RSBasic,

Danke, habe ich nicht gewusst! Funzt!

Gruss ... Velindos!

_________________
Windows 7/8/8.1/10 (32/64-Bit) |Ubuntu 10.4 (64-Bit) |Purebasic 5.43 LTS (32/64-Bit)


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 3 Beiträge ] 

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 9 Gäste


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.

Suche nach:
Gehe zu:  

 


Powered by phpBB © 2008 phpBB Group | Deutsche Übersetzung durch phpBB.de
subSilver+ theme by Canver Software, sponsor Sanal Modifiye