Aktuelle Zeit: 23.08.2019 21:42

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]




Ein neues Thema erstellen Auf das Thema antworten  [ 81 Beiträge ]  Gehe zu Seite Vorherige  1 ... 5, 6, 7, 8, 9  Nächste
Autor Nachricht
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 23.10.2018 09:36 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Mit dieser Funktion kann man Gadgets in ein anderes Fenster verschieben:
Code:
EnableExplicit

Procedure MoveGadget(gadget, target_windowid)
  ! var GadgetElement = $(spider_GadgetID(v_gadget).div);
  ! GadgetElement.appendTo(v_target_windowid.content);
 
EndProcedure

;================================================== Beispielcode ==================================================

Procedure GadgetEvent()
  Select EventGadget()
    Case 2
      MoveGadget(1, WindowID(1))
    Case 3
      MoveGadget(1, WindowID(0))
  EndSelect
 
EndProcedure

If OpenWindow(0, 100, 100, 300, 200, "Window 1")
  ButtonGadget(1, 10, 10, 100, 20, "Button 007", 0)
  ButtonGadget(2, 120, 10, 150, 20, "Move button 007 >>", 0)
  ButtonGadget(3, 120, 40, 150, 20, "<< Move button 007", 0)
 
  BindEvent(#PB_Event_Gadget, @GadgetEvent())
 
EndIf

If OpenWindow(1, 500, 100, 300, 200, "Window 2")
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 23.10.2018 10:27 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Browser-Name ermitteln:
Code:
EnableExplicit

Procedure.s GetBrowserName()
  ! return platform.name;
 
EndProcedure

;================================================== Beispielcode ==================================================

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_ScreenCentered)
  Debug GetBrowserName()
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 23.10.2018 10:28 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Browser-Version ermitteln:
Code:
EnableExplicit

Procedure.s GetBrowserVersion()
  ! return platform.version;
 
EndProcedure

;================================================== Beispielcode ==================================================

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_ScreenCentered)
  Debug GetBrowserVersion()
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 23.10.2018 10:28 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Browser-Engine ermitteln:
Code:
EnableExplicit

Procedure.s GetBrowserEngine()
  ! return platform.layout;
 
EndProcedure

;================================================== Beispielcode ==================================================

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_ScreenCentered)
  Debug GetBrowserEngine()
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 23.10.2018 11:17 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Mit dieser Funktion kann man eine interne oder externe Seite in einem Popup-Fenster aufrufen:
Code:
EnableExplicit

Procedure OpenDialog(url.s, x, y, width, height, showtoolbar, showscrollbars)
  Protected specs.s
 
  If x <> #PB_Ignore
    specs + "left=" + x + ","
  EndIf
  If y <> #PB_Ignore
    specs + "top=" + y + ","
  EndIf
  specs + "width=" + width + ",height=" + height + ",toolbar=" + showtoolbar + ",scrollbars=" + showscrollbars
 
  ! window.open(v_url, "", v_specs);
 
EndProcedure

Procedure.s GetSiteURL()
  ! return window.location;
 
EndProcedure

;================================================== Beispielcode ==================================================

