Scrollbares Image im ImageGadget

[topsoft]

Hallo,

ich habe folgenden Testcode:

Code: Alles auswählen

#Fenster_w  = 640 : #Fenster_h  = 480 : #Scroll_w   = 2100 : #Scroll_h   = 2940

Define hWin.i = OpenWindow(#PB_Any, 0, 0, #Fenster_w, #Fenster_h, "Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  ; neues Fenster
If hWin
  Define scroll.i = ScrollAreaGadget(#PB_Any, 0, 0, #Fenster_w, #Fenster_h, #Scroll_w, #Scroll_h)                             ; Scrollbereich 2100 x 2940 Pixel auf 640 x 480 Pixel
  Define imgad.i = ImageGadget(#PB_Any, 0, 0, #Scroll_w, #Scroll_h, #Null)                                                    ; Gadget fuer das Bild im Scrollbereich, Grösse 2100 x 2940 Pixel
  Define image.i = CreateImage(#PB_Any, #Scroll_h, #Scroll_w, 24, #Green)                                                     ; das Bild was ausschnittsweise im Scrollbereich zu sehen sein soll
  SetGadgetState(imgad, ImageID(image))                                                                                       ; Bild dem Gadget zuweisen
  Repeat
    Event = WaitWindowEvent()
  Until Event = #PB_Event_CloseWindow
  CloseWindow(hWin)
EndIf
End

Nun sollte das Bild (hier gruener Hintergrund) genauso groß wie das Imagegadget sein. Wie man auf dem folgenden Bild sieht ist dem aber nicht so.
Vergrößer ich das Bild wird auch irgendwann das ganze Imagegadget ausgefüllt. Beide sind aber gleich groß. Was übersehe ich hier nur?



Gruß

[mk-soft]

Bei CreateImage Width und Height vertauscht

Update Eventuell DPI Anpassung berechnen

Code: Alles auswählen

#Fenster_w  = 640 : #Fenster_h  = 480 : #Scroll_w   = 2100 : #Scroll_h   = 2940

Define x, y, dx, dy

Define hWin.i = OpenWindow(#PB_Any, 0, 0, #Fenster_w, #Fenster_h, "Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  ; neues Fenster
If hWin
  Define scroll.i = ScrollAreaGadget(#PB_Any, 0, 0, #Fenster_w, #Fenster_h, #Scroll_w, #Scroll_h)                             ; Scrollbereich 2100 x 2940 Pixel auf 640 x 480 Pixel
  Define imgad.i = ImageGadget(#PB_Any, 0, 0, #Scroll_w, #Scroll_h, #Null)  ; Gadget fuer das Bild im Scrollbereich, Grösse 2100 x 2940 Pixel
  
  ; DPI Mode
  dx = DesktopScaledX(#Scroll_w)
  dy = DesktopScaledY(#Scroll_h)
  
  Define image.i = CreateImage(#PB_Any, dx, dy, 24, #Green) 
  
  x = DesktopScaledX(10)
  y = DesktopScaledY(10)
  
  StartDrawing(ImageOutput(image))
  DrawingMode(#PB_2DDrawing_Outlined)
  Box(x + 1, y + 1, dx - 2 * x, dy - 2 * y, #White)
  Box(x, y, dx - 2 * x, dy - 2 * y, #Black)
  StopDrawing()
  
  SetGadgetState(imgad, ImageID(image))                                                                                       ; Bild dem Gadget zuweisen
  Repeat
    Event = WaitWindowEvent()
  Until Event = #PB_Event_CloseWindow
  CloseWindow(hWin)
EndIf
End

[topsoft]

Hallo,

Bei CreateImage Width und Height vertauscht

Oh je, manchmal sieht man den Wald vor lauter Bäumen nicht.

Eventuell DPI Anpassung berechnen

Ja das trifft auch zu.
Wenn ich "DPI-kompatibles Executable erstellen" benutze muß ich DesktopScaled nutzen.

Danke und Gruß