PureBoard

Code: Alles auswählen

EnableExplicit

UseZipPacker()

Global *worksheet
Global worksheet_size.i
Global xml_node.i
Global index.i

Procedure FillTree(*CurrentNode,CurrentSublevel.i)
  Protected text.s
  Protected *child
  If XMLNodeType(*CurrentNode) = #PB_XML_Normal
    text = GetXMLNodeName(*CurrentNode) + " (Attributes: "
    If ExamineXMLAttributes(*CurrentNode)
      While NextXMLAttribute(*CurrentNode)
        text + XMLAttributeName(*CurrentNode) + "=" + Chr(34) + XMLAttributeValue(*CurrentNode) + Chr(34) + " "
      Wend
    EndIf
    AddGadgetItem(4, -1, text, 0, CurrentSublevel)   
    *child = ChildXMLNode(*CurrentNode)
    While *child
      FillTree(*child, CurrentSublevel + 1)      
      *child = NextXMLNode(*child)
    Wend        
  EndIf
EndProcedure

If OpenPack(0,"dummy.xlsx");<- change!!!
  If ExaminePack(0)
    While NextPackEntry(0)
      If Right(PackEntryName(0),12) = "workbook.xml"
        worksheet_size = PackEntrySize(0,#PB_Packer_UncompressedSize)
        If worksheet_size
          *worksheet = AllocateMemory(worksheet_size)
          If *worksheet
            If UncompressPackMemory(0,*worksheet,worksheet_size) = worksheet_size
              If CatchXML(1,*worksheet,worksheet_size)
                If OpenWindow(3,0,0,600,400, "Excel Worksheet",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
                  TreeGadget(4,10,10,580,380)
                  xml_node = MainXMLNode(1)      
                  If xml_node
                    FillTree(xml_node,0)
                  EndIf
                  For index = 0 To CountGadgetItems(4) - 1
                    SetGadgetItemState(4,index,#PB_Tree_Expanded)
                  Next
                  Repeat
                  Until WaitWindowEvent() = #PB_Event_CloseWindow
                EndIf
                FreeXML(1)
              EndIf 
            EndIf 
          EndIf
        EndIf
        Break
      EndIf
    Wend
  EndIf
  ClosePack(0)
EndIf   

End