Procedure GadgetEvent()
  Select EventGadget()
    Case 1
      ;OpenDialog("http://www.google.de", #PB_Ignore, #PB_Ignore, 500, 400, 0, 1)
      OpenDialog(GetSiteURL(), #PB_Ignore, #PB_Ignore, 500, 400, 0, 1)
  EndSelect
 
EndProcedure

If OpenWindow(0, 0, 0, 400, 300, "Window", #PB_Window_ScreenCentered)
  ButtonGadget(1, 10, 10, 200, 20, "Open site in dialog", 0)
 
  BindEvent(#PB_Event_Gadget, @GadgetEvent())
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 25.10.2018 09:32 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Deutschland::Berlin()
Die Möglichkeit, einen Placeholder-Text hinzuzufügen, besteht nur beim StringGadget, aber nicht beim EditorGadget und andere Input-Gadgets. Jetzt es ist auch beim EditorGadget, SpinGadget, DateGadget und ComboBoxGadget möglich. Außerdem kann man den Placeholder-Text auch jederzeit wieder ändern:
Code:
EnableExplicit

Procedure SetGadgetPlaceHolder(gadget, text.s)
  ! var GadgetElement = $(spider_GadgetID(v_gadget).div);
 
  Select GadgetType(gadget)
    Case #PB_GadgetType_String, #PB_GadgetType_Spin, #PB_GadgetType_Date, #PB_GadgetType_ComboBox
      ! GadgetElement.find("input").attr("placeholder", v_text);
    Case #PB_GadgetType_Editor
      ! GadgetElement.find("textarea").attr("placeholder", v_text);
  EndSelect
 
EndProcedure

;================================================== Beispielcode ==================================================

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_ScreenCentered)
  StringGadget(1, 10, 10, 200, 20, "", 0)
  EditorGadget(2, 10, 40, 200, 200, 0)
  SpinGadget(3, 10, 250, 90, 20, 0, 100, 0)
  ComboBoxGadget(4, 110, 250, 100, 20, #PB_ComboBox_Editable)
 
  SetGadgetPlaceHolder(1, "Hello")
  SetGadgetPlaceHolder(2, "Hola")
  SetGadgetPlaceHolder(3, "Hallo")
  SetGadgetPlaceHolder(4, "Hallo")
 
EndIf

_________________
BildBildBildBild(Update: 17.08.2019 (+196 Dateien, +1392 MB)) BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 06.02.2019 15:27 
Offline
Benutzeravatar

Registriert: 08.09.2004 08:53
Danke RSBasic, für deine Erweiterungen. Habe ich schon öfters gebrauchen können.

Da ich eben noch für ein TextGadget (), das ich zur Anzeige von Html verwende, den Scrollbalken aktivieren musste,
hier eine Adaption:

Code:
Procedure Gadget_Enable_AutoScroll (gadget)
  Protected styles.s
  Protected id.s
 
  ;Falls nicht existiert, dann <style type="text/css" id="SBCustomStyles"></style> im Head erstellen, ohne Inline-Styles verwenden zu müssen
  ! if (!document.getElementById('SBCustomStyles')) {
  !   var StyleElement = document.createElement('style');
  !   StyleElement.type = 'text/css';
  !   StyleElement.id = 'SBCustomStyles';
  !   var HeadElement = document.getElementsByTagName('head')[0];
  !   HeadElement.appendChild(StyleElement);
  ! }
 
  ;Falls nicht existiert, dann eine ID im Hauptelement erstellen, um später per CSS besser darauf zugreifen zu können
  ! var GadgetElement = $(spider_GadgetID(v_gadget).div);
  ! if (GadgetElement.attr("id")) {
  !   v_id = GadgetElement.attr("id");
  ! } else {
  !   GadgetElement.attr("id", "SB_Gadget_" + v_gadget);
  !   v_id = GadgetElement.attr("id");
  ! }
 
  styles = "#" + id + " { overflow: auto; }"
 
  ;Styles hinzufügen
  ! document.getElementById("SBCustomStyles").appendChild(document.createTextNode( v_styles ));
 
EndProcedure

_________________
"Papa, mein Wecker funktioniert nicht! Der weckert immer zu früh."


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 06.02.2019 15:55 
Offline
Ein Admin
Benutzeravatar

Registriert: 29.08.2004 20:20
Wohnort: Saarbrücken
RSBasic hat geschrieben:
@NicTheQuick
Bekomme ich Geld für die Werbung? :D

Gerade erst gesehen, weil ich normalerweise nichts zu Spiderbasic lese. :lol:
Ich kann dir leider nichts anbieten. :wink:

_________________
Freakscorner.de - Der Bastelkeller | Neustes Video: Neje DK - 1 Watt Laser Engraver
Ubuntu Gnome 18.04.1 LTS x64, PureBasic 5.60 x64 (außerdem 4.41, 4.50, 4.61, 5.00, 5.10, 5.11, 5.21, 5.22, 5.30, 5.31, 5.40, 5.50)
"Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen – Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen."


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 07.02.2019 10:28 
Offline

Registriert: 19.10.2014 15:51
dige, ich habe deine Procedure eben getestst. Da scrollt aber nichts automatisch runter.
Oder habe ich da was falsch verstanden?
Wie muss die Procedure eingesetzt werden?


Nachdem ich einem Textgadget einen Text hinzugefügt gabe, muss ich zudem:
Code:
 !$(v_chatid.div).animate({scrollTop: $(v_chatid.div).prop("scrollHeight")}, 0);


machen, sonst wird nicht gescrollt.

_________________
Ich programmiere plattformunabhängig und suche immer Lösungen für alle Plattformen.
Win 7/10, Linux Mageia 6,Linux Mint 18.3 / 19.1


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: SpiderBasic Library - Liste neuer Funktionen
BeitragVerfasst: 07.02.2019 10:52 
Offline
Benutzeravatar

Registriert: 08.09.2004 08:53
@Stevie1401: es werden nur die Scrollbalken aktiviert, damit der Nutzer scrollen kann. Im Prinzip wird nur der Style "overflow: auto;" hinzugefügt.

_________________
"Papa, mein Wecker funktioniert nicht! Der weckert immer zu früh."


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 81 Beiträge ]  Gehe zu Seite Vorherige  1 ... 5, 6, 7, 8, 9  Nächste

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.

Suche nach:
Gehe zu:  

 


Powered by phpBB © 2008 phpBB Group | Deutsche Übersetzung durch phpBB.de
subSilver+ theme by Canver Software, sponsor Sanal Modifiye