Aktuelle Zeit: 24.09.2017 10:31

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]




Ein neues Thema erstellen Auf das Thema antworten  [ 16 Beiträge ]  Gehe zu Seite Vorherige  1, 2
Autor Nachricht
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 24.11.2015 15:49 
Offline
Benutzeravatar

Registriert: 25.01.2005 12:19
Kukulkan hat geschrieben:
Allerdings muss ich vorher noch die Positionen ermitteln, damit ich bei einem Restart des Programms an exakt die selbe Position scrollen kann. Hat jemand auch dazu die passenden Befehle um die Position zu ermitteln?

Ich hatte im englischen Forum bereits einmal ein Beispiel von Blue, das unter Windows die oberste sichtbare Zeile in einem ListViewGadget ermittelt, um den Linux- und Mac-spezifischen Teil erweitert:
http://www.purebasic.fr/english/viewtop ... 25&start=6

Für ein ListIconGadget muß in der dort gezeigten Prozedur GetVisibleTopRow() lediglich für Windows in der SendMessage_()-Funktion die Konstante #LB_GETTOPINDEX (ListBox bei Microsoft, ListViewGadget bei PureBasic) gegen #LVM_GETTOPINDEX (ListView bei Microsoft, ListIconGadget bei PureBasic) ausgetauscht werden.

Ich habe trotzdem noch einmal ein komplett neues Beispiel erstellt, das bei Betätigen der Schaltfläche "Get current top row" im Fenstertitel die Zeilennummer der obersten sichtbaren Zeile anzeigt. Zu beachten ist, dass - wie in meinem englischen Posting erwähnt - betriebssystembedingt bei Linux und MacOS als oberste Zeile auch eine oberste Zeile angegeben wird, die nur teilweise sichtbar ist. Wenn man nur die Zeilennummer der obersten voll sichtbaren Zeile haben möchte, müßte man die Zeilennummer bei Linux und MacOS entsprechend aufrunden.

Ich habe das Beispiel erfolgreich unter folgenden Betriebssystemen getestet:
- MacOS X 10.6.8 (Snow Leopard)
- Ubuntu 12.04 x64 mit KDE (Gtk2 und Gtk3)
- Windows 7 x64 SP1
Code:
CompilerIf #PB_Compiler_OS = #PB_OS_Linux
  ImportC ""
    gtk_tree_view_get_visible_range(*TreeView.GtkTreeView, *StartPath, *EndPath)
  EndImport
CompilerEndIf

Procedure.I GetVisibleTopRow(ListIconID.I)
  Protected VisibleTopRow.I

  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Linux
      Protected *EndPath
      Protected *StartPath

      If gtk_tree_view_get_visible_range(GadgetID(ListIconID), @*StartPath, @*EndPath)
        VisibleTopRow = PeekI(gtk_tree_path_get_indices_(*StartPath))
        gtk_tree_path_free_(*StartPath)
        gtk_tree_path_free_(*EndPath)
      EndIf
    CompilerCase #PB_OS_MacOS
      Protected ContentView.I
      Protected EnclosingScrollView.I
      Protected VisibleRange.NSRange
      Protected VisibleRect.NSRect
     
      ; ----- Get scroll view inside of ListIconGadget
      EnclosingScrollView = CocoaMessage(0, GadgetID(ListIconID), "enclosingScrollView")
     
      If EnclosingScrollView
        ContentView = CocoaMessage(0, EnclosingScrollView, "contentView")
        ; ----- Get visible area
        ;       (automatically subtract horizontal scrollbar if shown)
        CocoaMessage(@VisibleRect, ContentView, "documentVisibleRect")
        ; ----- Subtract border width
        If CocoaMessage(0, EnclosingScrollView, "borderType") > 0
          VisibleRect\size\height - 5
        EndIf
        ; ----- Get visible top row
        CocoaMessage(@VisibleRange, GadgetID(ListIconID), "rowsInRect:@", @VisibleRect)
        VisibleTopRow = Int(VisibleRange\location)
      EndIf
    CompilerCase #PB_OS_Windows
      VisibleTopRow = SendMessage_(GadgetID(ListIconID), #LVM_GETTOPINDEX, 0, 0)
  CompilerEndSelect

  ProcedureReturn VisibleTopRow
EndProcedure

OpenWindow(0, 100, 100, 200, 155, "")
ListIconGadget(0, 10, 10, WindowWidth(0) - 20, WindowHeight(0) - 55, "Column 1",
  100)
ButtonGadget(1, 10, WindowHeight(0) - 35, WindowWidth(0) - 20, 25,
  "Get current top row")

For i = 1 To 50
  AddGadgetItem(0, -1, "Item " + Str(i))
Next i

SetWindowTitle(0, "Top row: " + Str(GetVisibleTopRow(0) + 1))

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow
      Break
    Case #PB_Event_Gadget
      If EventGadget() = 1
        SetWindowTitle(0, "Top row: " + Str(GetVisibleTopRow(0) + 1))
      EndIf
  EndSelect
ForEver


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 24.11.2015 16:06 
Offline
Benutzeravatar

Registriert: 09.09.2004 07:07
Wohnort: Süddeutschland
Hallo Shardik,

Super, DANKE! :allright: <)

_________________
http://www.x-beliebig.info


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 24.11.2015 16:32 
Offline

Registriert: 21.11.2013 21:17
Wohnort: Schweiz
Warum heisst Listicongadget Listview und ListViewGadget Listbox? Warum so verdreht? Warum nicht einheitlich Listbox = Listboxgadget und Listview = Listviewgadget ?
Wie kam man den überhaupt auf diese Idee mit den Bezeichnungen? Hat das einen bestimmten Grund? Heisst auf Linux diese gtk Controls so? oder beim Macintosh? :?


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 17.08.2017 09:59 
Offline

Registriert: 21.11.2013 21:17
Wohnort: Schweiz
Ich warte schon so lange auf eine Antwort und fast jeden Tag schau ich rein aber immer noch keine Antwort. Weiss den keiner warum das so is?


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 17.08.2017 11:06 
Offline
Ein Admin
Benutzeravatar

Registriert: 29.08.2004 20:20
Wohnort: Saarbrücken
Nein. :wink:

_________________
Freakscorner.de - Der Bastelkeller | Neustes Video: Unser Anet A8 3D-Drucker und sein Zusammenbau
Ubuntu Gnome 16.04.3 LTS x64, PureBasic 5.60 x64 (außerdem 4.41, 4.50, 4.61, 5.00, 5.10, 5.11, 5.21, 5.22, 5.30, 5.31, 5.40, 5.50)
"Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen – Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen."


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: editorgadget scrollen (gelöst)
BeitragVerfasst: 02.09.2017 08:42 
Offline

Registriert: 29.08.2004 13:18
NeoChris hat geschrieben:
Ich warte schon so lange auf eine Antwort und fast jeden Tag schau ich rein aber immer noch keine Antwort. Weiss den keiner warum das so is?


Vermutlich historisch begründet. Ich würde auf die Amiga-Version tippen. Möglich das es dort "gedreht" ist.

_________________
CodeArchiv Rebirth: Deutsches Forum Github Hilfe ist immer gern gesehen!


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 16 Beiträge ]  Gehe zu Seite Vorherige  1, 2

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.

Suche nach:
Gehe zu:  

 


Powered by phpBB © 2008 phpBB Group | Deutsche Übersetzung durch phpBB.de
subSilver+ theme by Canver Software, sponsor Sanal Modifiye