debug Structure

marcelx · **Registriert:** 19.02.2010 20:19 **Wohnort:** Darmstadt

Hallo,

wie kann ich Daten mit structure ausgeben ohne einzelnen zu ausgeben per Debug?

Code:

Structure _pos
  x.i
  y.i  
EndStructure

Structure _dimension
  w.i
  h.i  
EndStructure

Structure _list
  name.s
  pos.i  
EndStructure

Structure _specifications
  List._list
  pos._pos
  dimension._dimension
  name.s
EndStructure

NewList specifications._specifications()

AddElement(specifications())

With specifications()
  \name = "Test"
  \pos\x = 10
  \pos\y = 20
  \dimension\h = 15
  \dimension\w = 25
  \list\name = "Test list"
  \list\pos = 1
EndWith

Debug specifications()  ???

Gruss
MarcelX

STARGÅTE · **Registriert:** 01.11.2005 13:34 **Wohnort:** Glienicke

z.B. mit JSON, die Hilfe zeigt hier sogar ein Beispiel wie du es hast:
https://www.purebasic.com/documentation/json/insertjsonstructure.html

#NULL · **Registriert:** 20.04.2006 09:50

Code:

json = CreateJSON(#PB_Any)
InsertJSONList(JSONValue(json), specifications())
Debug ComposeJSON(json, #PB_JSON_PrettyPrint)
FreeJSON(json)

marcelx · **Registriert:** 19.02.2010 20:19 **Wohnort:** Darmstadt

Wunderbar - danke STARGÅTE
das war eine schnelle Antwort

Code:

  If CreateJSON(0)
    InsertJSONStructure(JSONValue(0), @specifications(), _specifications)
    Debug ComposeJSON(0, #PB_JSON_PrettyPrint)
  EndIf

marcelx · **Registriert:** 19.02.2010 20:19 **Wohnort:** Darmstadt

wie kann ich eine Structure an eine Procedure übergeben?
Ich möchte mit eine allgemeine Procedure strukturierten Daten anzeigen:

Code:

Procedure debugStr(*adr, str)
  Debug "----------------------"
  If CreateJSON(0)
    InsertJSONStructure(JSONValue(0), *adr, str)
    Debug ComposeJSON(0, #PB_JSON_PrettyPrint)
  EndIf
  Debug "----------------------"   
EndProcedure
debugStr(@specifications(), _specifications)

So funktioniert nicht.
EDIT: so funktioniert - ich hatte _specifications in Hochkomma gesetzt und geht auch nicht

mk-soft · **Registriert:** 24.11.2004 13:12 **Wohnort:** Germany

Das geht leider nicht, da die Strukturen zur Compilerzeit aufgelöst werden.

Mit Macros kann man einiges lösen.

Code:

Structure sFoo
  iVal.i
  sVal.s
  List ListVal.i()
EndStructure

Macro debugStr(adr, str)
  Debug "----------------------"
  If CreateJSON(0)
    InsertJSONStructure(JSONValue(0), adr, str)
    Debug ComposeJSON(0, #PB_JSON_PrettyPrint)
  EndIf
  Debug "----------------------"   
EndMacro

data1.sfoo

debugStr(data1, sfoo)

marcelx · **Registriert:** 19.02.2010 20:19 **Wohnort:** Darmstadt

Danke mk-soft für die Erläuterung der Hintergrund.
Daran habe ich nicht gedacht.

PureBoard

debug Structure

Wer ist online?